R_TRANSPORTATIONORDERBPTP

CDS View

Transportation Order Business Partner - TP

R_TRANSPORTATIONORDERBPTP is a CDS View in S/4HANA. Transportation Order Business Partner - TP. 6 CDS views read from this table.

Used by 6 CDS view(s)

CDS Views using this table (6)

ViewTypeJoinVDMDescription
A_FreightBookingBP view_entity projection CONSUMPTION Freight Booking Business Partner
A_FreightOrderBusinessPartner view_entity projection CONSUMPTION Freight Order Business Partner
A_FreightUnitBusinessPartner view_entity projection CONSUMPTION Freight Unit Business Partner
I_FreightBookingBPTP view_entity projection TRANSACTIONAL Freight Booking Business Partner - TP
I_FreightOrderBPTP view_entity projection TRANSACTIONAL Freight Order Business Partner - TP
I_FreightUnitBusinessPartnerTP view_entity projection TRANSACTIONAL Freight Unit Business Partner - TP 
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Transportation Order Business Partner - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['BusinessPartner'],
    representativeKey: 'TransportationOrderBusPartUUID'
}
define view entity R_TransportationOrderBPTP
  as select from I_TransportationOrderBP as TranspOrdBusinessPartner
  /* We must join I_TransportationOrder to make I_TransportationOrder.TransportationOrderCategory available in the
   * projection views to filter by TransportationOrderCategory */
  inner join I_TransportationOrder as TransportationOrder on TransportationOrder.TransportationOrderUUID = TranspOrdBusinessPartner.TransportationOrderUUID
  association to parent R_TransportationOrderTP as _TransportationOrder on $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID

  composition [0..1] of R_TranspOrdBPAddrDfltRprstnTP as _TranspOrdBPAddrDfltRprstn
{
      /* Attributes */
  key TranspOrdBusinessPartner.TransportationOrderBusPartUUID,
      TranspOrdBusinessPartner.TransportationOrderUUID,
      TranspOrdBusinessPartner.BusinessPartnerUUID,
      TranspOrdBusinessPartner.BusinessPartner,
      TranspOrdBusinessPartner.BusinessPartnerRole as TranspOrdBizPartnerFunction,
      TranspOrdBusinessPartner.AddressID as TranspOrdBizPartnerAddressID,

      // (Technical/Hidden) Attributes

      TransportationOrder.TransportationOrderCategory,

      /* Associations */
      TranspOrdBusinessPartner._BusinessPartner,
      TranspOrdBusinessPartner._PartnerFunction,
      _TransportationOrder,
      _TranspOrdBPAddrDfltRprstn
}

Learn More