A_ProcessOrderComponent_2

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Process Order Components'
@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.updateEnabled: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

define view entity A_ProcessOrderComponent_2
  as select from I_MfgOrderOperationComponent
  association [1..1] to E_ReservationDocumentItem as _Extension // Extensibility

  on  $projection.Reservation           = _Extension.Reservation
  and $projection.ReservationItem       = _Extension.ReservationItem
  and $projection.ReservationRecordType = _Extension.RecordType
{
      // Key

      @ObjectModel.sapObjectNodeTypeReference: 'ReservationDocument'
  key Reservation,
  key ReservationItem,
  key RecordType                                                                     as ReservationRecordType,      // New field in CE2008


      // Material data

      MaterialGroup,
      Material,
      Plant,

      // Order and Operation data

      @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderCategory'
      ManufacturingOrderCategory,
      @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderType'
      ManufacturingOrderType,
      @ObjectModel.sapObjectNodeTypeReference: 'ProductionOrder'
      cast(ManufacturingOrder                             as co_bid preserving type) as ManufacturingOrder,
      ManufacturingOrderSequence,
      ManufacturingOrderOperation,
      ProductionPlant,
      OrderInternalBillOfOperations,

      // Date and Time

      MatlCompRequirementDate,
      MatlCompRequirementTime,
      MaterialIsDirectlyProduced,                                                                                    // New field in OP2023.FPS03


      // Attributes

      ReservationIsFinallyIssued,
      cast( MatlCompIsMarkedForDeletion as /plmb/lkenz preserving type )             as MatlCompIsMarkedForDeletion, // CE2208

      IsBulkMaterialComponent,
      MatlCompIsMarkedForBackflush,
      MaterialCompIsCostRelevant,
      RequirementType,                                                                                               // New field in OP2023.FPS03

      WBSElementInternalID_2                                                         as WBSElementInternalID,        // New field in OP2023.FPS03


      // Text

      @Semantics.text:true
      _LongText.OrderComponentLongText, // CE2008


      // Assignments

      @ObjectModel.sapObjectNodeTypeReference: 'SalesOrder'
      SalesOrder,
      SalesOrderItem,
      SortField,

      // Assignments BOM

      BillOfMaterialCategory,

      BOMItem,
      BOMItemCategory,
      BillOfMaterialItemNumber,
      @EndUserText.label: 'BOM Item Text'
      @Semantics.text: true
      BOMItemDescription,

      // Goods Movement data

      @ObjectModel.sapObjectNodeTypeReference: 'StorageLocation'
      StorageLocation,
      Batch,
      case when BatchSplitType = ' '                      // LCOMKF4R

            and MaterialComponentIsPhantomItem = ' '      // resb-dumps

            and MatlCompIsTextItem             = ' '      // resb-txtps

            and MaterialIsDirectlyProcured     <> 'X'     // resb-dbskz NE 'F'

           then _ProductPlant2.IsInternalBatchManaged     // resb-xchar

           else BatchSplitType end                                                   as BatchSplitType,
      @ObjectModel.sapObjectNodeTypeReference: 'GoodsMovementType'
      GoodsMovementType,
      SupplyArea,
      @Semantics.text: true
      GoodsRecipientName,
      @Semantics.text: true
      UnloadingPointName,
      InventorySpecialStockType, // New field in OP2023.FPS03


      // Assignments WM

      MaterialStaging, // New field in OP2023.FPS03


      // Alternative item data - added with CE2011

      MaterialCompIsAlternativeItem,
      AlternativeItemGroup,
      AlternativeItemStrategy,
      AlternativeItemPriority,
      UsageProbabilityPercent,

      // Phantom assembly

      MaterialComponentIsPhantomItem,

      // Lead-Time offset

      LeadTimeOffset,

      // Quantities and UoM

      QuantityIsFixed,
      IsNetScrap,
      ComponentScrapInPercent,
      OperationScrapInPercent,
      BaseUnit,
      _BaseUnit.UnitOfMeasureISOCode                                                 as BaseUnitISOCode, // CE2105

      _BaseUnit.UnitOfMeasureSAPCode                                                 as BaseUnitSAPCode, // CE2105

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      RequiredQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      WithdrawnQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      ConfirmedAvailableQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      MaterialCompOriginalQuantity,
      EntryUnit,
      _EntryUnit.UnitOfMeasureISOCode                                                as EntryUnitISOCode,
      _EntryUnit.UnitOfMeasureSAPCode                                                as EntryUnitSAPCode,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      GoodsMovementEntryQty,

      // Amount and Currency

      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      Currency,
      @Semantics.amount.currencyCode: 'Currency'
      WithdrawnQuantityAmount,

      // eTag for Update CE2201

      @Semantics.durationInSeconds: true
      @Semantics.dateTime: false
      case I_MfgOrderOperationComponent._MfgOrder.LastChangeDate
        when '00000000' then  // not changed yet, use create

          concat(I_MfgOrderOperationComponent._MfgOrder.MfgOrderCreationDate,
                 I_MfgOrderOperationComponent._MfgOrder.MfgOrderCreationTime)
        else
          concat(I_MfgOrderOperationComponent._MfgOrder.LastChangeDate,
                 I_MfgOrderOperationComponent._MfgOrder.LastChangeTime)
        end                                                                          as LastChangeDateTime


}
where
  //RecordType = '' and  // scenario where RecordType/RSART <> '' (followup materials) is not supported   // Not relevant with CE2008 anymore, see key definition above

  ManufacturingOrderCategory = '40';