R_PROJECTDEMANDWORK

@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ObjectModel: {
   modelingPattern: #ANALYTICAL_DIMENSION,
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
   semanticKey:       ['ActivityType' ],
   representativeKey: 'ProjectDemandWorkUUID',
   usageType: {
     serviceQuality:  #A,
     dataClass:       #TRANSACTIONAL,
     sizeCategory:    #XL
   }
}

@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Project Demand for Resource'

define view entity R_ProjectDemandWork
  as select from workdemand

  association [1..1] to R_ProjectDemand                as _Root               on $projection.ProjectDemandUUID = _Root.ProjectDemandUUID
  association [0..*] to R_ProjDmndResourceAssignment   as _ResourceAssignment on $projection.ProjectDemandWorkUUID = _ResourceAssignment.ProjectDemandWorkUUID
  association [0..*] to R_ProjectDemandResourceRequest as _ProjDmndRsceReq    on $projection.ProjectDemandWorkUUID = _ProjDmndRsceReq.ProjectDemandWorkUUID
  association [1..1] to I_EnterpriseProject        as _Project                  on $projection.ProjectUUID =  _Project.ProjectUUID 
  association [0..1] to I_EnterpriseProjectElement as _WorkPackage              on $projection.ReferencedObjectUUID = _WorkPackage.ProjectElementUUID  

  association [0..*] to I_CostCenterActivityTypeCtrl   as _CostCenterActType  on $projection.ActivityType = _CostCenterActType.CostCtrActivityType
  association [0..*] to I_CostCenter                   as _CostCenter         on $projection.CostCenter = _CostCenter.CostCenter
  association [0..*] to I_CostCenterText               as _CostCenterText     on $projection.CostCenter = _CostCenterText.CostCenter
  association [0..*] to I_CostCenterActivityTypeText   as _ActivityTypeText   on $projection.ActivityType = _ActivityTypeText.CostCtrActivityType  
  
{

  key projectdemandworkuuid          as ProjectDemandWorkUUID,

      projectdemanduuid              as ProjectDemandUUID,
      
      @ObjectModel.foreignKey.association:    '_Project'
      //Casting to a type which annotates Change Document Relevance as false. This field is already written into Change Document in root node .

      //cast(projectuuid as tv_proj_dmnd_uuid_chg_doc preserving type ) as ProjectUUID, "commented out, please see message 2380013083

      cast(projectuuid as tv_project_uuid_chg_doc preserving type ) as ProjectUUID,
      
      // usually this is a workpackage in S4CE

      @ObjectModel.foreignKey.association:    '_WorkPackage'
      //Casting to a type which annotates Change Document Relevance as false. This field is already written into Change Document in root node .

      //cast(referencedobjectuuid as tv_proj_dmnd_uuid_chg_doc preserving type ) as ReferencedObjectUUID, "commented out, please see message 2380013083

      cast(referencedobjectuuid as tv_dmnd_ref_obj_uuid_chg_doc preserving type ) as ReferencedObjectUUID,
            

      @ObjectModel: { text.association: '_CostCenterText' }
      costcenter                     as CostCenter,

      @ObjectModel.foreignKey.association: '_CostCenterActType'
      @ObjectModel: { text.association: '_ActivityTypeText' }
      activitytype                   as ActivityType,

      projdmndassgmtstatus           as ProjDmndAssgmtStatus,
      projectelementworkitem         as ProjectElementWorkItem,
      projdmndbillingcontrolcategory as ProjDmndBillingControlCategory,
      projdmndrequesteddeliveryorg   as ProjDmndRequestedDeliveryOrg,
      projdmndassgmtisinconsistent   as ProjDmndAssgmtIsInconsistent,

      @Semantics.user.createdBy: true
      createdbyuser                  as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      creationdatetime               as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      lastchangedbyuser              as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      lastchangedatetime             as LastChangeDateTime,


      /* Associations */
      _Root,
      _ResourceAssignment,
      _ProjDmndRsceReq,
      _Project,
      _WorkPackage, 

      _CostCenterActType,
      _CostCenter,
      _CostCenterText,
      _ActivityTypeText

}