R_INSURAPPLICATIONPREMIUM

CDS View

Premium in Insurance Application

R_INSURAPPLICATIONPREMIUM is a CDS View in S/4HANA. Premium in Insurance Application. It contains 16 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 16 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
I_InsurApplContract view_entity inner COMPOSITE Contract in Insurance Appl
I_InsurApplContrCoverage view_entity inner COMPOSITE Contract Coverage in Insurance Appl
I_InsurApplCoverage view_entity inner COMPOSITE Coverage of Cvrg Package in Insur Appl
P_InsurPlcyPremDevContract view_entity from COMPOSITE

Fields (16)

KeyField CDS FieldsUsed in Views
KEY InsurPlcyInsurContr InsurPlcyInsurContr 1
KEY InsurPlcyUUID InsurPlcyUUID 1
InsurancePolicyPremium InsurancePolicyPremium 3
InsurPerdPremAftTaxPaytAmt InsurPerdPremAftTaxPaytAmt 3
InsurPerdPremBfrTaxPaytAmt InsurPerdPremBfrTaxPaytAmt 3
InsurPlcyCvrgIsPremiumExempt InsurContrIsPremExempt,InsurPlcyCvrgIsPremiumExempt 3
InsurPlcyCvrgPremExmpEndDate InsurContrPremExmpEndDte,InsurPlcyCvrgPremExmpEndDate 3
InsurPlcyJrnlEndNmbr InsurPlcyJrnlEndNmbr,InsurPlcyPremJournalEndNumber 4
InsurPlcyJrnlNmbr InsurPlcyJrnlNmbr,InsurPlcyPremiumJournalNumber 4
InsurPlcyMainDueDayMonth InsurPlcyMainDueDayMonth 1
InsurPlcyPerdPremBfrTxPaytAmt InsurPlcyPerdPremBfrTxPaytAmt 3
InsurPlcyPremiumCurrency InsurPlcyPremiumCurrency 4
InsurPlcyPremiumTemplate InsurPlcyPremiumTemplate 3
InsurPlcyTotAnnPremAmt InsurPlcyTotAnnPremAmt 4
InsurPremSpecPaytRcrrcFrqcy InsurPremSpecPaytRcrrcFrqcy 1
InsurPremType InsurPremType 3 
@EndUserText.label: 'Premium in Insurance Application'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XXL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
define view entity R_InsurApplicationPremium
  as select from P_InsurPolicyJournalKeys      as PlcyJrnl
    inner join   I_InsurancePolicyPremiumBasic as Premium on  PlcyJrnl.InsurPlcyUUID                  =  Premium.InsurPlcyUUID
                                                          and PlcyJrnl.InsurPlcyInsurContr            =  Premium.InsurPlcyInsurContr
                                                          and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr >= Premium.InsurPlcyJrnlNmbr
                                                          and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr <  Premium.InsurPlcyJrnlEndNmbr

  association [1..1] to I_Currency                as _Currency                on $projection.InsurPlcyPremiumCurrency = _Currency.Currency
  association [1..1] to I_InsurPremPaytRcrrcFrqcy as _InsurPremPaytRcrrcFrqcy on $projection.InsurPremSpecPaytRcrrcFrqcy = _InsurPremPaytRcrrcFrqcy.InsurPremSpecPaytRcrrcFrqcy
  association [1..*] to I_InsurPlcyTemplateT      as _InsurPlcyTemplateT      on $projection.InsurPlcyPremiumTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate

{
  key Premium.InsurPlcyUUID,
  key Premium.InsurPlcyInsurContr,
  key Premium.InsurPlcyCoveragePackageID,
  key Premium.InsurPlcyCoverageID,
  key Premium.InsurancePolicyPremium,
  key cast( PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      Premium.InsurPlcyJrnlNmbr,
      Premium.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Premium.InsurPlcyProductPackageID,
      @ObjectModel.foreignKey.association: '_InsurPremPaytRcrrcFrqcy'
      Premium.InsurPremSpecPaytRcrrcFrqcy,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      Premium.InsurPerdPremBfrTaxPaytAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      Premium.InsurPerdPremAftTaxPaytAmt,
      Premium.InsurPremType,
      @Semantics.booleanIndicator:true
      Premium.InsurPlcyCvrgIsPremiumExempt,
      Premium.InsurPlcyCvrgPremExmpEndDate,
      @ObjectModel.foreignKey.association: '_Currency'
      Premium.InsurPlcyPremiumCurrency,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      Premium.InsurPlcyTotAnnPremAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      Premium.InsurPlcyPerdPremBfrTxPaytAmt,
      Premium.InsurPlcyMainDueDayMonth,
      @Semantics.systemDateTime.lastChangedAt: true
      Premium.LastChangeDateTime,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Premium.InsurPlcyPremiumTemplate,

      @Consumption.hidden: true
      _Currency,
      @Consumption.hidden: true
      _InsurPremPaytRcrrcFrqcy,
      @Consumption.hidden: true
      _InsurPlcyTemplateT

}

Learn More