A_ProjectDemand

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Project Demand'
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API
@Metadata.ignorePropagatedAnnotations: true
@OData.entityType.name: 'A_ProjectDemand_Type'
define root view entity A_ProjectDemand
  provider contract transactional_query
  as projection on I_ProjectDemandTP as  ProjectDemand
  association [0..1] to A_EnterpriseProjectElement_2 as _WorkPackage on $projection.ReferencedObjectUUID = _WorkPackage.ProjectElementUUID
  association [1]    to A_EnterpriseProject_2 as _Project on $projection.ProjectUUID = _Project.ProjectUUID 
{
  key ProjectDemandUUID,
      ProjectDemand,
      ProjectDemandName,
      ProjectDemandDescription,
      @ObjectModel.sapObjectNodeTypeReference: 'ProjectDemandCategory'
      ProjectDemandCategory,
      @ObjectModel.sapObjectNodeTypeReference: 'ProjectDemandType'
      ProjectDemandType,
      @ObjectModel.sapObjectNodeTypeReference: 'EnterpriseProjectElement'
      ReferencedObjectUUID,
      @ObjectModel.sapObjectNodeTypeReference: 'ProjectDemandStatus'
      ProjectDemandStatus,
      ProjectDemandDateMaintenance,
      ProjectDemandStartDate,
      ProjectDemandEndDate,
      ProjectDemandReleasedDateTime,
      ProjDmndActualSupplyDate,
      @Semantics: { amount : {currencyCode: 'ProjectDemandRequestCurrency'} }
      ProjectDemandPerUnitAmount,
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      ProjectDemandRequestCurrency,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      ProjDmndRequestedQuantityUnit,
      PriceUnitQty,
      @Semantics: { amount : {currencyCode: 'ProjDmndReqNetAmountCurrency'} }
      ProjectDemandRequestNetAmount,
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      ProjDmndReqNetAmountCurrency,
      @Semantics: { amount : {currencyCode: 'ProjDmndReqNetAmountCurrency'} }
      ProjectDemandOverallAmount,
      @Semantics: {
              amount: {
                currencyCode: 'ProjDmndReqNetAmountCurrency'
              }
            }
      cast( ProjectDemandRequestNetAmount as tv_proj_dmnd_expected_value preserving type ) as ProjectDemandExpectedAmount,
      @Semantics: { quantity : {unitOfMeasure: 'ProjDmndRequestedQuantityUnit'} }
      ProjDmndRequestedQuantity,
      Plant,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchasingGroup'
      PurchasingGroup,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchasingOrganization'
      PurchasingOrganization,      
      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      LastChangeDateTime,
      ProjectDemandLastChangedByUser,
      ProjDemandLastChangeDateTime,
      ProjDmndExternalReferenceUUID,
      @Consumption.hidden: true
      ProjectUUID,

      /* Associations */
      _Material : redirected to composition child A_ProjectDemandMaterial,
      _Service  : redirected to composition child A_ProjectDemandService,
      _Work     : redirected to composition child A_ProjectDemandResource, //_Work must be used due to underlying structure historically grown. At one point it was decided to name _Resource, but cannot be used here.

      _Expense  : redirected to composition child A_ProjectDemandExpense,
      _WorkPackage,
      _Project,
      @Consumption.hidden: true
      _EnterpriseProjectForUser
}