ATOV_CUST_DEPENDENCIES

@AbapCatalog.sqlViewName: 'ATO_V_CUS_DEP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'ATO Item Dependencies to Custom Objects'
define view ATOV_CUST_DEPENDENCIES
  as select from    ato_conti_depcus         as cus_dep

  // left outer join so that no rows get lost in case of missing translations...

    left outer join ato_adapt_typest         as item_type_description     on  item_type_description.adaptation_type = cus_dep.item_type
                                                                          and item_type_description.language        = $session.system_language

    left outer join ATOV_ADAPTATION_TYPE     as item_type                 on item_type.code = cus_dep.item_type

    left outer join ATOV_U_ITEM_DESCRIPTION  as item_base                 on  item_base.item_type = cus_dep.item_type
                                                                          and item_base.item_id   = cus_dep.item_id
    left outer join ATOV_ALL_TEXT_ADAPT_TYPE as object_type_description   on  cus_dep.depending_on_object      = replace(
      object_type_description.item_type, 'R3TR_', ''
    )
                                                                          and object_type_description.language = $session.system_language

    inner join      ato_sap_objt             as sap_object                on  sap_object.object_type = 'CUST'
                                                                         and sap_object.language    = $session.system_language

{
  key cus_dep.item_type                                                     as item_type,
  key cus_dep.item_id                                                       as item_id,
  key cast( concat('CUST', cus_dep.depending_on_object) as ato_item_type )  as depending_on_item_type,
  key cast(cus_dep.depending_on_object_name as ato_item_id)                 as depending_on_item_id,
      item_type_description.description                                     as item_type_description,
      item_type.sap_icon                                                    as item_type_sap_icon,
      item_base.item_description                                            as item_description,
      cast(concat_with_space(
             sap_object.description,
             coalesce(object_type_description.description, cus_dep.depending_on_object), 2
           ) as ato_item_type_description )                                 as depending_on_type_description,
      cast('sap-icon://developer-settings' as ato_sap_icon)                 as depending_on_type_sap_icon,

      cast(concat_with_space(
             coalesce(object_type_description.description,  cus_dep.depending_on_object),
             cus_dep.depending_on_object_name, 2 ) as ato_item_description) as depending_on_item_description,
//      ''                                                                    as rework, //Blank zurückgeben

//      ''                                                                    as rework_priority,

//      ''                                                                    as rework_priority_text,

//      ''                                                                    as rework_category,

//      ''                                                                    as rework_category_text,

      item_type.semantic_object                                             as semantic_object,
      item_type.semantic_action                                             as semantic_action

}