R_CNTRLPURCONTRITEMNOTESTP

CDS View

CCTR Item Notes

R_CNTRLPURCONTRITEMNOTESTP is a CDS View in S/4HANA. CCTR Item Notes. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
A_CntrlPurContrItemNotes_2 view_entity projection CONSUMPTION Central Purchase Contract Item Notes
C_CePuCoHierItmNotesMassUpdt view from CONSUMPTION Central Purchase Cont Hier Item Notes
C_CePuCoItmNotesForMassUpdt view from CONSUMPTION Central Purchase Contract Item Notes
I_CntrlPurContrItemNotesTP_2 view_entity projection TRANSACTIONAL CCTR Item Notes - TP 
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'CCTR Item Notes'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.semanticKey: [ 'CentralPurchaseContract', 'CentralPurchaseContractItem']

@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}

@Metadata.ignorePropagatedAnnotations: true

define view entity R_CntrlPurContrItemNotesTP

  as select from I_CntrlPurContractItemNotes

  association to parent R_CntrlPurchaseContractItemTP as _CntrlPurchaseContractItem on  $projection.CentralPurchaseContract     = _CntrlPurchaseContractItem.CentralPurchaseContract
                                                                                    and $projection.CentralPurchaseContractItem = _CntrlPurchaseContractItem.CentralPurchaseContractItem

  association to R_CntrlPurchaseContractTP            as _CentralPurchaseContract   on  $projection.CentralPurchaseContract = _CentralPurchaseContract.CentralPurchaseContract


{

  key I_CntrlPurContractItemNotes.PurchasingDocumentNoteUUID,
      I_CntrlPurContractItemNotes.PurchasingDocumentObjNodeType,
      I_CntrlPurContractItemNotes.PurchasingDocumentNoteObjectID,
      I_CntrlPurContractItemNotes.PurchasingDocumentNoteType,
      I_CntrlPurContractItemNotes.PurchasingDocumentNoteLanguage,
      I_CntrlPurContractItemNotes.PurchasingDocumentNoteTitle,
      I_CntrlPurContractItemNotes.PurchasingDocumentNoteMimeType,
      I_CntrlPurContractItemNotes.PurgDocNoteCreatedBy,
      I_CntrlPurContractItemNotes.PurgDocNoteCreationDateTime,
      I_CntrlPurContractItemNotes.PurgDocNoteLastChangedBy,
      I_CntrlPurContractItemNotes.PurgDocNoteLastChangedDateTime,
      I_CntrlPurContractItemNotes.PurgDocNoteText,

      I_CntrlPurContractItemNotes.CentralPurchaseContract,

      /* Derived fields */
      cast( right( left(I_CntrlPurContractItemNotes.PurchasingDocumentNoteObjectID, 15), 5) as vdm_cntrlpurchasecontractitem ) as CentralPurchaseContractItem,
      _CentralPurchaseContract.LastChangeDateTime,

      /* Associations */
      _CentralPurchaseContract,
      _CntrlPurchaseContractItem,
      I_CntrlPurContractItemNotes._LanguageDef,
      I_CntrlPurContractItemNotes._NoteTypeDef

}
where
  _CentralPurchaseContract.CentralPurchaseContract is not null;

Learn More