A_SalesOrderItemSimulation

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Sales Order Item Simulation (API)'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASOITMSIM',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_SalesOrderItemSimulation
  as select from I_SalesOrderItem as SalesOrderItem

  association [1..1] to I_SalesDocumentBasic          as _SalesDocument     on  _SalesDocument.SalesDocument = $projection.SalesOrder

  association [1..1] to A_SalesOrderSimulation        as _SalesOrder        on  _SalesOrder.SalesOrder = $projection.SalesOrder

  association [0..*] to A_SalesOrderScheduleLineSimln as _ScheduleLine      on  _ScheduleLine.SalesOrder     = $projection.SalesOrder
                                                                            and _ScheduleLine.SalesOrderItem = $projection.SalesOrderItem

  association [0..*] to A_SalesOrderItemPartnerSimln  as _Partner           on  _Partner.SalesOrder     = $projection.SalesOrder
                                                                            and _Partner.SalesOrderItem = $projection.SalesOrderItem

  association [0..*] to A_SalesOrderItmPrcgElmntSimln as _PricingElement    on  _PricingElement.SalesOrder     = $projection.SalesOrder
                                                                            and _PricingElement.SalesOrderItem = $projection.SalesOrderItem

  // RFM enhancement : value-added services

  association [0..*] to A_SlsOrdSimlnValAddedSrvc     as _ValueAddedService on  _ValueAddedService.SalesOrder     = $projection.SalesOrder
                                                                            and _ValueAddedService.SalesOrderItem = $projection.SalesOrderItem

  //    Extensibility

  association [0..1] to E_SalesDocumentItemBasic      as _Extension         on  $projection.SalesOrder     = _Extension.SalesDocument
                                                                            and $projection.SalesOrderItem = _Extension.SalesDocumentItem

