A_CustMgmtTask

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Customer Management Task Activity'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ACUSTMGMTTASK',
  compiler.compareFilter: true,
  preserveKey:true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_CustMgmtTask
  as select from I_CustMgmtActivityEnhcd as CustMgmtTask

  association [0..*] to A_CustMgmtTaskPersonResp as _PersonResponsible on $projection.CustMgmtTask = _PersonResponsible.CustMgmtTask

  association [0..*] to A_CustMgmtTaskText       as _Text              on $projection.CustMgmtTask = _Text.CustMgmtTask
  //Extensibility

  association [0..1] to E_ActivityDocument       as _Extension         on  _Extension.BusinessObjectType   = 'BUS2000125'
                                                                        and $projection.CustMgmtTask  = _Extension.ActivityDocument
{

  key CustMgmtActivity            as CustMgmtTask,
      CustMgmtActivityType        as CustMgmtTaskType,
      CustMgmtActivityDescription as CustMgmtTaskDescription,
      CustMgmtActivityUUID        as CustMgmtTaskUUID,
      CustMgmtActivityPriority    as CustMgmtTaskPriority,
      CustMgmtActivityIsPrivate   as CustMgmtTaskIsPrivate,
      Account,
      ContactPerson,
      case CustMgmtActivityStatus
       when 'C' then 'X'
       else ''
       end                        as CustMgmtTaskIsCompleted,
      CustMgmtActivityIsRejected  as CustMgmtTaskIsRejected,
      CustMgmtActivityStartDateTime as CustMgmtTaskStartDateTime,
      CustMgmtActivityEndDateTime   as CustMgmtTaskEndDateTime,
      ResponsibleSalesOrganization,
      ServiceOrganization,
      ResponsibleServiceOrganization,
      DistributionChannel,
      Division,
      SalesOrganizationOrgUnitID,
      SalesOfficeOrgUnitID,
      SalesGroupOrgUnitID,
      //Associations

      _PersonResponsible,
      _Text
}
where
  CustMgmtObjectType = 'BUS2000125' // Task