R_SOURCINGPROJECTTP

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #NOT_REQUIRED,
  privilegedAssociations: [ '_CreatedByUser', '_ChangedByUser']
}

@ObjectModel:{representativeKey: 'SourcingProjectUUID',
              semanticKey: ['SourcingProject','SourcingProjectVersion'],

              usageType: {
                dataClass: #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory: #L
              },
              sapObjectNodeType.name: 'SourcingProject'
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Sourcing Project - TP'
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  allowNewDatasources: false,
  elementSuffix: 'SPH',
  quota: { maximumFields: 404,
           maximumBytes: 40400 },
  allowNewCompositions: true }


define root view entity R_SourcingProjectTP
  as select from R_SourcingProject
  composition [*] of R_SourcingProjectItemTP           as _SourcingProjectItem
  composition [*] of R_SrcgProjProcurementProjectTP    as _SrcgProjProcurementProject
  composition [*] of R_SrcgProjAllowedCurrencyTP       as _SrcgProjAllowedCurrency
  composition [*] of R_SourcingProjectMilestoneTP      as _SourcingProjectMilestone
  composition [*] of R_SourcingProjectContactTP        as _SourcingProjectContact
  composition [*] of R_SrcgProjAllwdSuplrContactTP     as _SrcgProjAllwdSuplrContact
  composition [*] of R_SrcgProjPubdSuplrListBPTP       as _SrcgProjPubdSuplrListBP
  composition [*] of R_SourcingProjectNoteTP           as _SourcingProjectNote
  composition [0..1] of R_SrcgProjPLMCollaborationTP   as _SrcgProjPLMCollaboration

  association [0..*] to I_PaymentTermsText             as _PaymentTermsText             on  $projection.PaymentTerms = _PaymentTermsText.PaymentTerms
  association [0..*] to I_IncotermsClassificationText  as _IncotermsText                on  $projection.IncotermsClassification = _IncotermsText.IncotermsClassification
  association [0..*] to I_IncotermsVersionText         as _IncotermsVersionText         on  $projection.IncotermsVersion = _IncotermsVersionText.IncotermsVersion
  association [0..*] to I_CurrencyText                 as _CurrencyText                 on  $projection.DocumentCurrency = _CurrencyText.Currency
  association [0..*] to I_PurgDocumentCategoryText     as _PurgDocumentCategoryText     on  $projection.SrcgProjFollowOnDocumentCat = _PurgDocumentCategoryText.PurchasingDocumentCategory
  association [0..*] to I_SourcingProjectTypeText      as _SourcingProjectTypeText      on  $projection.SourcingProjectType = _SourcingProjectTypeText.SourcingProjectType
  association [0..*] to I_MaterialGroupText            as _MaterialGroupText            on  $projection.MaterialGroup = _MaterialGroupText.MaterialGroup
  association [0..*] to I_PurchasingDocumentTypeText   as _PurchasingDocumentTypeText   on  $projection.SrcgProjFollowOnDocumentType = _PurchasingDocumentTypeText.PurchasingDocumentType
                                                                                        and $projection.SrcgProjFollowOnDocumentCat  = _PurchasingDocumentTypeText.PurchasingDocumentCategory
  association [0..1] to R_SourcingSupplierList         as _SourcingSupplierList         on  $projection.SourcingSupplierListUUID = _SourcingSupplierList.SourcingSupplierListUUID
  association [0..*] to I_SrcgProjLifecycleStatusText  as _SrcgProjLifecycleStatusText  on  $projection.SrcgProjLifecycleStatus = _SrcgProjLifecycleStatusText.SrcgProjLifecycleStatus
  association [0..*] to I_SrcgProjApprovalStatusText   as _SrcgProjApprovalStatusText   on  $projection.SrcgProjApprovalStatus = _SrcgProjApprovalStatusText.SrcgProjApprovalStatus
  association [1..*] to I_Shippinginstructiontext      as _ShippingInstructionText      on  $projection.ShippingInstruction = _ShippingInstructionText.ShippingInstruction
  association [1..*] to I_SourcingProjectPhaseText     as _SourcingProjectPhaseText     on  $projection.SourcingProjectPhase = _SourcingProjectPhaseText.SourcingProjectPhase
  association [0..*] to I_ProductSourcingReasonText    as _SourcingProjectReasonText    on  $projection.SourcingProjectVersioningRsn = _SourcingProjectReasonText.ProductSourcingReason
  association [1..1] to R_SourcingProjectBiddingRatio  as _SourcingProjectBiddingRatio  on  $projection.SourcingProjectUUID = _SourcingProjectBiddingRatio.SourcingProjectUUID
  association [0..*] to I_SrcgProjSourcingScenarioText as _SrcgProjSourcingScenarioText on  $projection.SourcingScenario = _SrcgProjSourcingScenarioText.SourcingScenario
  association [0..*] to I_SrcgProjSourcingOriginText   as _SrcgProjSourcingOriginText   on  $projection.SourcingOrigin = _SrcgProjSourcingOriginText.SourcingOrigin
  association [0..*] to I_ProductSourcingReasonText    as _SrcgProjCancellationRsnText  on  $projection.SrcgProjCancellationRsn = _SrcgProjCancellationRsnText.ProductSourcingReason
  //Extension

  association [1..1] to E_SourcingProject              as _Extension                    on  $projection.SourcingProjectUUID = _Extension.SourcingProjectUUID
{
  key SourcingProjectUUID,
      SourcingProject,
      SourcingProjectVersion,
      //      @ObjectModel: { foreignKey.association: '_SourcingProjectType',

      //                      readOnly: 'EXTERNAL_CALCULATION' }


      // ##### Move text assosications into I_VIEW #####

      SourcingProjectType,
      SourcingProjectName,
      //      @ObjectModel: { readOnly: true,

      //                      foreignKey.association: '_SrcgProjLifecycleStatus' }

      SrcgProjLifecycleStatus,
      SrcgProjApprovalStatus,
      //      @ObjectModel: { readOnly: true,

      //                      foreignKey.association: '_SourcingProjectPhase' }

      SourcingProjectPhase,
      SourcingSupplierListUUID,
      SrcgProjRevisionSts,
      SrcgProjActvtnSts,
      SrcgProjPubgSts,
      //      @ObjectModel: { foreignKey.association: '_CompanyCode',

      //                      mandatory: true,

      //                      readOnly:'EXTERNAL_CALCULATION' }

      CompanyCode,
      //      @ObjectModel: { foreignKey.association: '_PurchasingGroup',

      //                      mandatory: true }

      PurchasingGroup,
      //      @ObjectModel: { foreignKey.association: '_PurchasingOrganization',

      //                      mandatory: true }

      PurchasingOrganization,
      //      @ObjectModel: { foreignKey.association: '_MaterialGroup',

      //                      mandatory: true,

      //                      readOnly:'EXTERNAL_CALCULATION' }

      MaterialGroup,
      //      @ObjectModel: { foreignKey.association: '_DocumentCurrency'}

      DocumentCurrency,
      SrcgProjTotalTargetAmount,
      PurchaserRespWorkAgreement,
      PurchaserResponsiblePerson,

      QtnLatestSubmissionDateTime,
      //      @ObjectModel: { readOnly: true,

      //                      foreignKey.association: '_ChangedByUser' }

      LastChangedByUser,
      //      @ObjectModel: { readOnly: true,

      //                      foreignKey.association: '_CreatedByUser' }

      CreatedByUser,
      LastChangeDateTime,
      CreationDateTime,
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsVersion,
      IncotermsLocation1,
      IncotermsLocation2,
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      CashDiscount1Percent,
      CashDiscount2Percent,
      NetPaymentDays,
      //TargetAmount,

      SrcgProjPubgDteTme,
      SrcgProjCancDteTme,
      SrcgProjAttchsAreForbidden,
      SrcgProjNotesAreForbidden,
      SrcgProjFollowOnDocumentCat,
      SrcgProjFollowOnDocumentType,
      //      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }

      PurContrValidityStartDate,
      //      @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }

      PurContrValidityEndDate,
      ExchangeRateType,
      SourcingOrigin,
      SourcingScenario,
      ExternalSourcingProjectRef,
      LogicalSystem,
      ShippingInstruction,
      SourceSourcingProjectUUID,
      CentralPurchaseContract,
      ProcurementPlanningBundleUUID,
      SourcingProjectVersioningRsn,
      SrcgProjPaymentTermIsManual,
      //      //Required for the ECM Integration

      //      @ObjectModel: { readOnly: true }

      cast( concat(SourcingProject,
             concat('/' ,cast(SourcingProjectVersion as abap.char(10))))
              as vdm_sourcingprojectuniqueid ) as SourcingProjectUniqueID,
      cast( '' as abap.char( 1 ) )             as SrcgProjHasBeenActivated,
      SrcgProjEarliestCndnSelDate,
      SrcgProjCancellationRsn,
      // cast( '' as abap.char( 1 ) )             as IsNotesEnabled,

      @ObjectModel.editableFieldFor: 'SourcingProjectType'
      SourcingProjectType                      as SourcingProjectTypeForEdit,
      @ObjectModel.editableFieldFor: 'PurchasingOrganization'
      PurchasingOrganization                   as PurchasingOrganizationForEdit,
      @ObjectModel.editableFieldFor: 'PurchasingGroup'
      PurchasingGroup                          as PurchasingGroupForEdit,
      @ObjectModel.editableFieldFor: 'CompanyCode'
      CompanyCode                              as CompanyCodeForEdit,
      @ObjectModel.editableFieldFor: 'MaterialGroup'
      MaterialGroup                            as MaterialGroupForEdit,

      _SourcingProjectItem,
      _SourcingProjectType,
      _SrcgProjProcurementProject,
      _SrcgProjAllowedCurrency,
      _SourcingProjectMilestone,
      _SourcingProjectContact,
      _SrcgProjAllwdSuplrContact,
      _PurchasingGroup,
      _PurchasingOrganization,
      _CompanyCode,
      _PaymentTermsText,
      _IncotermsText,
      _IncotermsVersionText,
      _CurrencyText,
      _PurgDocumentCategoryText,
      _SourcingProjectTypeText,
      _MaterialGroupText,
      _PurchasingDocumentTypeText,
      _SourcingSupplierList,
      _SrcgProjPubdSuplrListBP,
      _SrcgProjLifecycleStatusText,
      _SrcgProjApprovalStatusText,
      _CreatedByUser,
      _ChangedByUser,
      _ShippingInstructionText,
      _SourcingProjectPhaseText,
      _SourceSourcingProject,
      _SourcingProjectReasonText,
      _SourcingProjectNote,
      _SourcingProjectBiddingRatio,
      _DocumentCurrency,
      _SrcgProjSourcingScenarioText,
      _SrcgProjSourcingOriginText,
      _SrcgProjCancellationRsnText,
      _SrcgProjPLMCollaboration
}