R_SALESQUOTATIONTEXTTP

CDS View

Sales Quotation - Text TP

R_SALESQUOTATIONTEXTTP is a CDS View in S/4HANA. Sales Quotation - Text TP. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_SalesQuotationTextManageTP view_entity projection CONSUMPTION Sales Quotaiton - Text
I_SalesQuotationTextTP view_entity projection TRANSACTIONAL Sales Quotation - Text TP 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}
@ObjectModel.semanticKey: ['SalesQuotation', 'Language', 'LongTextID']

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@EndUserText.label: 'Sales Quotation - Text TP'
define view entity R_SalesQuotationTextTP
  as select from P_SalesDocumentText( P_SAPClient : $session.client ) as SalesQuotationText

    inner join   I_SalesDocumentBasic                                 as SalesDocumentBasic on  SalesDocumentBasic.SalesDocument = SalesQuotationText.SalesDocument
                                                                                            and SalesDocumentBasic.SDDocumentCategory = 'B'

    inner join   I_SalesDocumentType                                  as SalesDocumentType  on SalesDocumentBasic.SalesDocumentType = SalesDocumentType.SalesDocumentType


  association to parent R_SalesQuotationTP            as _SalesQuotation              on  $projection.SalesQuotation = _SalesQuotation.SalesQuotation

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK'

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language
  association [0..1] to I_SDDocumentLongTextID        as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(SalesQuotationText.SalesDocument as sales_quotation preserving type) as SalesQuotation,

  key SalesQuotationText.Language,

  key SalesQuotationText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      SalesQuotationText.LongTextID                                                 as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      SalesQuotationText.Language                                                   as LanguageForEdit,

      SalesQuotationText.LongText,

      @Consumption.hidden: true
      SalesDocumentType.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                      as TextDeterminationProcedureItem,

      // For Access control

      @Consumption.hidden: true
      _SalesQuotation.SalesQuotationType,
      @Consumption.hidden: true
      _SalesQuotation.SalesOrganization,
      @Consumption.hidden: true
      _SalesQuotation.DistributionChannel,
      @Consumption.hidden: true
      _SalesQuotation.OrganizationDivision,


      // Exposed associations

      _SalesQuotation,
      _Language,
      _LongTextID
}

Learn More