R_PROJECTDEMANDMATERIAL

CDS View

Project Demand for Material

R_PROJECTDEMANDMATERIAL is a CDS View in S/4HANA. Project Demand for Material. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_ProjectDemandMaterial view from BASIC Project Demand for Material
I_ProjectDemandMaterialTP view_entity from TRANSACTIONAL Project Demand for Material - TP 
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel: {
   modelingPattern: #ANALYTICAL_DIMENSION,
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
   semanticKey:       ['Material'],
   representativeKey: 'ProjectDemandMaterialUUID',
   usageType: {
     serviceQuality:  #A,
     dataClass:       #TRANSACTIONAL,
     sizeCategory:    #XL
   }
}

@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Project Demand for Material'

define view entity R_ProjectDemandMaterial
  as select from materialdemand

  association [0..1] to R_ProjectDemandMaterialSupply as _MaterialSupply       on  _MaterialSupply.ProjectDemandMaterialUUID = $projection.ProjectDemandMaterialUUID
  association [1..1] to R_ProjectDemand               as _RootTP               on  $projection.ProjectDemandUUID = _RootTP.ProjectDemandUUID
  
  association [0..1] to I_ProductStdVH                as _MaterialNumber       on  $projection.Material = _MaterialNumber.Product
  association [1..1] to I_ProductDescription          as _MaterialText         on  $projection.Material   = _MaterialText.Product
                                                                               and _MaterialText.Language = $session.system_language
  association [0..1] to I_ProductGroup_2              as _MaterialGroup        on  $projection.MaterialGroup = _MaterialGroup.ProductGroup
  association [1..1] to I_ProductGroupText_2          as _MaterialGroupText    on  $projection.MaterialGroup   = _MaterialGroupText.ProductGroup
                                                                               and _MaterialGroupText.Language = $session.system_language
  association [0..1] to I_Supplier                    as _Supplier             on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_PurchasingInfoRecord        as _PurchasingInfoRecord on  $projection.PurchasingInfoRecord = _PurchasingInfoRecord.PurchasingInfoRecord
{

  key projectdemandmaterialuuid   as ProjectDemandMaterialUUID,

      projectdemanduuid           as ProjectDemandUUID,

      storagelocation             as StorageLocation,
      
      @Consumption.valueHelp: '_MaterialNumber'
      material                    as Material,

      @Consumption.valueHelpDefinition: [{
             entity: {   name:    'I_ProductGroup_2',
                         element: 'ProductGroup' }
         }]
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      materialgroup               as MaterialGroup,

      @ObjectModel.foreignKey.association: '_Supplier'
      supplier                    as Supplier,

      @ObjectModel.foreignKey.association: '_PurchasingInfoRecord'
      purchasinginforecord        as PurchasingInfoRecord,

      purchasecontract            as PurchaseContract,

      purchasecontractitem        as PurchaseContractItem,

      materialplanneddeliverydurn as MaterialPlannedDeliveryDurn,

      @Semantics.user.createdBy: true
      createdbyuser               as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      creationdatetime            as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      lastchangedbyuser           as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      lastchangedatetime          as LastChangeDateTime,

      _RootTP,
      _MaterialNumber,
      _MaterialText,
      _MaterialGroup,
      _MaterialGroupText,
      _Supplier,
      _MaterialSupply,
      _PurchasingInfoRecord

}

Learn More