A_CmplSubsqntProcessFlow

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'CMH Subsequent Documents entity'
@ObjectModel: {

   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #D,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API
@OData: {
  entitySet:  { name: 'SubsequentProcFlowDocItem' },
 entityType: { name: 'SubsequentProcFlowDocItem_Type' }
}
define view entity A_CmplSubsqntProcessFlow
  as select from           I_SDDocumentMultiLevelProcFlow as SubsequentProcFlowDocItem
    left outer to one join I_SDDocumentMultiLevelProcFlow as _SDDocMultiLevelProcFlow on  _SDDocMultiLevelProcFlow.SubsequentDocument         = SubsequentProcFlowDocItem.SubsequentDocument
                                                                                      and _SDDocMultiLevelProcFlow.SubsequentDocumentCategory = SubsequentProcFlowDocItem.SubsequentDocumentCategory
                                                                                      and _SDDocMultiLevelProcFlow.SubsequentDocumentItem     = SubsequentProcFlowDocItem.SubsequentDocumentItem
                                                                                      and _SDDocMultiLevelProcFlow.ProcessFlowLevel           = '00'

    left outer to one join I_ComplaintProcessFlowStatus   as _ProcessFlowStatus       on  _SDDocMultiLevelProcFlow.SubsequentDocument     = _ProcessFlowStatus.SalesDocument
                                                                                      and _SDDocMultiLevelProcFlow.SubsequentDocumentItem = _ProcessFlowStatus.DocumentItemNumber

    inner join             I_SDDocumentCategoryText       as _Category                on  _SDDocMultiLevelProcFlow.SubsequentDocumentCategory = _Category.SDDocumentCategory
                                                                                      and _Category.Language                                  = $session.system_language

    left outer to one join A_ComplaintInspection          as _ComplaintInspection     on  _SDDocMultiLevelProcFlow.PrecedingDocument         = _ComplaintInspection.ReferenceDocument
                                                                                      and _SDDocMultiLevelProcFlow.PrecedingDocumentItem     = _ComplaintInspection.ReferenceDocumentItem
                                                                                      and _SDDocMultiLevelProcFlow.PrecedingDocumentCategory = 'H'
                                                                                      and SubsequentProcFlowDocItem.SubsequentDocumentCategory  = 'T'
{
  key SubsequentProcFlowDocItem.DocRelationshipUUID,
      SubsequentProcFlowDocItem.PrecedingDocument,
      SubsequentProcFlowDocItem.PrecedingDocumentItem,
      SubsequentProcFlowDocItem.SubsequentDocument,
      SubsequentProcFlowDocItem.SubsequentDocumentItem,
      _SDDocMultiLevelProcFlow.PrecedingDocument      as SubsqntDocItmPrecdgDocument,
      _SDDocMultiLevelProcFlow.PrecedingDocumentItem  as SubsqntDocItmPrecdgDocItem,
      SubsequentProcFlowDocItem.SubsequentDocumentCategory,
      _Category.SDDocumentCategoryName                as DocumentDescription,
      _ProcessFlowStatus.SubsequentDocStatus,
      _ProcessFlowStatus.SDProcessStatusDesc          as SubsequentDocStatusDesc,
      SubsequentProcFlowDocItem.ProcessFlowLevel,
      _ComplaintInspection.InspectionDocument,
      _ComplaintInspection.ReturnsInspectionItem,
      _ComplaintInspection.SubsequentDocumentCategory as InspDocCategoryValue,
      _ComplaintInspection.ReturnsInspectionStatusText,
      _ComplaintInspection.CustomerReturnType
}
where
  (
       SubsequentProcFlowDocItem.SubsequentDocumentCategory = 'C' --> Sales Order
    or SubsequentProcFlowDocItem.SubsequentDocumentCategory = 'H' --> Customer Return
    or SubsequentProcFlowDocItem.SubsequentDocumentCategory = 'M' --> Invoice
    or SubsequentProcFlowDocItem.SubsequentDocumentCategory = 'O' --> Credit Memo
    or SubsequentProcFlowDocItem.SubsequentDocumentCategory = 'P' --> Debit Memo
    or SubsequentProcFlowDocItem.SubsequentDocumentCategory = 'T' --> Returns Delivery
    or SubsequentProcFlowDocItem.SubsequentDocumentCategory = 'J' --> Outbound Delivery
    or SubsequentProcFlowDocItem.SubsequentDocumentCategory = 'K' --> Credit Memo Request
    or SubsequentProcFlowDocItem.SubsequentDocumentCategory = 'L' --> Debit Memo Request
  )