A_DevelopmentProjectElement

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Development Project Element Details'
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel: {
    usageType: {
      dataClass:       #TRANSACTIONAL,
      serviceQuality:  #C,
      sizeCategory:    #XL
    }
}
@VDM: {
    viewType: #CONSUMPTION,
    lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@OData.entityType.name:'DevelopmentProjectElement_Type'
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]

define view entity A_DevelopmentProjectElement
  as projection on R_DevelopmentProjectElementTP as _ProjectElement
  association [0..*] to A_DevProjRoleStaffing          as _Staffing                on  $projection.DevProjElmntUUID = _Staffing.DevProjElmntUUID
  association [1..*] to A_DevProjectElementResponsible as _ProjectElmntResponsible on  (
      $projection.DevProjElmntUUID                                                                                                        = _ProjectElmntResponsible.DevProjElmntUUID
    )
                                                                                   or  (
                                                                                       $projection.DevProjElmntOriginalTaskUUID           = _ProjectElmntResponsible.DevProjElmntUUID
                                                                                     )
                                                                                   and (
                                                                                      _ProjectElmntResponsible.DevProjElmntRespObjType    = 'TPO'
                                                                                      or _ProjectElmntResponsible.DevProjElmntRespObjType = 'TTO'
                                                                                      or _ProjectElmntResponsible.DevProjElmntRespObjType = 'PPO'
                                                                                      or _ProjectElmntResponsible.DevProjElmntRespObjType = 'CPO'
                                                                                      or _ProjectElmntResponsible.DevProjElmntRespObjType = 'CTO'
                                                                                      or _ProjectElmntResponsible.DevProjElmntRespObjType = 'ITO'
                                                                                    )
  association [0..*] to A_DevProjTaskRelationship      as _TaskRelationship        on  $projection.DevProjElmntUUID = _TaskRelationship.PredecessorTaskUUID
                                                                                   or  $projection.DevProjElmntUUID = _TaskRelationship.SuccessorTaskUUID
  association [1..*] to A_DevProjElementStatus         as _ProjectElementStatus    on  (
         $projection.DevProjElmntUUID                                                                                           = _ProjectElementStatus.DevProjElmntUUID
         and $projection.IsMirroredTask                                                                                         = ''
       )
                                                                                   or  (
                                                                                       $projection.DevProjElmntOriginalTaskUUID = _ProjectElementStatus.DevProjElmntUUID
                                                                                     )
  association [0..*] to A_DevRoleTaskAssignment        as _TaskRoleAssignment      on  $projection.DevProjElmntUUID               = _TaskRoleAssignment.DevProjElmntUUID
                                                                                   and _TaskRoleAssignment.DevProjElmntObjectType = 'TTO'
  ---Extension Association
  association [1..1] to E_DevelopmentProjectElement    as _Extension               on  $projection.DevProjElmntUUID = _Extension.TaskUUID
{
  key DevProjElmntUUID,
      ProjectElementDescription,
      @ObjectModel.sapObjectNodeTypeReference: 'DevelopmentProjectObjectType'
      DevProjElmntObjectType,
      ProjectUUID,
      DevelopmentProjectElement,
      SortingNumber,
      DevProjHierarchySortNumber,
      @ObjectModel.sapObjectNodeTypeReference: 'DevelopmentProjectElementType'
      DevProjElmntType,
      @ObjectModel.sapObjectNodeTypeReference: 'DevelopmentProjectProcessType'
      DevProjElmntProcessType,
      @ObjectModel.sapObjectNodeTypeReference: 'DevProjectConstraintType'
      StartConstraintType,
      StartConstraintDate,
      @ObjectModel.sapObjectNodeTypeReference: 'DevProjectConstraintType'
      DevProjFinishConstraintType,
      FinishConstraintDate,
      EarliestStartDate,
      EarliestFinishDate,
      LatestStartDate,
      LatestFinishDate,
      ProjectElementDuration,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      DurationUnit,
      DevProjElmntTotalFloat,
      FactoryCalendar,
      @Semantics.quantity.unitOfMeasure : 'PlannedWorkQuantityUnit'
      PlannedWorkQuantity,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      PlannedWorkQuantityUnit,
      @Semantics.quantity.unitOfMeasure : 'RemainingWorkQuantityUnit'
      DevProjElmntRmngWrkQuantity,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      RemainingWorkQuantityUnit,
      IsMilestoneTask,
      IsObligatory,
      IsApprovalRelevant,
      IsMirroredTask,
      DevProjElmntGroupingText,
      DevProjElmntSearchFieldText,
      ActualStartDate,
      ActualFinishDate,
      PercentageOfCompletion,
      @Semantics.quantity.unitOfMeasure : 'ActualWorkQuantityUnit'
      DevProjElmntActlWorkQuantity,
      @ObjectModel.sapObjectNodeTypeReference: 'UnitOfMeasure'
      ActualWorkQuantityUnit,
      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      LastChangeDateTime,
      ForecastedStartDate,
      ForecastedFinishDate,
      DevProjElmntParentTaskUUID,
      DevProjElmntOriginalTaskUUID,
      CheckListItemIsNotRelevant,
      CheckListItemIsNotOkay,
      CheckListItemIsOkay,
      /* Associations */
      _Staffing,
      _ProjectElmntResponsible,
      _TaskRelationship,
      _ProjectElementStatus,
      _TaskRoleAssignment,
      _Project : redirected to parent A_DevelopmentProject
}