{
       @ObjectModel.readOnly: true
  key  SalesOrder,

       @ObjectModel.text.element: 'SalesOrderItemText'
  key  SalesOrderItem,

       HigherLevelItem,

       @ObjectModel.readOnly: true
       HigherLevelItemUsage,

       SalesOrderItemCategory,

       @Semantics.text: true
       SalesOrderItemText,

       PurchaseOrderByCustomer,

       Material,

       @ObjectModel.readOnly: true
       OriginallyRequestedMaterial,

       MaterialByCustomer,

       PricingDate,

       PricingReferenceMaterial,

       @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
       @Semantics.quantity.unitOfMeasureSapCode: 'RequestedQuantitySAPUnit'
       @Semantics.quantity.unitOfMeasureIsoCode: 'RequestedQuantityISOUnit'
       RequestedQuantity,

       @Semantics.unitOfMeasure: true
       RequestedQuantityUnit,
       cast(_RequestedQuantityUnit.UnitOfMeasureSAPCode as sd_reqd_qty_sapunit preserving type) as RequestedQuantitySAPUnit,
       cast(_RequestedQuantityUnit.UnitOfMeasureISOCode as sd_reqd_qty_isounit preserving type) as RequestedQuantityISOUnit,

       @Semantics.unitOfMeasure: true
       @ObjectModel.readOnly: true
       OrderQuantityUnit,

       @ObjectModel.readOnly: true
       cast(_OrderQuantityUnit.UnitOfMeasureSAPCode as sd_ord_qty_sapunit preserving type)      as OrderQuantitySAPUnit,

       @ObjectModel.readOnly: true
       cast(_OrderQuantityUnit.UnitOfMeasureISOCode as sd_ord_qty_isounit preserving type)      as OrderQuantityISOUnit,

       @ObjectModel.readOnly: true
       @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
       @Semantics.quantity.unitOfMeasureSapCode: 'OrderQuantitySAPUnit'
       @Semantics.quantity.unitOfMeasureIsoCode: 'OrderQuantityISOUnit'
       ConfdDelivQtyInOrderQtyUnit,

       @ObjectModel.readOnly: true
       @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
       @Semantics.quantity.unitOfMeasureSapCode: 'ItemWeightSAPUnit'
       @Semantics.quantity.unitOfMeasureIsoCode: 'ItemWeightISOUnit'
       ItemGrossWeight,

       @ObjectModel.readOnly: true
       @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
       @Semantics.quantity.unitOfMeasureSapCode: 'ItemWeightSAPUnit'
       @Semantics.quantity.unitOfMeasureIsoCode: 'ItemWeightISOUnit'
       ItemNetWeight,

       @Semantics.unitOfMeasure: true
       @ObjectModel.readOnly: true
       ItemWeightUnit,

       @ObjectModel.readOnly: true
       cast(_ItemWeightUnit.UnitOfMeasureSAPCode as sd_itm_wgt_sapunit preserving type)         as ItemWeightSAPUnit,

       @ObjectModel.readOnly: true
       cast(_ItemWeightUnit.UnitOfMeasureISOCode as sd_itm_wgt_isounit preserving type)         as ItemWeightISOUnit,

       @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
       @Semantics.quantity.unitOfMeasureSapCode: 'ItemVolumeSAPUnit'
       @Semantics.quantity.unitOfMeasureIsoCode: 'ItemVolumeISOUnit'
       @ObjectModel.readOnly: true
       ItemVolume,

       @Semantics.unitOfMeasure: true
       @ObjectModel.readOnly: true
       ItemVolumeUnit,

       @ObjectModel.readOnly: true
       cast(_ItemVolumeUnit.UnitOfMeasureSAPCode as sd_itm_vol_sapunit preserving type)         as ItemVolumeSAPUnit,

       @ObjectModel.readOnly: true
       cast(_ItemVolumeUnit.UnitOfMeasureISOCode as sd_itm_vol_isounit preserving type)         as ItemVolumeISOUnit,

       @Semantics.currencyCode: true
       @ObjectModel.readOnly: true
       TransactionCurrency,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       NetAmount,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       TaxAmount,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       CostAmount,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       Subtotal1Amount,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       Subtotal2Amount,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       Subtotal3Amount,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       Subtotal4Amount,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       Subtotal5Amount,

       @Semantics.amount.currencyCode: 'TransactionCurrency'
       @ObjectModel.readOnly: true
       Subtotal6Amount,

       @ObjectModel.readOnly: true
       MaterialSubstitutionReason,

       MaterialGroup,
       MaterialPricingGroup,
       Batch,
       Plant,
       StorageLocation,
       DeliveryGroup,
       ShippingPoint,
       ShippingType,
       DeliveryPriority,

       IncotermsClassification,
       IncotermsTransferLocation,
       IncotermsLocation1,
       IncotermsLocation2,

       ProductTaxClassification1,
       ProductTaxClassification2,
       ProductTaxClassification3,
       ProductTaxClassification4,
       ProductTaxClassification5,
       ProductTaxClassification6,
       ProductTaxClassification7,
       ProductTaxClassification8,
       ProductTaxClassification9,

       ReferenceSDDocument,
       ReferenceSDDocumentItem,

       CustomerPaymentTerms,

       SalesDocumentRjcnReason,

       //Fashion Enhancement

       @Feature:'SW:RFM_SEASON_UI'
       ProductSeasonYear,
       @Feature:'SW:RFM_SEASON_UI'
       ProductSeason,
       @Feature:'SW:RFM_SEASON_UI'
       ProductCollection,
       @Feature:'SW:RFM_SEASON_UI'
       ProductTheme,
       @ObjectModel.readOnly: true
       @Feature:'SW:RFM_SEASON_UI'
       SeasonCompletenessStatus,
       @Feature:'SW:RFM_FSH_WHSL_UI'
       FashionCancelDate,
       @Feature:'SW:RFM_SEGMTN_UI'
       RequirementSegment,

       // For Access control

       @Consumption.hidden: true
       _SalesDocument.SalesDocumentType                                                         as SalesOrderType,

       @Consumption.hidden: true
       _SalesDocument.OrganizationDivision,

       @Consumption.hidden: true
       _SalesDocument.SalesOrganization,

       @Consumption.hidden: true
       _SalesDocument.DistributionChannel,

       //Expose own associations

       _SalesOrder,
       _Partner,
       _PricingElement,
       _ScheduleLine,

       // RFM enhancement : value-added service

       @Feature:'SW:RFM_VAS_UI'
       _ValueAddedService
}
where
  SalesOrderItem.SalesOrder = '0'