P_PURCHASEORDERSCHEDULELINE1

CDS View

P_PURCHASEORDERSCHEDULELINE1 is a CDS View in S/4HANA. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_OverdueNotReleased view left_outer CONSUMPTION 
@AbapCatalog.sqlViewName: 'PMMPOSCHELINE1'
//@ClientDependent: true

@AbapCatalog.compiler.compareFilter: true
@VDM.viewType : #CONSUMPTION
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@VDM.private : true
@AccessControl.personalData.blocking: #NOT_REQUIRED
define view P_PurchaseOrderScheduleLine1 as select from I_PurgDocScheduleLine 

  association [1..1] to I_PurchaseOrder           as _PurchaseOrder             on  $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder
  association [1..1] to I_PurchaseOrderItem       as _PurchaseOrderItem         on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                                and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
  association [0..1] to I_UnitOfMeasure           as _PurchaseOrderQuantityUnit on  $projection.PurchaseOrderQuantityUnit = _PurchaseOrderQuantityUnit.UnitOfMeasure
  association [0..1] to I_Currency                as _Currency                  on  $projection.Currency = _Currency.Currency

  
{
    
      @ObjectModel.foreignKey.association: '_PurchaseOrder'
  key PurchasingDocument                                 as PurchaseOrder,
      @ObjectModel.foreignKey.association: '_PurchaseOrderItem'
  key PurchasingDocumentItem                             as PurchaseOrderItem,

  key ScheduleLine                                       as ScheduleLine,

     ScheduleLineDeliveryDate ,

      SchedLineStscDeliveryDate,

      PerformancePeriodStartDate,

      PerformancePeriodEndDate,

      ScheduleLineDeliveryTime,
      PurchasingDocument,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      @DefaultAggregation: #SUM
      ScheduleLineOrderQuantity,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      @DefaultAggregation: #SUM
      RoughGoodsReceiptQty,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      @DefaultAggregation: #SUM
      (ScheduleLineOrderQuantity - RoughGoodsReceiptQty) as OpenPurchaseOrderQuantity,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_PurchaseOrderQuantityUnit'
      _PurchaseOrderItem.PurchaseOrderQuantityUnit       as PurchaseOrderQuantityUnit,

      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_Currency'
      _PurchaseOrderItem.DocumentCurrency                as Currency,

      @DefaultAggregation: #SUM
      cast(
      case when _PurchaseOrderItem.OrderQuantity != 0  
             then (  ScheduleLineOrderQuantity - RoughGoodsReceiptQty) *
              DIVISION( _PurchaseOrderItem.NetAmount , _PurchaseOrderItem.OrderQuantity, 3 )
           else   0 end
      as abap.curr( 21, 3 ))                             as OpenPurchaseOrderNetAmount,

      I_PurgDocScheduleLine.PurchaseRequisition,

      I_PurgDocScheduleLine.PurchaseRequisitionItem,

      _PurchaseOrder,
      _PurchaseOrderItem,
      _PurchaseOrderQuantityUnit,
      _Currency

      
      
}
where _PurchaseOrder.PurchasingDocumentDeletionCode != 'X'

Learn More