R_COLLECTIONSACCOUNTTP
Collections Management Account
R_COLLECTIONSACCOUNTTP is a CDS View in S/4HANA. Collections Management Account. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_CollectionsAccountTP | view_entity | projection | CONSUMPTION | Collections Management Account |
@AccessControl: { authorizationCheck: #CHECK,
personalData: { blocking: #BLOCKED_DATA_EXCLUDED },
privilegedAssociations: [ '_CollectionsAccountNote' ] }
@EndUserText: { label: 'Collections Management Account' }
@VDM: { viewType: #TRANSACTIONAL,
lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ObjectModel: { usageType: { serviceQuality: #X,
sizeCategory: #L,
dataClass: #TRANSACTIONAL },
semanticKey: [ 'Customer',
'CollectionSegment',
'CompanyCode',
'BusinessPartner' ],
representativeKey: 'Customer',
sapObjectNodeType: { name: 'CollectionsManagementAccount' } }
define root view entity R_CollectionsAccountTP
as select from I_CollectionsAccount
// VDM Associations
// Invoices
association [0..*] to R_CollectionsInvoiceTP as _CollectionsInvoice on $projection.CollectionSegment = _CollectionsInvoice.CollectionSegment
and $projection.Customer = _CollectionsInvoice.BranchAccount
// Invoices on Company Code Level
association [0..*] to R_CollectionsInvoiceTP as _CollectionsInvoiceCompanyCode on $projection.CompanyCode = _CollectionsInvoiceCompanyCode.CompanyCode
and $projection.Customer = _CollectionsInvoiceCompanyCode.BranchAccount
// Credit Management
association [0..1] to R_CollsAcctCreditMgmtSummary as _CollsAcctCreditMgmtSummary on $projection.BusinessPartner = _CollsAcctCreditMgmtSummary.BusinessPartner
and $projection.CollectionSegment = _CollsAcctCreditMgmtSummary.CollectionSegment
// Main Contact Person
association [0..1] to I_CollectionsMainContact as _CollectionsMainContact on $projection.BusinessPartner = _CollectionsMainContact.BusinessPartner
and $projection.CollectionSegment = _CollectionsMainContact.CollectionSegment
// Payment Trend
association [0..*] to I_CollectionsPaymentTrend as _CollectionsPaymentTrend on $projection.Customer = _CollectionsPaymentTrend.Customer
and $projection.CollectionSegment = _CollectionsPaymentTrend.CollectionSegment
// Due Date Grid
association [0..*] to I_CollectionsDueDateGrid as _CollectionsDueDateGrid on $projection.BusinessPartner = _CollectionsDueDateGrid.BusinessPartner
and $projection.CollectionSegment = _CollectionsDueDateGrid.CollectionSegment
// Resubmissions
association [0..*] to R_CollsResubmissionDraftTP as _CollectionsResubmission on $projection.BusinessPartner = _CollectionsResubmission.BusinessPartner
and $projection.CollectionSegment = _CollectionsResubmission.CollectionSegment
// Sticky Note
association [0..1] to I_CollsAccountStickyNote as _CollsAccountStickyNote on $projection.Customer = _CollsAccountStickyNote.Customer
and $projection.CollectionSegment = _CollsAccountStickyNote.CollectionSegment
// Head-Office/Branch
association [0..*] to I_CollectionsHeadOfficeBranch as _CollectionsHeadOfficeBranch on $projection.Customer = _CollectionsHeadOfficeBranch.Customer
// Collections Contacts
association [0..*] to R_CollectionsContactDraftTP as _CollectionsContactDraft on $projection.BusinessPartner = _CollectionsContactDraft.BusinessPartnerCompany
and $projection.CollectionSegment = _CollectionsContactDraft.CollectionSegment
// Collections Account Notes
association [0..*] to I_CollectionsAccountNote as _CollectionsAccountNote on $projection.Customer = _CollectionsAccountNote.Customer
and $projection.CollectionSegment = _CollectionsAccountNote.CollectionSegment
// Dispute Case on Collection Segment Level
association [0..*] to R_DisputeCaseDraftCollsSgmtTP as _DisputeCaseDraftCollsSegment on $projection.Customer = _DisputeCaseDraftCollsSegment.Customer
and $projection.CollectionSegment = _DisputeCaseDraftCollsSegment.CollectionSegment
// Promise To Pay on Collection Segment Level
association [0..*] to R_CollsPrmsToPayCollsSegmentTP as _PromiseToPayDraftCollsSegment on $projection.Customer = _PromiseToPayDraftCollsSegment.BranchAccount
and $projection.CollectionSegment = _PromiseToPayDraftCollsSegment.CollectionSegment
// Business Partner Quick View Facet
association [0..1] to R_CollectionsBPQuickView as _AddressBP on $projection.BusinessPartner = _AddressBP.BusinessPartner
and $projection.CollectionSegment = _AddressBP.CollectionSegment
and $projection.CompanyCode = _AddressBP.CompanyCode
// Key Figures
association [0..1] to R_CollectionsAccountKeyFigure as _CollectionsAccountKeyFigure on $projection.BusinessPartner = _CollectionsAccountKeyFigure.BusinessPartner
and $projection.CollectionSegment = _CollectionsAccountKeyFigure.CollectionSegment
{
// VDM Fields
key Customer,
key CollectionSegment,
key CompanyCode,
@ObjectModel: { foreignKey: { association: '_AddressBP' } }
BusinessPartner,
// Exposed Associations
_BusinessPartner,
_CollectionSegment,
_CompanyCode,
_Customer,
_CollectionsMainContact,
_CollectionsResubmission,
_CollectionsPaymentTrend,
_CollectionsDueDateGrid,
_CollsAccountStickyNote,
_CollectionsInvoice,
_CollectionsInvoiceCompanyCode,
_CollectionsHeadOfficeBranch,
_CollectionsContactDraft,
_CollectionsAccountNote,
_DisputeCaseDraftCollsSegment,
_PromiseToPayDraftCollsSegment,
_AddressBP,
_CollsAcctCreditMgmtSummary,
_CollectionsAccountKeyFigure
}