A_CndnContrCndnRecord

@EndUserText.label: 'Condition Record'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  usageType.serviceQuality: #P,
  usageType.dataClass: #TRANSACTIONAL,
  usageType.sizeCategory: #XXL,
  query.implementedBy: 'ABAP:CL_WCB_CC_TP_QRY_COND_REC'
  }
@VDM: {
  viewType: #CONSUMPTION,
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
  }

define view entity A_CndnContrCndnRecord
  as projection on R_CndnContrCndnRecordTP
{
  key ConditionContract,
  key ConditionRecord,
      ConditionTable,
      ConditionApplication,
      ConditionType,
      @Semantics.businessDate.from: true
      ConditionValidityStartDate,
      @Semantics.businessDate.to: true
      ConditionValidityEndDate,
      ConditionCalculationType,
      PricingScaleBasis,
      @Semantics.amount.currencyCode: 'ConditionCurrency'
      @OData.v2.amount.noDecimalShift: true
      ConditionRateAmount,
      @Semantics.amount.currencyCode: 'ConditionCurrency'
      @OData.v2.amount.noDecimalShift: true
      ConditionAccrualsAmount,
      @Semantics.currencyCode: true
      ConditionCurrency,
      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      ConditionQuantity,
      @Semantics.unitOfMeasure: true
      ConditionQuantityUnit,
      cast( _ConditionQuantityUnit.UnitOfMeasureISOCode as wlf_kvmei_iso preserving type )                as ConditionQuantityUnitISOCode,
      cast( _ConditionQuantityUnit.UnitOfMeasureSAPCode as wlf_kvmei_sapcode preserving type )            as ConditionQuantityUnitSAPCode,
      @Semantics.quantity.unitOfMeasure: 'ConditionRateRatioUnit'
      ConditionRateRatio,
      @Semantics.quantity.unitOfMeasure: 'ConditionRateRatioUnit'
      ConditionAccrualsRatio,
      @Semantics.unitOfMeasure: true
      ConditionRateRatioUnit,
      cast( _ConditionRateRatioUnit.UnitOfMeasureISOCode as wcb_cond_percent_sign_iso   preserving type ) as ConditionRateRatioUnitISOCode,
      cast( _ConditionRateRatioUnit.UnitOfMeasureSAPCode as wcb_cond_percent_sign_sap preserving type )   as ConditionRateRatioUnitSAPCode,
      PricingScaleType,
      @Semantics.unitOfMeasure: true
      ConditionScaleQuantityUnit,
      cast( _ConditionScaleQuantityUnit.UnitOfMeasureISOCode as wcb_konms_iso preserving type )           as CndnScaleQuantityUnitISOCode,
      cast( _ConditionScaleQuantityUnit.UnitOfMeasureSAPCode as wcb_konms_sapcode preserving type )       as CndnScaleQuantityUnitSAPCode,
      @Semantics.currencyCode: true
      ConditionScaleAmountCurrency,
      ConditionIsDeleted,
      Product,
      Customer,
      BillToParty,
      PayerParty,
      ShipToParty,
      Supplier,
      InvoicingParty,
      PriorSupplier,
      SupplyingSupplier,
      CompanyCode,
      SalesOrganization,
      DistributionChannel,
      Division,
      SalesOffice,
      SalesGroup,
      PurchasingOrganization,
      Plant,
      ProductGroup,
      SalesSpcfcProductGroup1,
      SalesSpcfcProductGroup2,
      SalesSpcfcProductGroup3,
      SalesSpcfcProductGroup4,
      SalesSpcfcProductGroup5,

      /* --- Root Entity --- */
      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      _ConditionContract         : redirected to parent A_ConditionContract,

      /* --- Compositions --- */
      @ObjectModel.filter.enabled: false
      _CndnContrCndnRecdValidity : redirected to composition child A_CndnContrCndnRecdValidity,
      @ObjectModel.filter.enabled: false
      _CndnContrScCndnRecord     : redirected to composition child A_CndnContrScCndnRecord,
      @ObjectModel.filter.enabled: false
      _TextTP        as    _Text : redirected to composition child A_CndnContrCndnRecdText
}