A_ProductionOrderOperation

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'API Production Order Operations'
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

define view entity A_ProductionOrderOperation
  as select from I_MfgOrderOperationDurn
  association [1..1] to I_MfgOrderSequence      as _OrderSequence             on  $projection.ManufacturingOrder            = _OrderSequence.ManufacturingOrder
                                                                              and $projection.ManufacturingOrderSequence    = _OrderSequence.ManufacturingOrderSequence
                                                                              and $projection.OrderInternalBillOfOperations = _OrderSequence.OrderInternalID
{
      // Technical Key

  key OrderInternalBillOfOperations,
  key OrderIntBillOfOperationsItem,
      ManufacturingOrder,             // Manufacturing Order

      @ObjectModel.text.element: ['MfgOrderOperationText']
      ManufacturingOrderOperation,    // Operation Number

      MfgOrderOperationIsPhase,
      ManufacturingOrderSequence,     // Sequence,

      cast(_OrderSequence.MfgOrderSequenceText  as mfgordersequencetext preserving type)       as MfgOrderSequenceText,      
      MfgOrderOperationText,          // OperationShortText

      ManufacturingOrderType,   // Order Type

      BusinessProcessEntryUnit, // BusinessProcessEntryUnit

      // Order header data

      ManufacturingOrderCategory, // Category

      @EndUserText.label: 'Work Center Type Code ' // Material

      WorkCenterTypeCode,
      WorkCenter, // WorkCenter,

      @EndUserText.label:'Earliest Execution Start Date'
      OpErlstSchedldExecStrtDte,      // PlannedStartDate

      @EndUserText.label:'Earliest Execution Start Time'
      OpErlstSchedldExecStrtTme,      // PlannedStartTime

      @EndUserText.label:'Earliest Execution End Date'
      OpErlstSchedldExecEndDte,       // P  lannedEndDate

      @EndUserText.label:'Earliest Execution End Time'
      OpErlstSchedldExecEndTme,       // PlannedEndTime

      @EndUserText.label:'Actual Execution Start Date'
      OpActualExecutionStartDate,     // StartDate,

      @EndUserText.label:'Actual Execution Start Time'
      OpActualExecutionStartTime,     // StartTime,

      @EndUserText.label:'Actual Execution End Date'
      OpActualExecutionEndDate,       // EndDate,

      @EndUserText.label:'Actual Execution End Time'
      OpActualExecutionEndTime,       // EndTime,

      OperationUnit,                  // OperationUnit,

      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      OpPlannedTotalQuantity,         // OperationQuantity,

      @EndUserText.label:'Scheduled Execution Duration'
      ErlstSchedldExecDurnInWorkdays, // PlannedDuration,

      @EndUserText.label:'Actual Execution Duration'
      OpActualExecutionDays, // ActualDuration,

      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      OpTotalConfirmedYieldQty, // Confirmed Quantity

      WorkCenterInternalID,
      
      /* enhanced to support Etag using Last change date time to schedule operations */
      case I_MfgOrderOperationDurn._MfgOrder.LastChangeDate
        when '00000000' then  // not changed yet, use create

          concat(I_MfgOrderOperationDurn._MfgOrder.MfgOrderCreationDate , I_MfgOrderOperationDurn._MfgOrder.MfgOrderCreationTime)
        else
          concat(I_MfgOrderOperationDurn._MfgOrder.LastChangeDate,I_MfgOrderOperationDurn._MfgOrder.LastChangeTime)
      end as LastChangeDateTime
}
where
  ManufacturingOrderCategory = '10';