P_PPM_PROJECTIMAGE

@VDM.private: true
@VDM.viewType: #COMPOSITE

@AbapCatalog.sqlViewName: 'PPPMPROIMAGE'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ObjectModel.representativeKey: 'ProjectUUID'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED

// @EndUserText.label: 'Icon image URL for a portfolio item'

define view P_PPM_ProjectImage as select from I_PPM_ItemInfo as ItemInfo
            inner join /rpm/document as document
                                  on document.entity_type = 'PPO'
                                  and document.entity_guid = ItemInfo.PortfolioItemUUID
                                  and is_thumbnail = 'X' {                                             
  key ItemInfo.ProjectUUID,
  ItemInfo.PortfolioItemUUID ,
  ItemInfo.PortfolioUUID,
  //project image url has to be enhanced with prefix <protocol>://<hostname>:<portnumer>

  //this information is only available on the application server

  cast(
  concat('/sap/rpm_file?sap-client=', 
        concat(ItemInfo.mandt,
        concat('&PORTFOLIO_GUID=',
        concat(bintohex(ItemInfo.PortfolioUUID),
        concat('&PARENT_GUID=',
        concat(bintohex(ItemInfo.ParentObjectUUID),
        concat('&OBJ_GUID=',
        concat(bintohex(ItemInfo.PortfolioItemUUID),
        concat('&DOCUMENT_GUID=',
        concat(bintohex(document.guid),'&NO_AUTH_CHECK=X&OBJ_TYPE=RIH&PARENT_TYPE=RBH'    
        )))))))))) as /s4ppm/tv_image_url ) as ProjectImageURL
}