A_BR_NFItem

@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'ABRNFITEM'
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Brazil Nota Fiscal Item'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@OData.entitySet.name : 'A_BR_NFItem'
@ObjectModel: {
  representativeKey: 'BR_NotaFiscalItem',
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: false
}
define view A_BR_NFItem
  as select from I_BR_NFItem
  association to parent A_BR_NFDocument             as _BR_NFDoc on $projection.BR_NotaFiscal = _BR_NFDoc.BR_NotaFiscal
  composition [1..*] of A_BR_NFTax                  as _BR_NFTax
  composition [0..*] of A_BR_NFAdditionImportDoc    as _BR_NFAdditionImportDoc
  composition [0..*] of A_BR_NFExportDocument       as _BR_NFExportDocument
  composition [0..*] of A_BR_NFItemNVE              as _BR_NFItemNVE
  composition [0..*] of A_BR_NFeProductTraceability as _BR_NFeProductTraceability
  composition [0..1] of A_BR_NFVehicle              as _BR_NFVehicle
  composition [0..1] of A_BR_NFePharmaceutical      as _BR_NFePharmaceutical
  composition [0..1] of A_BR_NFFuel                 as _BR_NFFuel
  composition [0..*] of A_BR_NFItemText             as _BR_NFItemText
  composition [0..*] of A_BR_NFItemAdditionalInfo   as _BR_NFItemAdditionalInfo
  composition [0..*] of A_BR_NFFuelOriginIndicator  as _BR_NFFuelOriginIndicator
{
      //I_BR_NFItem

      @ObjectModel.foreignKey.association: '_BR_NFDoc'
  key BR_NotaFiscal,
  key BR_NotaFiscalItem,
      BR_ICMSTaxSituation,
      BR_IPITaxSituation,
      BR_ISSTaxSituation,
      BR_COFINSTaxSituation,
      BR_PISTaxSituation,
      BR_ICMSBaseDetn,
      BR_ICMSSTBaseDetermination,
      BR_ICMSSTLegalClassfctn,
      BR_SubstituteICMSAmount,
      BR_ICMSExemptionReason,
      BR_ICMSDefermentAmount,
      BR_ICMSDeferralTaxRate,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_WithholdingICMSSTBaseAmount,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_WithholdingICMSSTAmount,
      BR_IPILegalClassification,
      BR_TobaccoBeverageIPIClassfctn,
      BR_IPIControlSealCode,
      BR_IPIControlSealQuantityValue,
      CostCenter,
      ProfitCenter,
      InternalOrder,
      ProjectNetwork,
      WBSElementInternalID,
      CostObject,
      Segment,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_NFNetFreightAmount,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_NFNetInsuranceAmount,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_NFNetOtherExpensesAmount,
      NetPriceAmount,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      NetValueAmount,
      BR_NFItemType,
      BR_ICMSOrISSIsIncludedInPrice,
      BR_NFItemIsStatistical,
      BR_NFIsServiceItem,
      Material,
      MaterialName,
      ValuationArea,
      ValuationType,
      MaterialGroup,
      BR_CFOPCategory,
      @Semantics.quantity.unitOfMeasure:'BaseUnit'
      QuantityInBaseUnit,
      BaseUnit,
      Plant,
      Batch,
      BR_NFSourceDocumentType,
      BR_NFSourceDocumentNumber,
      BR_NFSourceDocumentItem,
      BR_ReferenceNFNumber,
      BR_ReferenceNFItem,
      BR_NFPercentReturned,
      BR_NFNetDiscountAmount,
      BR_ExemptedICMSAmount,
      BR_ICMSStatisticalExemptionAmt,
      BR_ICMSSTMarginAddedPercent,
      BR_CPRBIsRelevant,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_NFTotalAmount,
      BR_CFOPCode,
      BR_MaterialOrigin,
      BR_MaterialUsage,
      IsProducedInhouse,
      NCMCode,
      BR_NBSCode,
      BR_EFDREINFServiceCode,
      BR_LC116ServiceCode,
      BR_ISSBenefitCode,
      BR_CSTISSCode,
      BR_NFApproximateTotalTaxAmount,
      BR_FCINumber,
      BR_ICMSTaxLaw,
      BR_IPITaxLaw,
      BR_ISSTaxLaw,
      BR_COFINSTaxLaw,
      BR_PISTaxLaw,
      GLAccount,
      PurchaseOrder,
      PurchaseOrderItem,
      InternationalArticleNumber,
      BR_NFExternalItemNumber,
      BR_RECOPINumber,
      BR_ISSSuspensionProcess,
      @Semantics.quantity.unitOfMeasure:'BR_NFTributaryUnit'
      BR_NFTributaryQuantity,
      BR_NFTributaryUnit,
      BR_NFIsPhysicalMvtOfMaterial,
      BR_NFItemHasTaxIncentive,
      BR_NFPriceAmountWithTaxes,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_NFValueAmountWithTaxes,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_NFDiscountAmountWithTaxes,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_NFFreightAmountWithTaxes,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_NFInsuranceAmountWithTaxes,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_NFExpensesAmountWithTaxes,
      BR_NFExemptedICMSWithTaxes,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_NFTotalAmountWithTaxes,
      BR_TaxCode,
      ActivityNumber,
      CreditCalculationBaseCode,
      BR_ReducnPctEffctvCalcBasis,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_EffctvCalcBasisAmount,
      BR_EffectiveICMSRate,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_EffectiveICMSAmount,
      ProductionIsInRelevantScale,
      BR_ManufacturerCNPJ,
      TaxIncentiveCode,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_ICMSSTDestTaxBaseAmount,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_ICMSSTDestTaxAmount,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_FCPOnICMSSTWithheldBaseAmt,
      BR_FCPonICMSSTWithheldRate,
      CustomsChargesAmount,
      BR_FCPOnICMSSTWithheldAmount,
      BR_IOFTaxAmount,
      BR_ICMSSTRateIncludingFCP,
      BR_NFeStatisticalAmount,
      SalesDocumentCurrency,
      BR_NFPartnerCNAE,
      BR_BusinessPlaceCNAE,
      BR_NFFreightNature,
      BR_InternalBarcode,         
      BR_InternalTributaryBarcode,
      BR_PISSTInNFTotal as BR_NFIsPISSTInTotalAmount,
      BR_PISSTInNFTotal,  
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_PISSTTaxAmount,    
      BR_COFINSSTInNFTotal as BR_NFIsCOFINSSTInTotalAmount,
      BR_COFINSSTInNFTotal,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      BR_COFINSSTTaxAmount,
      BR_ICMSDefermentPercent,     
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'                             
      @OData.v2.amount.noDecimalShift:true
      BR_FCPOnICMSDefermentAmount, 
      BR_FCPOnICMSDeferralTaxRate, 
      BR_FCPOnICMSDefermentPercent,
      BR_ExemptedICMSSTAmount, 
      BR_ICMSSTExemptionReason,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      @OData.v2.amount.noDecimalShift:true
      BR_ExclICMSAmtFromPISAndCOFINS,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      @OData.v2.amount.noDecimalShift:true
      BR_NFMonoICMSDeferredAmount,
      BR_NFAdRemICMSRetainedTaxRate,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      @OData.v2.amount.noDecimalShift:true
      BR_NFMonoICMSRetainedAmount,
      @Semantics.quantity.unitOfMeasure:'BaseUnit'
      BR_NFMonoRetainedTaxedQuantity,
      BR_NFAdRemICMSReductionReason,
      BR_NFAdRemICMSReductionRate,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      @OData.v2.amount.noDecimalShift:true
      BR_NFMonoICMSOperationAmount,
      BR_NFAdRemICMSDeferralPercent,
      //Texts

      cast('' as abap.sstring(999)) as BR_NFMessageText,
      cast('' as abap.sstring(132)) as BR_NFAdditionalProductInfoText,
      /* Associations */
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
      _BR_NFDoc,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BR_NFTax,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BR_NFAdditionImportDoc,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BR_NFExportDocument,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BR_NFItemNVE,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BR_NFeProductTraceability,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BR_NFVehicle,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BR_NFePharmaceutical,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BR_NFFuel,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BR_NFItemText,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BR_NFItemAdditionalInfo,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]      
      _BR_NFFuelOriginIndicator
}