R_REOUTPUTREQUESTTP

CDS View

Real Estate Output Request TP

R_REOUTPUTREQUESTTP is a CDS View in S/4HANA. Real Estate Output Request TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_REOutputRequestTP view_entity projection CONSUMPTION Real Estate Output Request 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Real Estate Output Request TP'

@ObjectModel.representativeKey: 'OutputRequestUUID'
@ObjectModel.semanticKey: ['RealEstateProcess']
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@VDM: {
        viewType: #TRANSACTIONAL,
        lifecycle.contract.type: #SAP_INTERNAL_API,
        usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
      }
define root view entity R_REOutputRequestTP
  as select from I_REOutputRequest
  
  association [0..1] to R_OutputRequestTP       as _OutputRequest   on $projection.OutputRequestUUID = _OutputRequest.OutputRequestUUID
  
  association [0..1] to I_REProcess             as _REProcess       on $projection.RealEstateProcess = _REProcess.RealEstateProcess
{
  key OutputRequestUUID,
      OutputControlApplObjectType,
      OutputControlApplicationObject,
      RealEstateProcess,
      RealEstateContract,
      _REContract.REContractName,
      CompanyCode,
      OutputParameterText,
      CreationDateTime,
      CreatedByUser,
      LastChangeDateTime,
      LastChangedByUser,
      cast ( case 
                when OutputControlApplObjectType <> 'RE_ADJUSTMENT'
                    then 'X'
                    else ' ' end as recabool )                         as REOutpReqAdjustmentIsHidden,
      cast ( case
                when OutputControlApplObjectType <> 'RE_CONTRACT_A520'
                    then 'X'
                    else ' ' end as recabool )                          as REOutpReqInvoiceIsHidden,
                    
      _REContract.REContractType                                        as REContractType,
      _REContract.REAuthorizationGroup                                  as REAuthorizationGroup,
      /* Associations */
      _CompanyCode,
      _REContract,
      _ApplicationObjectType,
      _OutputRequest,
      _REProcess
      //      _OutputRequestItem

}

Learn More