P_SALESDOCITEMCOMPLETEPARTNER

CDS View

P_SALESDOCITEMCOMPLETEPARTNER is a CDS View in S/4HANA. It contains 24 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 24 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_SalesDocItemCompletePartner view from COMPOSITE Sales Doc Item and Inherited Partners

Fields (24)

KeyField CDS FieldsUsed in Views
KEY PartnerFunction PartnerFunction 1
KEY SalesDocument SalesDocument 1
KEY SalesDocumentItem SalesDocumentItem 1
_Address _Address 1
_BPRefAddressForDocSpcfcAddr _BPRefAddressForDocSpcfcAddr 1
_BusinessPartnerAddress _BusinessPartnerAddress 1
_DfltAddrRprstn _DfltAddrRprstn 1
_PartnerFunction _PartnerFunction 1
_SalesDocument _SalesDocument 1
_SalesDocumentItem _SalesDocumentItem 1
AddressID AddressID 1
AddressObjectType AddressObjectType 1
AddressPersonID AddressPersonID 1
BPAddrDeterminationTransaction BPAddrDeterminationTransaction 1
BPRefAddressIDForDocSpcfcAddr BPRefAddressIDForDocSpcfcAddr 1
ContactPerson ContactPerson 1
Customer Customer 1
PartnerIsSpecificForSDDocItem PartnerIsSpecificForSDDocItem 1
Personnel Personnel 1
ReferenceBusinessPartner ReferenceBusinessPartner 1
SDDocPartnerAddressRefType SDDocPartnerAddressRefType 1
Supplier Supplier 1
UnloadingPointName UnloadingPointName 1
VATRegistration VATRegistration 1 
@AbapCatalog: {
  sqlViewName: 'PSDOCITMCMPLPT',
  compiler.compareFilter: true,
  preserveKey: true
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
   representativeKey: 'PartnerFunction',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   }
}

@VDM: {
  private: true,
  viewType: #COMPOSITE
}

@AccessControl: { 
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [ '_DfltAddrRprstn' ]
}

@Metadata.ignorePropagatedAnnotations:true
define view P_SalesDocItemCompletePartner 
  as select from I_SalesDocumentItemPartner as ItemPartner 
                                                                
  association [0..1] to I_ContactPerson     as _ContactPerson   on $projection.ContactPerson = _ContactPerson.ContactPerson
  
{
      @ObjectModel.foreignKey.association: '_SalesDocument' 
  key ItemPartner.SalesDocument,
      @ObjectModel.foreignKey.association: '_SalesDocumentItem' 
  key ItemPartner.SalesDocumentItem,
      @ObjectModel.foreignKey.association: '_PartnerFunction' 
  key ItemPartner.PartnerFunction,
  
      ItemPartner.Customer,
      
      ItemPartner.Supplier,
      
      ItemPartner.ContactPerson,
      
      ItemPartner.ReferenceBusinessPartner,
      
      ItemPartner.Personnel,
      
      ItemPartner.AddressID,
      
      ItemPartner.AddressPersonID,
      
      ItemPartner.AddressObjectType,
      
      ItemPartner.SDDocPartnerAddressRefType,
      
      ItemPartner.BPAddrDeterminationTransaction,
      
      ItemPartner.BPRefAddressIDForDocSpcfcAddr,
      
      ItemPartner.VATRegistration,

      @Semantics.text: true
      ItemPartner.UnloadingPointName,
      
      cast ( 'X' as sd_partner_item_ind)               as PartnerIsSpecificForSDDocItem,
   
      /* Associations */   
      ItemPartner._Address, 
      ItemPartner._DfltAddrRprstn, 
      ItemPartner._BusinessPartnerAddress,  
      ItemPartner._BPRefAddressForDocSpcfcAddr,    
      ItemPartner._SalesDocument,  
      ItemPartner._SalesDocumentItem,     
      ItemPartner._PartnerFunction, 
      _ContactPerson
}

union all 
 
select from P_SalesDocItemInheritedPartner as InheritedPartner
                                                                  
  association[1..1] to I_SalesDocumentItem as _SalesDocumentItem on  $projection.SalesDocument     = _SalesDocumentItem.SalesDocument
                                                                 and $projection.SalesDocumentItem = _SalesDocumentItem.SalesDocumentItem
{
      @ObjectModel.foreignKey.association: '_SalesDocument' 
  key InheritedPartner.SalesDocument,
      @ObjectModel.foreignKey.association: '_SalesDocumentItem' 
  key InheritedPartner.SalesDocumentItem,
      @ObjectModel.foreignKey.association: '_PartnerFunction' 
  key InheritedPartner.PartnerFunction,
  
      InheritedPartner.Customer,
      
      InheritedPartner.Supplier,
      
      InheritedPartner.ContactPerson,
      
      InheritedPartner.ReferenceBusinessPartner,
      
      InheritedPartner.Personnel,
      
      InheritedPartner.AddressID,
      
      InheritedPartner.AddressPersonID,
      
      InheritedPartner.AddressObjectType,
      
      InheritedPartner.SDDocPartnerAddressRefType,
      
      InheritedPartner.BPAddrDeterminationTransaction,
      
      InheritedPartner.BPRefAddressIDForDocSpcfcAddr,
      
      InheritedPartner.VATRegistration,

      @Semantics.text: true
      InheritedPartner.UnloadingPointName,
      
      cast ( ' ' as sd_partner_item_ind)               as PartnerIsSpecificForSDDocItem,
      
      /* Associations */   
      InheritedPartner._Address,
      InheritedPartner._DfltAddrRprstn,    
      InheritedPartner._BusinessPartnerAddress,    
      InheritedPartner._BPRefAddressForDocSpcfcAddr,    
      InheritedPartner._SalesDocument, 
      _SalesDocumentItem,
      InheritedPartner._PartnerFunction, 
      InheritedPartner._ContactPerson
}

Learn More