P_VARCONFIGNSALESDOCUMENTITEM

@AbapCatalog.sqlViewName: 'PAVCSALESDOCITEM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@VDM.viewType: #BASIC
@VDM.private: true

@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_VarConfignSalesDocumentItem
  as select from vbap as SalesDocumentItem
  association [1..1] to P_VarConfignSalesDocument as _SalesDocument on SalesDocumentItem.vbeln = _SalesDocument.SalesDocument
{
  key SalesDocumentItem.vbeln           as SalesDocument,
  key SalesDocumentItem.posnr           as SalesDocumentItem,

      _SalesDocument.SDDocumentCategory as SDDocumentCategory,

      SalesDocumentItem.matnr           as Product,
      SalesDocumentItem.werks           as Plant,
      SalesDocumentItem.ernam           as CreatedByUser,
      SalesDocumentItem.erdat           as CreationDate,
      case
        when SalesDocumentItem.aedat = '00000000'
             or SalesDocumentItem.aedat is null
             then SalesDocumentItem.erdat
        else SalesDocumentItem.aedat
      end                               as LastChangeDate,

      case
        when SalesDocumentItem.aedat = '00000000'
             or SalesDocumentItem.aedat is null
             then SalesDocumentItem.ernam
        else _SalesDocument.LastChangedByUser
      end                               as LastChangedByUser,

      SalesDocumentItem.cuobj           as ProductConfiguration,
      SalesDocumentItem.kwmeng          as OrderQuantity,

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      cast(
        case
          when SalesDocumentItem.umvkn != 0
               then SalesDocumentItem.kwmeng * division(SalesDocumentItem.umvkz, SalesDocumentItem.umvkn, 3)
          else SalesDocumentItem.kwmeng
        end as abap.quan(15,3))         as OrderQuantityInBaseUnit,
      @Semantics.unitOfMeasure: true
      SalesDocumentItem.meins           as BaseUnit
}
where
  //Only configured Sales Document Items are relevant

  cuobj != '000000000000000000'
  and
  //inidicator whether the item is directly configurable

  //if it belongs to another item then it is configured through it

  uepos is initial