P_FIXEDASSETLINEITEM1

@AbapCatalog: {sqlViewName: 'PFASSETLINEITEM', preserveKey: true, compiler.compareFilter: true, buffering.status: #NOT_ALLOWED}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_FixedAssetLineItem1
  as select from           I_FxdAstActualLineItem as acdoca
    left outer to one join I_CompanyCode on I_CompanyCode.CompanyCode = acdoca.CompanyCode
{
  key  acdoca.AssetDepreciationArea,
  key  acdoca.CompanyCode,
  key  acdoca.FiscalYear,
  key  acdoca.MasterFixedAsset,
  key  acdoca.FixedAsset,
  key  acdoca.SubLedgerAcctLineItemType,
  key  acdoca.FiscalPeriod,
  key  cast('' as faa_deprecated_target_ldgrp)                             as LedgerGroup,
  key  acdoca.AccountingDocument,
  key  LedgerGLLineItem,
  key  acdoca.Ledger,
  key  acdoca.TransactionSubitem,
  key  acdoca.DebitCreditCode,

       acdoca.AccountingPrinciple,
       @Semantics.fiscal.year: true
       acdoca.LedgerFiscalYear,
       @Semantics.fiscal.yearVariant: true
       acdoca.FiscalYearVariant,
       @Semantics.fiscal.yearPeriod: true
       acdoca.FiscalYearPeriod,

       acdoca.ChartOfAccounts,
       acdoca.GLAccount,
       acdoca.CountryChartOfAccounts,
       cast(acdoca.AlternativeGLAccount as fis_altkt_skb1 preserving type) as AlternativeGLAccount,
       IsStatisticalDocument,
       acdoca.AssetAcctTransClassfctn,
       acdoca.GroupMasterFixedAsset,
       acdoca.GroupFixedAsset,
       acdoca.FinancialAccountType,
       acdoca.ChartOfDepreciation,

       acdoca.ReferenceDocumentItem,
       acdoca.ReferenceDocumentType,
       acdoca.LogicalSystem,
       acdoca.ReferenceDocument,
       acdoca.ReferenceDocumentContext,
       cast(acdoca.ReversalReferenceDocument as fis_stblg preserving type) as ReversalReferenceDocument,
       acdoca.ReversalReferenceDocumentCntxt,
       acdoca.IsReversal,
       acdoca.IsReversed,
       acdoca.DocumentDate,
       acdoca.PostingDate,
       acdoca.AssetTransactionType,
       acdoca.AssetValueDate,
       @Semantics.businessDate.at: true
       acdoca.AccountingDocumentCreationDate,
       acdoca.CreationTime,
       acdoca.DocumentItemText,
       acdoca.AccountingDocCreatedByUser,
       acdoca.GLBusinessTransactionType,
       acdoca.AssignmentReference,
       acdoca.JointVentureCostRecoveryCode,
       acdoca.DepreciationFiscalPeriod,
       acdoca.AccountingDocumentItem,
       acdoca.ReversalTransactionSubitem,

       acdoca.PurchasingDocument,
       acdoca.PurchasingDocumentItem,

       acdoca.CostCenter,
       acdoca.Plant,
       acdoca.BusinessArea,
       acdoca.PersonnelNumber,
       acdoca.FinancialManagementArea,
       acdoca.Fund,
       acdoca.GrantID,
       acdoca.FunctionalArea,
       acdoca.BudgetPeriod,
       acdoca.ProfitCenter,
       acdoca.Segment,
       acdoca.ControllingArea,
       I_CompanyCode.Country,
       acdoca.FundsCenter,
       AccountingDocumentType,

       acdoca.PartnerMasterFixedAsset,
       acdoca.PartnerFixedAsset,
       acdoca.JrnlEntryItemMigrationSource,

       //Measures

       @Semantics.currencyCode:true
       acdoca.CompanyCodeCurrency,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
       acdoca.AmountInCompanyCodeCurrency,

       @Semantics.currencyCode:true
       acdoca.GlobalCurrency,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
       acdoca.AmountInGlobalCurrency,

       @Semantics.currencyCode:true
       acdoca.FunctionalCurrency,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
       acdoca.AmountInFunctionalCurrency,

       @Semantics.currencyCode:true
       acdoca.FreeDefinedCurrency1,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
       acdoca.AmountInFreeDefinedCurrency1,

       @Semantics.currencyCode:true
       acdoca.FreeDefinedCurrency2,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
       acdoca.AmountInFreeDefinedCurrency2,

       @Semantics.currencyCode:true
       acdoca.FreeDefinedCurrency3,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
       acdoca.AmountInFreeDefinedCurrency3,

       @Semantics.currencyCode:true
       acdoca.FreeDefinedCurrency4,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
       acdoca.AmountInFreeDefinedCurrency4,

       @Semantics.currencyCode:true
       acdoca.FreeDefinedCurrency5,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
       acdoca.AmountInFreeDefinedCurrency5,

       @Semantics.currencyCode:true
       acdoca.FreeDefinedCurrency6,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
       acdoca.AmountInFreeDefinedCurrency6,

       @Semantics.currencyCode:true
       acdoca.FreeDefinedCurrency7,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
       acdoca.AmountInFreeDefinedCurrency7,

       @Semantics.currencyCode:true
       acdoca.FreeDefinedCurrency8,
       @DefaultAggregation: #SUM
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
       acdoca.AmountInFreeDefinedCurrency8,

       @Semantics.unitOfMeasure:true
       acdoca.BaseUnit,
       @DefaultAggregation: #SUM
       @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
       acdoca.Quantity
}


union all select from    I_FxdAstStatisticalLineItem as docit
  left outer to one join I_CompanyCode               on I_CompanyCode.CompanyCode = docit.CompanyCode
  inner join             I_AssetRedesignSwitchStatus on I_AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = ''
{
  key docit.AssetDepreciationArea,
  key docit.CompanyCode,
  key docit.FiscalYear,
  key docit.MasterFixedAsset,
  key docit.FixedAsset,
  key docit.SubLedgerAcctLineItemType,
  key docit.FiscalPeriod,
  key docit.LedgerGroup,
  key cast('' as fis_belnr)                            as AccountingDocument,
  key cast('' as fis_docln)                            as LedgerGLLineItem,
      docit.Ledger                                     as Ledger,
  key docit.TransactionSubitem,
  key docit.DebitCreditCode,

      docit.AccountingPrinciple,
      @Semantics.fiscal.year: true
      LedgerFiscalYear,
      @Semantics.fiscal.yearVariant: true
      cast('' as periv )                               as FiscalYearVariant,
      @Semantics.fiscal.yearPeriod: true
      cast('0000000' as jahrper)                       as FiscalYearPeriod,

      cast(I_CompanyCode.ChartOfAccounts as fis_ktopl) as ChartOfAccounts,
      cast('' as fagl_hkont)                           as GLAccount,
      I_CompanyCode.CountryChartOfAccounts             as CountryChartOfAccounts,
      cast('' as  fis_altkt_skb1)                      as AlternativeGLAccount,

      cast( 'X' as boolean )                           as IsStatisticalDocument,
      docit.AssetAcctTransClassfctn,
      docit.GroupMasterFixedAsset,
      docit.GroupFixedAsset,
      cast('A' as fis_koart)                           as FinancialAccountType,
      docit.ChartOfDepreciation,

      docit.ReferenceDocumentItem,
      docit.ReferenceDocumentType,
      docit.LogicalSystem,
      docit.ReferenceDocument,
      docit.ReferenceDocumentContext,
      docit.ReversalReferenceDocument,
      docit.ReversalReferenceDocumentCntxt,
      docit.IsReversal,
      docit.IsReversed,
      docit.DocumentDate,
      docit.PostingDate,

      docit.AssetTransactionType,
      docit.AssetValueDate,
      @Semantics.businessDate.at: true
      docit.AccountingDocumentCreationDate,
      docit.CreationTime,
      docit.DocumentItemText,
      docit.AccountingDocCreatedByUser,
      docit.GLBusinessTransactionType,
      docit.AssignmentReference,
      docit.JointVentureCostRecoveryCode,
      cast('000' as fis_peraf)                         as DepreciationFiscalPeriod,
      cast('' as buzei)                                as AccountingDocumentItem,
      cast('' as fins_subta_rev)                       as ReversalTransactionSubitem,

      cast('' as fis_ebeln)                            as PurchasingDocument,
      cast('' as fis_ebelp)                            as PurchasingDocumentItem,

      cast('' as kostl)                                as CostCenter,
      cast('' as werks_d)                              as Plant,
      cast('' as gsber)                                as BusinessArea,
      cast('' as pernr_d)                              as PersonnelNumber,

      I_CompanyCode.FinancialManagementArea,
      cast('' as bp_geber)                             as Fund,
      cast('' as gm_grant_nbr)                         as GrantID,
      cast('' as fm_farea)                             as FunctionalArea,
      cast('' as fm_budget_period)                     as BudgetPeriod,
      cast('' as prctr)                                as ProfitCenter,
      cast('' as fb_segment)                           as Segment,
      I_CompanyCode.ControllingArea,
      I_CompanyCode.Country,
      cast('' as fistl)                                as FundsCenter,
      cast('' as fis_blart)                            as AccountingDocumentType,

      docit.PartnerMasterFixedAsset,
      docit.PartnerFixedAsset,
      cast('' as fis_acdoc_mig_source)                 as JrnlEntryItemMigrationSource,

      //Measures

      @Semantics.currencyCode:true
      docit.CompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      docit.AmountInCompanyCodeCurrency,

      @Semantics.currencyCode:true
      docit.GlobalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      docit.AmountInGlobalCurrency,

      @Semantics.currencyCode:true
      cast('' as fins_currfc)                          as FunctionalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      cast(0 as fins_vfccur12)                         as AmountInFunctionalCurrency,

      @Semantics.currencyCode:true
      docit.FreeDefinedCurrency1,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      docit.AmountInFreeDefinedCurrency1,

      @Semantics.currencyCode:true
      docit.FreeDefinedCurrency2,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      docit.AmountInFreeDefinedCurrency2,

      @Semantics.currencyCode:true
      docit.FreeDefinedCurrency3,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      docit.AmountInFreeDefinedCurrency3,

      @Semantics.currencyCode:true
      docit.FreeDefinedCurrency4,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      docit.AmountInFreeDefinedCurrency4,

      @Semantics.currencyCode:true
      docit.FreeDefinedCurrency5,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      docit.AmountInFreeDefinedCurrency5,

      @Semantics.currencyCode:true
      docit.FreeDefinedCurrency6,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      docit.AmountInFreeDefinedCurrency6,

      @Semantics.currencyCode:true
      docit.FreeDefinedCurrency7,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      docit.AmountInFreeDefinedCurrency7,

      @Semantics.currencyCode:true
      docit.FreeDefinedCurrency8,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      docit.AmountInFreeDefinedCurrency8,

      @Semantics.unitOfMeasure:true
      cast ('' as meins)                               as BaseUnit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      cast (0 as quan1_12)                             as Quantity
}

union all select from    I_AssetSimulatedDueDeprValues as duevalues
  left outer to one join I_CompanyCode                  on I_CompanyCode.CompanyCode = duevalues.CompanyCode
  left outer to one join I_ChartOfDeprForAcctgPrinciple on  I_ChartOfDeprForAcctgPrinciple.AccountingPrinciple = duevalues.AccountingPrinciple
                                                        and I_ChartOfDeprForAcctgPrinciple.CompanyCode         = duevalues.CompanyCode
  inner join             I_AssetRedesignSwitchStatus    on I_AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = 'X'
{
  key duevalues.AssetDepreciationArea,
  key duevalues.CompanyCode,
  key duevalues.FiscalYear,
  key duevalues.MasterFixedAsset,
  key duevalues.FixedAsset,
  key duevalues.SubLedgerAcctLineItemType,
  key duevalues.FiscalPeriod,
  key duevalues.LedgerGroup,
  key cast('' as fis_belnr)                            as AccountingDocument,
  key cast('' as fis_docln)                            as LedgerGLLineItem,
      duevalues.Ledger,
  key cast('000000' as fins_subta)                     as TransactionSubitem,
  key cast('' as shkzg)                                as DebitCreditCode,

      duevalues.AccountingPrinciple,
      @Semantics.fiscal.year: true
      LedgerFiscalYear                                 as LedgerFiscalYear,
      @Semantics.fiscal.yearVariant: true
      I_CompanyCode.FiscalYearVariant,
      @Semantics.fiscal.yearPeriod: true
      cast('0000000' as jahrper)                       as FiscalYearPeriod,

      cast(I_CompanyCode.ChartOfAccounts as fis_ktopl) as ChartOfAccounts,
      cast('' as fagl_hkont)                           as GLAccount,
      I_CompanyCode.CountryChartOfAccounts             as CountryChartOfAccounts,
      cast('' as  fis_altkt_skb1)                      as AlternativeGLAccount,

      cast( 'X' as boolean )                           as IsStatisticalDocument,
      duevalues.AssetAcctTransClassfctn,
      duevalues.GroupMasterFixedAsset,
      duevalues.GroupFixedAsset,
      cast('A' as fis_koart)                           as FinancialAccountType,
      I_ChartOfDeprForAcctgPrinciple.ChartOfDepreciation,

      cast('000000' as fins_awitem)                    as ReferenceDocumentItem,
      cast('' as fis_awtyp)                            as ReferenceDocumentType,
      cast('' as logsystem)                            as LogicalSystem,
      cast('' as awref)                                as ReferenceDocument,
      cast('' as fis_aworg)                            as ReferenceDocumentContext,
      cast('' as fis_stblg)                            as ReversalReferenceDocument,
      cast('' as aworg_rev)                            as ReversalReferenceDocumentCntxt,
      cast('' as fins_xreversing)                      as IsReversal,
      cast('' as fins_xreversed)                       as IsReversed,
      cast('00000000' as fis_bldat)                    as DocumentDate,
      cast('00000000' as fis_budat)                    as PostingDate,

      duevalues.AssetTransactionType,
      cast('00000000' as bzdat)                        as AssetValueDate,
      @Semantics.businessDate.at: true
      cast('00000000' as fis_cpudt)                    as AccountingDocumentCreationDate,
      cast('000000' as fis_cputm)                      as CreationTime,
      cast('' as farp_sgtxt)                           as DocumentItemText,
      cast('' as fis_usnam)                            as AccountingDocCreatedByUser,
      cast('' as vorgn)                                as GLBusinessTransactionType,
      cast('' as fis_zuonr)                            as AssignmentReference,
      cast('' as jv_recind_cds)                        as JointVentureCostRecoveryCode,
      cast('000' as fis_peraf)                         as DepreciationFiscalPeriod,
      cast('' as buzei)                                as AccountingDocumentItem,
      cast('' as fins_subta_rev)                       as ReversalTransactionSubitem,

      cast('' as fis_ebeln)                            as PurchasingDocument,
      cast('' as fis_ebelp)                            as PurchasingDocumentItem,

      cast('' as kostl)                                as CostCenter,
      cast('' as werks_d)                              as Plant,
      cast('' as gsber)                                as BusinessArea,
      cast('' as pernr_d)                              as PersonnelNumber,
      I_CompanyCode.FinancialManagementArea,
      cast('' as bp_geber)                             as Fund,
      cast('' as gm_grant_nbr)                         as GrantID,
      cast('' as fm_farea)                             as FunctionalArea,
      cast('' as fm_budget_period)                     as BudgetPeriod,
      cast('' as prctr)                                as ProfitCenter,
      cast('' as fb_segment)                           as Segment,

      I_CompanyCode.ControllingArea,
      I_CompanyCode.Country,
      cast('' as fistl)                                as FundsCenter,
      cast('' as fis_blart)                            as AccountingDocumentType,

      cast('' as panl1)                                as PartnerMasterFixedAsset,
      cast('' as panl2)                                as PartnerFixedAsset,
      cast('' as fis_acdoc_mig_source)                 as JrnlEntryItemMigrationSource,

      //Measures

      @Semantics.currencyCode:true
      duevalues.CompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      duevalues.AmountInCompanyCodeCurrency,

      @Semantics.currencyCode:true
      duevalues.GlobalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      duevalues.AmountInGlobalCurrency,

      @Semantics.currencyCode:true
      cast('' as fins_currfc)                          as FunctionalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      cast(0 as fins_vfccur12)                         as AmountInFunctionalCurrency,

      @Semantics.currencyCode:true
      duevalues.FreeDefinedCurrency1,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      duevalues.AmountInFreeDefinedCurrency1,

      @Semantics.currencyCode:true
      duevalues.FreeDefinedCurrency2,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      duevalues.AmountInFreeDefinedCurrency2,

      @Semantics.currencyCode:true
      duevalues.FreeDefinedCurrency3,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      duevalues.AmountInFreeDefinedCurrency3,

      @Semantics.currencyCode:true
      duevalues.FreeDefinedCurrency4,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      duevalues.AmountInFreeDefinedCurrency4,

      @Semantics.currencyCode:true
      duevalues.FreeDefinedCurrency5,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      duevalues.AmountInFreeDefinedCurrency5,

      @Semantics.currencyCode:true
      duevalues.FreeDefinedCurrency6,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      duevalues.AmountInFreeDefinedCurrency6,

      @Semantics.currencyCode:true
      duevalues.FreeDefinedCurrency7,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      duevalues.AmountInFreeDefinedCurrency7,

      @Semantics.currencyCode:true
      duevalues.FreeDefinedCurrency8,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      duevalues.AmountInFreeDefinedCurrency8,

      @Semantics.unitOfMeasure:true
      cast ('' as meins)                               as BaseUnit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      cast (0 as quan1_12)                             as Quantity
}