R_TRANSPORTATIONORDERTP

CDS View

Transportation Order - TP

R_TRANSPORTATIONORDERTP is a CDS View in S/4HANA. Transportation Order - TP. 6 CDS views read from this table.

Used by 6 CDS view(s)

CDS Views using this table (6)

ViewTypeJoinVDMDescription
A_FreightBooking view_entity projection CONSUMPTION Freight Booking
A_FreightOrder view_entity projection CONSUMPTION Freight Order
A_FreightUnit view_entity projection CONSUMPTION Freight Unit
I_FreightBookingTP view_entity projection TRANSACTIONAL Freight Booking - TP
I_FreightOrderTP view_entity projection TRANSACTIONAL Freight Order - TP
I_FreightUnitTP view_entity projection TRANSACTIONAL Freight Unit - TP 
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@EndUserText.label: 'Transportation Order - TP'
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['TransportationOrder'],
    representativeKey: 'TransportationOrderUUID',
    sapObjectNodeType.name: 'TransportationOrder'
}
@AccessControl: { authorizationCheck: #MANDATORY,
                  privilegedAssociations: ['_TransportationOrderStage',
                                           '_TranspOrdPlanningBlock',
                                           '_TransportationOrderBlock',
                                           '_SourceStop',
                                           '_DestinationStop',
                                           '_TranspOrdResponsiblePerson',
                                           '_CreatedBy',
                                           '_LastChangedBy']}
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'TOR',
  quota: {
    maximumFields: 408, //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <max number of fields in SCFD_REGISTRY>

    maximumBytes: 8160  //This is calculated with formula - 4* <Customer Percentage from SCFD_REGISTRY> * <number of chars as defined in SCFD_REGISTRY>

  }
 }

