P_WRKCTRAVAILABLECAPSHIFT

@AbapCatalog.sqlViewName: 'PWCAVLCAPSHFT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'Work Center Available Capacity Shift'

define view P_WrkCtrAvailableCapShift
  as select from I_AvailableCapacityShift
  association [1..1] to P_WorkCenterCapacityCalc       as _Capacity on  $projection.CapacityInternalID = _Capacity.CapacityInternalID

  association [1..1] to I_WorkCenterCapacityInterval_2 as _Interval on  $projection.CapacityInternalID    = _Interval.CapacityInternalID
                                                                    and $projection.AvailableCapacityType = _Interval.CapacityActiveVersion
                                                                    and $projection.ValidityEndDate       = _Interval.IntervalEndDate
{
  key CapacityInternalID,
  key AvailableCapacityType,
  key ValidityEndDate,
  key WeekDay,
  key AvailableCapacityShift,

      cast(coalesce(_Interval.WorkDayRule,'')as workdayrule preserving type ) as WorkDayRule,
      ShiftDefinition,

      CapacityNumberOfCapacities                                              as CapacityNumberOfCapacities,
      CapacityPlanUtilizationPercent                                          as CapacityPlanUtilizationPercent,

      cast(OperatingDurationInSeconds as abap.fltp)                           as OperatingDurationInSeconds,
      BreakDurationInSeconds                                                  as BreakDurationInSeconds,
      cast(TotOperatingDurationInSeconds as abap.fltp)                        as TotOperatingDurationInSeconds,
      _Interval.IntervalEndDate                                               as IntervalEndDate,
      _Interval.IntervalStartDate                                             as IntervalStartDate,
      _Capacity.ShiftGroup                                                    as ShiftGroup,
      _Capacity.ValidityEndDate                                               as CapacityEndDate,
      _Capacity.ValidityStartDate                                             as CapacityStartDate,
      CapacityStartTimeID                                                     as CapacityStartTimeID,
      CapacityEndTimeID                                                       as CapacityEndTimeID,
      _Capacity,
      _Interval
}