A_SalesQuotationText

DDL: A_SALESQUOTATIONTEXT Type: view COMPOSITE

Header Text

A_SalesQuotationText is a Composite CDS View that provides data about "Header Text" in SAP S/4HANA. It reads from 2 data sources (P_SalesDocumentText, I_SalesDocumentBasic) and exposes 9 fields with key fields SalesQuotation, Language, LongTextID. It has 1 association to related views.

2 data source(s) 9 fields

Data Sources (2)

SourceAliasJoin Type
P_SalesDocumentText P_SalesDocumentText from
I_SalesDocumentBasic SalesQuotation inner

Associations (1)

CardinalityTargetAliasCondition
[1..1] A_SalesQuotation _SalesQuotation _SalesQuotation.SalesQuotation = $projection.SalesQuotation

Annotations (14)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Header Text view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
AbapCatalog.sqlViewName ASQTEXT view
AbapCatalog.preserveKey true view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
ObjectModel.updateEnabled true view
ObjectModel.deleteEnabled true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view

Fields (9)

KeyFieldSource TableSource FieldDescription
KEY SalesQuotation
KEY Language Language
KEY LongTextID LongTextID
LongText LongText
SalesQuotationType I_SalesDocumentBasic SalesDocumentType
OrganizationDivision I_SalesDocumentBasic OrganizationDivision
SalesOrganization I_SalesDocumentBasic SalesOrganization
DistributionChannel I_SalesDocumentBasic DistributionChannel
_SalesQuotation _SalesQuotation 
@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Header Text'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASQTEXT',
    preserveKey: true,
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')  
}
@ObjectModel: {
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true


define view A_SalesQuotationText 
  as select from P_SalesDocumentText( P_SAPClient : $session.client ) as SalesQuotationText 
   inner join   I_SalesDocumentBasic                                  as SalesQuotation on  SalesQuotation.SalesDocument = SalesQuotationText.SalesDocument
                                                                                            and SalesQuotation.SDDocumentCategory               = 'B'
  association [1..1] to A_SalesQuotation as _SalesQuotation on _SalesQuotation.SalesQuotation = $projection.SalesQuotation
{
    @ObjectModel.readOnly: true
  key cast(SalesQuotationText.SalesDocument as sales_quotation preserving type)      as SalesQuotation,
  key Language,
  key LongTextID,
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_S4H_STXL_SQ'
      LongText,
      
      
      // For Access control

      @Consumption.hidden: true
      SalesQuotation.SalesDocumentType as SalesQuotationType,
      @Consumption.hidden: true
      SalesQuotation.OrganizationDivision,
      @Consumption.hidden: true
      SalesQuotation.SalesOrganization,
      @Consumption.hidden: true
      SalesQuotation.DistributionChannel,


      // Expose own associations

      _SalesQuotation
}

Learn More