define root view entity R_TransportationOrderTP
  as select from I_TransportationOrder
  composition [0..*] of R_TransportationOrderBPTP     as _TransportationOrderBP
  composition [0..*] of R_TranspOrdDocRefTP           as _TranspOrdDocumentReference
  composition [0..*] of R_TransportationOrderItemTP   as _TransportationOrderItem
  composition [0..*] of R_TransportationOrderStopTP   as _TransportationOrderStop
  composition [0..*] of R_TransportationOrderEventTP  as _TransportationOrderEvent
  composition [0..3] of R_TrOrdMainBPAddrDfltRprstnTP as _TrOrdMainBPAddrDfltRprstn
  composition [0..*] of R_TransportationOrderNoteTP   as _TransportationOrderNote
  // Charges specific composition

  composition [0..1] of R_TransportationOrderChargeTP as _TransportationOrderCharge

  association [0..1] to R_TrOrdMainBPAddrDfltRprstnTP as _CarrierAddrDfltRprstn       on  $projection.TransportationOrderUUID                     = _CarrierAddrDfltRprstn.TransportationOrderUUID
                                                                                     and _CarrierAddrDfltRprstn.TranspOrdBizPartnerFunction       = 'U3'
  association [0..1] to R_TrOrdMainBPAddrDfltRprstnTP as _ShipperAddrDfltRprstn       on  $projection.TransportationOrderUUID                     = _ShipperAddrDfltRprstn.TransportationOrderUUID
                                                                                     and _ShipperAddrDfltRprstn.TranspOrdBizPartnerFunction       = 'U6'
  association [0..1] to R_TrOrdMainBPAddrDfltRprstnTP as _ConsigneeAddrDfltRprstn     on  $projection.TransportationOrderUUID                     = _ConsigneeAddrDfltRprstn.TransportationOrderUUID
                                                                                     and _ConsigneeAddrDfltRprstn.TranspOrdBizPartnerFunction     = 'WE'
  association [0..1] to R_TrOrdMainBPAddrDfltRprstnTP as _ExectgCarrierAddrDfltRprstn on  $projection.TransportationOrderUUID                     = _ExectgCarrierAddrDfltRprstn.TransportationOrderUUID
                                                                                     and _ExectgCarrierAddrDfltRprstn.TranspOrdBizPartnerFunction = 'TJ'                                                                                  
  //Extension Association

  association [1]    to E_TransportationOrder            as _Extension            on  $projection.TransportationOrderUUID = _Extension.TransportationOrderUUID
{
      /* Attributes */
      // Identification

  key TransportationOrderUUID,
      TransportationOrder,

      // Key Characteristics

      TransportationOrderType,
      TransportationOrderCategory,
      TranspOrdShippingType         as TransportationShippingType,
      MovementType,
      TransportationMode,
      TransportationModeCategory,

      // Parties

      CarrierUUID,
      Carrier,
      CarrierAddressID,
      StandardCarrierAlphaCode,
      TranspOrdExecutingCarrierUUID,
      TranspOrdExecutingCarrier,
      ExecutingCarrierAddressID,
      ShipperUUID,
      Shipper,
      ShipperAddressID,
      ConsigneeUUID,
      Consignee,
      ConsigneeAddressID,

      PurchasingOrganization        as TranspPurgOrg,
      PurchasingOrgExternalID       as TranspPurgOrgExtID,
      PurchasingGroup               as TranspPurgGroup,
      PurchasingGroupExternalID     as TranspPurgGroupExtID,
      PurgOrgCompanyCode,
      PlngAndExecOrganization,
      PlngAndExecGroup,
      TransOrdAcctNmbrWthExectgCarr as CarrierAccountNumber,

      // Further Attributes

      MeansOfTransport              as TranspMeansOfTransport,
      TranspOrdPartnerReference,
      MasterBillOfLading,
      TranspOrdResponsiblePerson,
      TranspOrdHasMltplExectgPties,
      TranspOrdInvoicingCarrierLevel,

      // Status

      TranspOrdLifeCycleStatus,
      TranspOrderSubcontrgSts,
      TransportationOrderConfSts,
      TransportationOrderExecSts,
      TranspOrdGoodsMovementStatus,
      TranspOrdWhseProcessingStatus,
      TranspOrderDngrsGdsSts,
      TranspOrdPlanningBlock,
      TranspOrdExecutionIsBlocked,

      // Administrative Data

      TransportationOrderCrtnType,
      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      ChangedDateTime,


      /* Associations */
      _Carrier,
      _Consignee,
      _CreatedBy,
      _DestinationStop,
      _LastChangedBy,
      _MeansOfTransport,
      _MovementType,
      _PlngAndExecGroup,
      _PlngAndExecOrganization,
      _PurchasingCompanyCode,
      _PurchasingGroup,
      _PurchasingOrganization,
      _Shipper,
      _SourceStop,
      _TranspOrdConfirmationStatus,
      _TranspOrdExecutionIsBlocked,
      _TranspOrdLifeCycleStatus,
      _TranspOrdPlanningBlock,
      _TranspOrdResponsiblePerson,
      _TranspOrdShippingType,
      _TranspOrdSubcontractingSts,
      _TransportationMode,
      _TransportationModeCategory,
      _TransportationOrderBlock,
      _TransportationOrderCategory,
      _TransportationOrderExecSts,
      _TransportationOrderStage,
      _TransportationOrderType,
      _TranspSCACCode,
      _TranspOrdDngrsGdsStatus,

      /* Composition Associations */
      _TransportationOrderBP,
      _TranspOrdDocumentReference,
      _TransportationOrderItem,
      _TransportationOrderStop,
      _TransportationOrderEvent,
      _TrOrdMainBPAddrDfltRprstn,
      _TransportationOrderNote,
      //Charges specific compositions

      _TransportationOrderCharge,

      _CarrierAddrDfltRprstn,
      _ShipperAddrDfltRprstn,
      _ConsigneeAddrDfltRprstn,
      _ExectgCarrierAddrDfltRprstn

}

Learn More