ATOV_ST_CURRENT_COLS

@AbapCatalog.sqlViewName: 'ATO_V_ST_COLS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_ALLOWED
@EndUserText.label: 'Collections with imported items'

define view ATOV_ST_CURRENT_COLS
  as select from ATOV_ST_CURRENT_COL_VERSIONS as current_version
    inner join   ato_cols                     as col     on col.collection_id = current_version.collection_id
    inner join   ato_col_versions             as version on  version.collection_id = current_version.collection_id
                                                         and version.version       = current_version.collection_version
                                                         and version.timestamp     = 0
    inner join   ato_changelists              as changel on  changel.collection_id      = current_version.collection_id
                                                         and changel.collection_version = current_version.collection_version
                                                         and (
                                                            (
                                                              changel.status            = #ATO_CHANGELIST_STATUS.'ID'
                                                              or changel.status         = #ATO_CHANGELIST_STATUS.'PI'
                                                            )
                                                            or

                                                            changel.changelist_type     = #ATO_CHANGELIST_TYPE.'M' // Migration

                                                          )

{
  key col.collection_id                     as collection_id,
      version.version                       as version,
      col.original_system_type              as original_system_type,
      col.description_text                  as description_text,
      col.category                          as category,
      col.devclass                          as devclass,
      col.dev_namespace                     as dev_namespace,
      col.original_systname                 as original_systname,
      col.counter                           as counter,
      col.collection_type                   as collection_type,
      col.project_id                        as project_id,
      col.project_description               as project_description,
      version.product_version               as product_version,
      version.basis_release                 as basis_release,
      version.count_all_items_in_col_at_exp as count_all_items_in_col_at_exp,
      changel.exported_at                   as exported_at,
      changel.downtimer_required            as downtimer_required,
      changel.changelist_type               as changelist_type,
      changel.consitency_status             as consitency_status
}