R_OUTPUTREQUESTITEMTP

CDS View

Output Request Item for RAP

R_OUTPUTREQUESTITEMTP is a CDS View in S/4HANA. Output Request Item for RAP. 7 CDS views read from this table.

Used by 7 CDS view(s)

CDS Views using this table (7)

ViewTypeJoinVDMDescription
C_APARIntrstRunOutpReqItem view_entity projection CONSUMPTION Output Request Item Projection
C_MngSettlmtDocsOutpReqItem view_entity projection CONSUMPTION Manage Settlement Docs OutpReq Item
C_OutputRequestItemStandard view_entity projection CONSUMPTION Output Request Item for RAP
C_SalesDocOutputRequestItemTP view_entity projection CONSUMPTION Output Request Item for Sales Document
C_SettlmtDocOutpReqItem_F3658A view_entity projection CONSUMPTION Settlement Document Object Page OutpReq Item
C_TranspDocsOutpReqItem view_entity projection CONSUMPTION Manage TranspDoc OutpReq Item
R_PurgOutputSimulationItem view_entity from TRANSACTIONAL Custom Entity for PO Output Item 
@ObjectModel: {
   usageType.serviceQuality: #B,
   usageType.sizeCategory: #XXL,
   usageType.dataClass: #TRANSACTIONAL,
   semanticKey: [ 'OutputRequestItem' ],
   representativeKey: 'OutputRequestItemUUID'
}
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.privilegedAssociations: [ '_OutputRequest',
                                         '_OutputRequestItemEmail',
                                         '_OutputRequestItemAttachment',
                                         '_OutputRequestItemLog' ]
@AccessControl.personalData.blocking: #REQUIRED

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
// ???

@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true //shall be changed to false, because MDE on this level(TP) is not needed anymore

@EndUserText.label: 'Output Request Item for RAP'

define view entity R_OutputRequestItemTP
  as select from R_OutputRequestItem
  association        to parent R_OutputRequestTP      as _OutputRequest               on $projection.OutputRequestUUID = _OutputRequest.OutputRequestUUID
  composition [0..*] of R_OutputRequestItemEmailTP    as _OutputRequestItemEmail
  composition [0..*] of R_OutputRequestItemAttchTP    as _OutputRequestItemAttachment
  composition [0..*] of R_OutputRequestItemLogTP      as _OutputRequestItemLog
  association [0..1] to I_OutputRequestItemBinaryData as _OutputReqBinaryDataStandard on _OutputReqBinaryDataStandard.OutputRequestItemBinaryDataID = ''
  association [0..1] to I_OutputSenderOrgUnitType     as _OutputSenderOrgUnitType     on $projection.SenderOrganizationalUnitType = _OutputSenderOrgUnitType.SenderOrganizationalUnitType
  association [0..1] to I_Country                     as _SenderCountry               on $projection.SenderCountry = _SenderCountry.Country
  association [0..1] to I_Country                     as _FormTemplateCountry         on $projection.FormTemplateCountry = _FormTemplateCountry.Country
  association [0..1] to I_Language                    as _FormTemplateLanguage        on $projection.FormTemplateLanguage = _FormTemplateLanguage.Language
{
      //R_OutputRequestItem

  key OutputRequestItemUUID,
      @ObjectModel.foreignKey.association: '_OutputControlApplObjectType'
      OutputControlApplObjectType,
      OutputControlApplicationObject,
      OutputRequestItem,
      OutputRequestUUID,
      @ObjectModel.foreignKey.association: '_OutputRequestItemStatus'
      OutputRequestItemStatus,
      @ObjectModel.foreignKey.association: '_OutputDocumentType'
      OutputDocumentType,
      @ObjectModel.foreignKey.association: '_OutputChannel'
      OutputChannel,
      OutputRequestItemOrigin,
      Recipient,
      RecipientRole,
      IsChangeDocument,
      @ObjectModel.foreignKey.association: '_DispatchTime'
      DispatchTime,
      @UI.hidden: true
      OutputRequestItemRefUUID,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      FormTemplate,
      FormTemplateType,
      FormTemplateLanguage,
      FormTemplateCountry,
      SenderOrganizationalCenter,
      SenderOrganizationalCenterType,
      SenderOrganizationalUnit,
      @ObjectModel.foreignKey.association: '_OutputSenderOrgUnitType'
      SenderOrganizationalUnitType,
      SenderCountry,
      EmailTemplate,
      SenderEmailAddress,
      PrintQueue,
      PrintQueueItem,
      PrintCopyNumber,
      //  PrintingMethod,

      TotalPageNumber,
      DocumentPageDescriptionLang,
      KnowledgeProviderObjectCat,
      KnowledgeProviderObject,
      FormPDFIsUntagged,
      /* Associations */
      //R_OutputRequestItem

      _DispatchTime,
      _OutputChannel,
      _OutputControlApplObjectType,
      _OutputDocumentType,
      _OutputRequest,
      _OutputRequestItemStatus,
      _OutputRequestItemEmail,
      _OutputRequestItemAttachment,
      _OutputRequestItemLog,
      _OutputReqBinaryDataStandard,
      _OutputSenderOrgUnitType,
      _SenderCountry,
      _FormTemplateCountry,
      _FormTemplateLanguage
}

Learn More