R_COLLSPROMISETOPAYTP

CDS View

Promise To Pay

R_COLLSPROMISETOPAYTP is a CDS View in S/4HANA. Promise To Pay. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_CollsPromiseToPayTP view_entity projection CONSUMPTION Promise To Pay 
@AccessControl: { authorizationCheck: #CHECK,
                  privilegedAssociations: [ '_CreatedByContactCard',
                                            '_ChangedByContactCard',
                                            '_ClosedByContactCard' ],
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Promise To Pay' }
@VDM: { viewType:  #TRANSACTIONAL,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]           
@ObjectModel: { usageType:                      { serviceQuality: #X,
                                                  sizeCategory:   #L,
                                                  dataClass:      #TRANSACTIONAL },
                modelCategory:                  #BUSINESS_OBJECT,
                transactionalProcessingEnabled: true,
                semanticKey:                    [ 'PromiseToPayUUID', 'CaseID' ],
                representativeKey:              'PromiseToPayUUID',
                sapObjectNodeType:              { name: 'PromiseToPay' } }

define root view entity R_CollsPromiseToPayTP
  as select from I_CollsPromiseToPay

  // VDM Associations

  // Installments

  composition [0..*] of R_CollsPromiseToPayInstlmntTP  as _CollsPromiseToPayInstlmntTP

  // Invoices

  composition [0..*] of R_CollsPromiseToPayInvoiceTP   as _CollsPromiseToPayInvoiceTP

  // Installment Status

  association [0..*] to I_CollsPrms2PInstallmentStatus as _CollsPrms2PInstallmentStatus on  $projection.PromiseToPayUUID = _CollsPrms2PInstallmentStatus.PromiseToPayUUID

  // Promise To Pay Payments

  association [0..*] to I_CollsPromiseToPayPayment     as _CollsPromiseToPayPayment     on  $projection.PromiseToPayUUID = _CollsPromiseToPayPayment.PromiseToPayUUID

  // Changed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard      as _ChangedByContactCard         on  $projection.CaseLastChangedBy = _ChangedByContactCard.ContactCardID

  // Created By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard      as _CreatedByContactCard         on  $projection.CaseCreatedBy = _CreatedByContactCard.ContactCardID

  // Closed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard      as _ClosedByContactCard          on  $projection.CaseClosedBy = _ClosedByContactCard.ContactCardID

  // Customer Quick View Facet

  association [0..1] to R_CollectionsCustomerQuickView as _CustomerQuickView            on  $projection.Customer    = _CustomerQuickView.Customer
                                                                                        and $projection.CompanyCode = _CustomerQuickView.CompanyCode

  // Association to extension include

  association [0..1] to E_PromiseToPay                 as _Extension                    on  $projection.PromiseToPayUUID = _Extension.PromiseToPayUUID

{

      // VDM FIelds

  key PromiseToPayUUID,
      CompanyCode,

      @ObjectModel: { foreignKey: { association: '_CustomerQuickView' } }
      Customer,

      ObjectType,
      LinkedInvoiceKey,
      PromisedAmount,
      PaidAmount,
      Currency,
      DueDate,
      PromiseToPayDate,
      LastPaymentDate,
      PromiseToPayStatus,
      PromiseToPayLevel,
      PromiseToPayGivenByPersonName,
      ContactPersonEmailAddress,
      ContactPersonPhoneNumber,
      ContactPersonFaxNumber,
      ContactPersonFaxCountry,
      ContactPerson,
      NumberOfInstallments,
      PaidOnScheduleAmount,
      PaidOffScheduleAmount,
      NextInstallmentDueDate,
      NextInstallmentAmount,
      Prms2PToInvoiceGroupRefUUID,
      CaseID,
      CaseExternalReference,

      @ObjectModel: { foreignKey: { association: '_CreatedByContactCard' } }
      CaseCreatedBy,

      CaseCreatedOn,

      @ObjectModel: { foreignKey: { association: '_ChangedByContactCard' } }
      CaseLastChangedBy,

      CaseLastChangedOn,

      @ObjectModel: { foreignKey: { association: '_ClosedByContactCard' } }
      CaseClosedBy,

      CaseClosedTime,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      PromisedAmount as PromisedAmountForEdit,

      IsCleared,

      // Exposed Associations

      _CaseAttribute,
      _ChangedByContactCard,
      _ClosedByContactCard,
      _CollsPromiseToPayStatus,
      _CompanyCode,
      _Country,
      _CreatedByContactCard,
      _Customer,
      _CollsPromiseToPayInstlmntTP,
      _CollsPromiseToPayInvoiceTP,
      _Currency,
      _CollsPrms2PInstallmentStatus,
      _CollsPromiseToPayPayment,
      _CustomerQuickView,
      _CustomerContact

}

Learn More