R_DISPUTECASEDRAFTCOLLSSGMTTP

CDS View

Dispute Case TP

R_DISPUTECASEDRAFTCOLLSSGMTTP is a CDS View in S/4HANA. Dispute Case TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_DisputeCaseDraftCollsSegment view_entity projection CONSUMPTION Dispute Case Draft in Collection Segment 
@AbapCatalog: { sqlViewName: 'RDISPCCLLSGTP',
                preserveKey: true,
                compiler: { compareFilter: true } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@EndUserText: { label: 'Dispute Case TP' }
@ObjectModel: { semanticKey:       [ 'DisputeCaseUUID', 'CaseID' ],
                representativeKey: 'DisputeCaseUUID',
                usageType:         { dataClass:      #TRANSACTIONAL,
                                     sizeCategory:   #L,
                                     serviceQuality: #C } }
@AccessControl: { authorizationCheck: #CHECK,
                  privilegedAssociations: ['_DisputeCaseCoordinatorCard',
                                           '_CreatedByContactCard',
                                           '_ChangedByContactCard',
                                           '_ClosedByContactCard',
                                           '_ProcessorContactCard',
                                           '_ResponsibleContactCard' ],
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@VDM: { viewType: #TRANSACTIONAL,
        usage: { type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] },
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }

define root view R_DisputeCaseDraftCollsSgmtTP
  as select from I_CollsSgmtCompanyCodeAssgmt
    inner join   P_DisputeCaseDraft on I_CollsSgmtCompanyCodeAssgmt.CompanyCode = P_DisputeCaseDraft.CompanyCode

  // VDM Associations

  // Created By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _CreatedByContactCard       on $projection.CaseCreatedBy = _CreatedByContactCard.ContactCardID

  // Changed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ChangedByContactCard       on $projection.CaseLastChangedBy = _ChangedByContactCard.ContactCardID

  // Closed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ClosedByContactCard        on $projection.CaseClosedBy = _ClosedByContactCard.ContactCardID

  // Coordinator Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _DisputeCaseCoordinatorCard on $projection.DisputeCaseCoordinator = _DisputeCaseCoordinatorCard.ContactCardID

  // Processor Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ProcessorContactCard       on $projection.CaseProcessor = _ProcessorContactCard.ContactCardID

  // Person Responsible Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ResponsibleContactCard     on $projection.CaseResponsible = _ResponsibleContactCard.ContactCardID

{

      // VDM Fields

  key CollectionSegment,
  key DisputeCaseUUID,
      DraftUUID,

      @ObjectModel: { foreignKey: { association: '_DisputeCaseCoordinatorCard' } }
      DisputeCaseCoordinator,

      DisputeCaseRootCause,
      CaseProcessingDeadlineDate,

      @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
      OriginalAmount,

      @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
      DisputedAmount,

      @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
      PaidAmount,

      @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
      CreditedAmount,

      @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
      WriteOffAmount,

      @Semantics: { amount: { currencyCode: 'DisputeCaseCurrency' } }
      ManuallyClearedAmount,

      @Semantics: { currencyCode: true }
      DisputeCaseCurrency,
      
      @Semantics: { amount: { currencyCode: 'CustomerDisputedCurrency' } }
      CustomerDisputedAmount,
      
      @Semantics: { currencyCode: true }
      CustomerDisputedCurrency,

      @Semantics: { name: { fullName: true } }
      ContactPersonName,

      @Semantics: { eMail: { address: true } }
      ContactPersonEmailAddress,

      @Semantics: { telephone: { type: [ #PREF ] } }
      ContactPersonPhoneNumber,

      @Semantics: { telephone: { type: [ #FAX ] } }
      ContactPersonFaxNumber,

      ContactPersonFaxCountry,
      Customer,
      P_DisputeCaseDraft.CompanyCode,
      DisputeCaseExternalApplication,
      CaseType,
      CaseID,
      CaseExternalReference,

      @ObjectModel: { foreignKey: { association: '_CreatedByContactCard' } }
      CaseCreatedBy,

      CaseCreatedOn,

      @ObjectModel: { foreignKey: { association: '_ChangedByContactCard' } }
      CaseLastChangedBy,

      CaseLastChangedOn,

      @ObjectModel: { foreignKey: { association: '_ClosedByContactCard' } }
      CaseClosedBy,

      CaseClosedTime,
      CasePlannedCloseDate,

      @ObjectModel: { foreignKey: { association: '_ProcessorContactCard' } }
      CaseProcessor,

      @ObjectModel: { foreignKey: { association: '_ResponsibleContactCard' } }
      CaseResponsible,

      CaseTitle,
      CaseEscalationReason,
      CaseCategory,
      CasePriority,
      CaseAuthorizationLevel,
      CaseStatusProfile,
      CaseStatus,
      CaseSystemStatus,
      CaseReason,
      IsActiveEntity,
      HasActiveEntity,
      DraftCreationDateTime,
      DraftLastChangedDateTime,

      // Exposed Associations

      _AuthLevel,
      _CaseSystemStatus,
      _CaseTypes,
      _CaseCategory,
      _ChangedByContactCard,
      _ClosedByContactCard,
      P_DisputeCaseDraft._CompanyCode,
      _Country,
      _CreatedByContactCard,
      _Customer,
      _DisputeCaseCoordinatorCard,
      _DisputeCaseExternalAppl,
      _Escalation,
      _Individual,
      _Priority,
      _ProcessorContactCard,
      _Reasons,
      _ResponsibleContactCard,
      _RootCause,
      _StatProfile,
      _CollectionSegment

}

Learn More