R_PCLBLCONFIGURATIONTP

CDS View

Configurations for Labels - TP

R_PCLBLCONFIGURATIONTP is a CDS View in S/4HANA. Configurations for Labels - TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_PCLblConfigurationTP view_entity projection CONSUMPTION Configurations for Labels 
@AccessControl.authorizationCheck: #CHECK

@ObjectModel: {
  usageType:{
    serviceQuality: #C,
    sizeCategory: #M,
    dataClass: #TRANSACTIONAL
  },
  sapObjectNodeType.name: 'ProdCmplncLabelConfiguration'
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Configurations for Labels - TP'
define root view entity R_PCLblConfigurationTP
  as select from I_PCLblConfiguration

  composition [0..*] of R_PCLblConfignCmplncDataTP     as _PCLblConfignCmplncData

  composition [0..*] of R_PCLblConfigurationTextTP     as _PCLblConfigurationText
  
  composition [0..*] of R_PCLblConfigurationPlantTP    as _PCLblConfigurationPlant
  
  composition [0..*] of R_PCLblConfignShipToPartyTP    as _PCLblConfignShipToParty

  association [0..1] to I_PCLblConfignNameWithFallback as _PCLblConfignNameWithFallback on $projection.PCLblConfigurationID = _PCLblConfignNameWithFallback.PCLblConfigurationID

  association [0..1] to I_PCLblTemplate                as _PCLblTemplate                on $projection.PCLblTemplateID = _PCLblTemplate.PCLblTemplateID

  association [0..1] to I_PCLblConfigurationCategory   as _PCLblConfigurationCategory   on $projection.PCLblConfigurationCategory = _PCLblConfigurationCategory.PCLblConfigurationCategory

{
  key PCLblConfigurationID,
      PCLblConfigurationCategory,
      PCLblTemplateID,

      _PCLblConfignNameWithFallback.PCLblConfigurationName,
     
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,

      _PCLblConfignCmplncData,
      _PCLblConfigurationText,
      _PCLblConfigurationPlant,
      _PCLblConfignShipToParty,

      _PCLblConfignNameWithFallback,
      _PCLblTemplate,
      _PCLblConfigurationCategory
}

Learn More