A_HandlingUnit

@AbapCatalog: {
    sqlViewName: 'AHANDLINGUNITHU',
    compiler.compareFilter: true,
    preserveKey: true
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
    authorizationCheck:     #CHECK,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

//@ObjectModel.compositionRoot: true

@ObjectModel: {
    usageType: {
      dataClass:       #MIXED,
      serviceQuality:  #C,
      sizeCategory:    #XL
    }
}
@VDM: {
    viewType: #CONSUMPTION,
    lifecycle.contract.type: #PUBLIC_REMOTE_API
// Annotations not allowed in remote API views

//    lifecycle.status: #DEPRECATED,

//    lifecycle.successor: 'A_HandlingUnit_2'

}
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]

@OData.entitySet.name : 'HandlingUnit'

@EndUserText.label: 'Handling Unit (Deprecated)'


define root view A_HandlingUnit  as select from I_HandlingUnitHeaderCombined
  composition [0..*] of A_HandlingUnitItem as _HandlingUnitItem
  //Extensibility

  association [0..1] to E_HandlingUnitHeader  as _Extension    on  $projection. HandlingUnitExternalID = _Extension.HandlingUnitExternalID
{
  key HandlingUnitExternalID, 
  key Warehouse,

      PackagingMaterial, 
      PackagingMaterialType, 

      Plant, 
      StorageLocation,      
      ShippingPoint, 


      ParentHandlingUnitNumber,

      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      GrossWeight, 
      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      NetWeight, 
      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      HandlingUnitMaxWeight, 
      @Semantics.unitOfMeasure:true    
      WeightUnit, 
      @Semantics.quantity.unitOfMeasure: 'HandlingUnitTareWeightUnit'
      HandlingUnitTareWeight, 
      @Semantics.unitOfMeasure:true    
      HandlingUnitTareWeightUnit, 
      
      @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
       GrossVolume, 
       @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
      HandlingUnitNetVolume, 
      @Semantics.unitOfMeasure:true      
      VolumeUnit, 
      @Semantics.quantity.unitOfMeasure: 'HandlingUnitTareVolumeUnit'
      HandlingUnitTareVolume, 
//      HandlingUnitVolumeTolerance, 

      @Semantics.unitOfMeasure:true      
      HandlingUnitTareVolumeUnit, 
 
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'     
      HandlingUnitLength, 
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
      HandlingUnitWidth, 
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
      HandlingUnitHeight, 
      @Semantics.unitOfMeasure:true    
      UnitOfMeasureDimension, 
      
      HandlingUnitReferenceDocument as HandlingUnitPackingObjectKey,
            
      case HandlingUnitPackingObjectType
        when '01' then cast(HandlingUnitReferenceDocument as vbeln)  // inbound delivery document reference

        when '03' then cast(HandlingUnitReferenceDocument as vbeln)  // outbound delivery document reference

        else cast('          ' as vbeln preserving type)            // 07 Repetitive Manufacturing - Finished Products - no document reference

                                                                    // 06 Non-Assigned Handling Unit - no document reference

      end as HandlingUnitReferenceDocument,
       
      CreatedByUser, 
      CreationDateTime, 
      LastChangedByUser, 
      LastChangeDateTime, 
      
      HandlingUnitProcessStatus,

//    EWM specific fields

      StorageType,
      StorageSection,
      StorageBin,

       /* Associations */ 
       
       _HandlingUnitItem


}