A_PhoneCallActivity

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Phone Call Activity'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'APHCLACT',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'PhoneCallActivity',
   createEnabled: true,
   updateEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_PhoneCallActivity
  as select from I_CustMgmtActivityEnhcd as PhoneCallActivity

  association [0..*] to A_PhoneCallActivityPersonResp as _PersonResponsible on  $projection.PhoneCallActivity = _PersonResponsible.PhoneCallActivity

  association [0..*] to A_PhoneCallActivityAttendee   as _Attendee          on  $projection.PhoneCallActivity = _Attendee.PhoneCallActivity

  association [0..*] to A_PhoneCallActivityText       as _Text              on  $projection.PhoneCallActivity = _Text.PhoneCallActivity

  //Extensibility

  association [0..1] to E_ActivityDocument            as _Extension         on  _Extension.BusinessObjectType   = 'BUS2000126'
                                                                            and $projection.PhoneCallActivity = _Extension.ActivityDocument
{

  key CustMgmtActivity            as PhoneCallActivity,
      CustMgmtActivityType        as PhoneCallActivityType,
      CustMgmtActivityDescription as PhoneCallActivityDescription,
      CustMgmtActivityUUID        as PhoneCallActivityUUID,
      CustMgmtActivityCategory,
      CustMgmtActivityPriority,
      CustMgmtActivityDirection,
      CustMgmtActivityIsPrivate,
      CustMgmtActyIsDspdInCalendar,
      Account,
      ContactPerson,
      case CustMgmtActivityStatus
       when 'C' then 'X'
       else ''
       end                        as PhoneCallActivityIsCompleted,
      CustMgmtActivityIsRejected  as PhoneCallActivityIsRejected,
      CustMgmtActivityStartDateTime,
      CustMgmtActivityEndDateTime,
      // CustMgmtActyPlndStartDateTime,

      // CustMgmtActyPlndEndDateTime,

      ResponsibleSalesOrganization,
      ServiceOrganization,
      ResponsibleServiceOrganization,
      DistributionChannel,
      Division,
      SalesOrganizationOrgUnitID,
      SalesOfficeOrgUnitID,
      SalesGroupOrgUnitID,
      ''                          as MarketingReferenceCampaignID,

      //Associations

      _PersonResponsible,
      _Attendee,
      _Text

}
where
      CustMgmtObjectType    = 'BUS2000126' // Customer Management Activity

  and BusinessActivityClass = 'A'          // Class - Phone Call