R_SALESQUOTATIONPARTNERTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_DfltAddrRprstn' ]
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['SalesQuotation', 'PartnerFunction']

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Sales Quotation Partner - TP'
define view entity R_SalesQuotationPartnerTP
  as select from I_SalesQuotationPartner as SalesQuotationPartner

  association        to parent R_SalesQuotationTP as _SalesQuotation         on  $projection.SalesQuotation = _SalesQuotation.SalesQuotation
  association [0..1] to I_PartnerFunction         as _PartnerFunction        on  $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction
  association [0..1] to I_Language                as _CorrespondenceLanguage on  $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
  association [0..1] to I_FormOfAddress           as _FormOfAddress          on  $projection.FormOfAddress = _FormOfAddress.FormOfAddress
  association [0..1] to I_TransportationZone      as _TransportationZone     on  $projection.transportzone = _TransportationZone.TransportZone
                                                                             and $projection.country       = _TransportationZone.CountryCode

{
  key SalesQuotation,

  key cast(SalesQuotationPartner.PartnerFunction as parvw_unv preserving type ) as PartnerFunction,

      @ObjectModel.foreignKey.association: '_PartnerFunction'
      cast(SalesQuotationPartner.PartnerFunction as parvw_unv preserving type ) as PartnerFunctionForEdit,

      SalesQuotationPartner.Customer,

      SalesQuotationPartner.Supplier,

      SalesQuotationPartner.Personnel,

      SalesQuotationPartner.ContactPerson,

      SalesQuotationPartner.ReferenceBusinessPartner,
      
      @ObjectModel.text.element: ['FullName']
      SalesQuotationPartner.Partner,

      @Semantics.name.fullName: true
      @Semantics.text: true
      SalesQuotationPartner.FullName,

      _PartnerFunction.SDDocumentPartnerType,

      @ObjectModel.foreignKey.association: '_FormOfAddress'
      @Semantics.name.jobTitle: true
      SalesQuotationPartner.FormOfAddress,

      @Semantics.address.zipCode:true
      SalesQuotationPartner._OrgNamePostalAddress.PostalCode,

      @Semantics.address.city:true
      SalesQuotationPartner._OrgNamePostalAddress.CityName,

      SalesQuotationPartner._OrgNamePostalAddress.DistrictName,

      @Semantics.address.country:true
      @ObjectModel.foreignKey.association: '_Country'
      SalesQuotationPartner._OrgNamePostalAddress.Country,

      @ObjectModel.foreignKey.association: '_Region'
      @Semantics.address.region: true
      SalesQuotationPartner._OrgNamePostalAddress.Region,

      @Semantics.address.street: true
      SalesQuotationPartner._OrgNamePostalAddress.StreetName,

      @Semantics.address.street: true
      SalesQuotationPartner._OrgNamePostalAddress.StreetPrefixName1,

      @Semantics.address.street: true
      SalesQuotationPartner._OrgNamePostalAddress.StreetPrefixName2,

      @Semantics.address.street: true
      SalesQuotationPartner._OrgNamePostalAddress.StreetSuffixName1,

      @Semantics.address.street: true
      SalesQuotationPartner._OrgNamePostalAddress.StreetSuffixName2,

      @Semantics.address.streetNoNumber: true
      SalesQuotationPartner._OrgNamePostalAddress.HouseNumber,

      @Semantics.telephone.type: [#WORK]
      SalesQuotationPartner.InternationalPhoneNumber,

      @Semantics.telephone.type:  [#CELL]
      SalesQuotationPartner.InternationalMobilePhoneNumber,

      @Semantics.telephone.type: [#FAX]
      SalesQuotationPartner.InternationalFaxNumber,

      @Semantics.eMail.address: true
      @Semantics.eMail.type:  [#WORK]
      SalesQuotationPartner.EmailAddress,

      @Semantics.address.postBox: true
      SalesQuotationPartner._OrgNamePostalAddress.POBox,

      @Semantics.address.zipCode:true
      SalesQuotationPartner._OrgNamePostalAddress.POBoxPostalCode,

      @ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
      SalesQuotationPartner.CorrespondenceLanguage,

      SalesQuotationPartner._OrgNamePostalAddress.TaxJurisdiction,

      @ObjectModel.foreignKey.association: '_TransportationZone'
      SalesQuotationPartner._OrgNamePostalAddress.TransportZone,

      @Semantics.text: true
      SalesQuotationPartner.UnloadingPointName,

      SalesQuotationPartner.VATRegistration,

      SalesQuotationPartner.AddressID,
      
      SalesQuotationPartner.SDDocPartnerAddrIsDocSpecific,

      SalesQuotationPartner.AddressPersonID,

      SalesQuotationPartner.AddressObjectType,
            
//    On Conditions For Associations

      @Consumption.hidden: true
      SalesQuotationPartner.SDDocPartnerAddressRefType,
      @Consumption.hidden: true
      SalesQuotationPartner.BPAddrDeterminationTransaction,
      @Consumption.hidden: true
      SalesQuotationPartner.BPRefAddressIDForDocSpcfcAddr,


      //    DCL

      @Consumption.hidden: true
      _SalesQuotation.SalesQuotationType,
      @Consumption.hidden: true
      _SalesQuotation.SalesOrganization,
      @Consumption.hidden: true
      _SalesQuotation.DistributionChannel,
      @Consumption.hidden: true
      _SalesQuotation.OrganizationDivision,

      //    Associations

      _SalesQuotation,
      _PartnerFunction,
      _CorrespondenceLanguage,
      _FormOfAddress,
      _TransportationZone,

      SalesQuotationPartner._DfltAddrRprstn,
      SalesQuotationPartner._BusinessPartnerAddress,
      SalesQuotationPartner._OrgNamePostalAddress._Country,
      SalesQuotationPartner._OrgNamePostalAddress._Region
}