R_FUNDEDPROGRAMTP

CDS View

Manage Funded Program - TP

R_FUNDEDPROGRAMTP is a CDS View in S/4HANA. Manage Funded Program - TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_FundedProgram view_entity projection CONSUMPTION Funded Program 
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #MASTER
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Manage Funded Program - TP'
define root view entity R_FundedProgramTP
  as select from I_FundedProgram as iFundedProgram
  association [0..1] to I_User as _user_created on  $projection.CreatedByUser = _user_created.UserID
  association [0..1] to I_User as _user_changed on  $projection.LastChangedByUser = _user_changed.UserID
  association [0..1] to E_FundedProgram as _Extension    on  $projection.FundedProgram                    = _Extension.FundedProgram
                                                and $projection.FinancialManagementArea = _Extension.FinancialManagementArea
{
      @ObjectModel.readOnly: true
  key iFundedProgram.FinancialManagementArea as FinancialManagementArea,
      @ObjectModel.readOnly: true
  key iFundedProgram.FundedProgram as FundedProgram,
      iFundedProgram.FundedProgramType as FundedProgramType,
      iFundedProgram.ValidityStartDate,
      iFundedProgram.ValidityEndDate,
      iFundedProgram.FundedProgramExpirationDate,
@Consumption.hidden: true
      iFundedProgram.FundedProgramAuthznGrp as FundedProgramAuthznGrp,
@Consumption.hidden: true
      iFundedProgram.FundedPgmFinMgmtAreaForAuthzn as FundedPgmFinMgmtAreaForAuthzn,
//      case

//      when _user_created.UserDescription is initial then iFundedProgram.CreatedByUser

//      else _user_created.UserDescription end  as CreatedByUserDescription,

      cast( _user_created.UserDescription as vdm_createdbyuserdescription preserving type )       as CreatedByUserDescription,
      @ObjectModel.readOnly: true
//      case

//      when _user_changed.UserDescription is initial then iFundedProgram._LastChangedByUser

//      else _user_changed.UserDescription end  as LastChangedByUserDescription,

      cast( _user_changed.UserDescription as vdm_lastchangedbyuserdescripti preserving type ) as LastChangedByUserDescription,
      iFundedProgram.CreatedByUser as CreatedByUser,
      iFundedProgram.CreationDate,
      iFundedProgram.CreationTime,
      iFundedProgram.LastChangedByUser,
      iFundedProgram.LastChangeDate,
      iFundedProgram.LastChangeTime,
      
      iFundedProgram._Text[1:Language = $session.system_language].FundedProgramName as FundedProgramName,
      iFundedProgram._Text[1:Language = $session.system_language].FundedProgramDescription as FundedProgramDescription,
      
      iFundedProgram._FinMgmtArea,
      iFundedProgram._Text,
      iFundedProgram._FundedProgramType,
      iFundedProgram._CreatedByUser,
      iFundedProgram._LastChangedByUser,
      iFundedProgram._FundedProgramHierarchyNode
      
}

Learn More