P_DMVCACTIVITYMATERIALEDGE

@AbapCatalog.sqlViewName: 'PDMVCAMEDGE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK

@VDM.viewType: #COMPOSITE
@VDM.private:true
define view P_DMVCActivityMaterialEdge
  with parameters
    P_DateFrom     : calendardate,
    P_DateTo       : calendardate,
    P_CurrencyType : fins_curtype,
    P_Ledger       : fins_ledger
  as select from           P_DMVCGroupedActyMaterialPair(P_DateFrom : :P_DateFrom,P_DateTo : :P_DateTo,P_CurrencyType : :P_CurrencyType, P_Ledger: :P_Ledger ) as _Edge

    left outer to one join P_MLMaterialHeader                                                                                                                            as _MaterialHeader on _MaterialHeader.CostEstimate = _Edge.MaterialValueChainNodeFrom
                                                                                                                                                                                            or _MaterialHeader.CostEstimate = _Edge.MaterialValueChainNodeTo

  association [0..1] to P_DMVCMaterialActivity as _Activity on _Activity.CostEstimate = _Edge.MaterialValueChainNodeFrom
                                                            or _Activity.CostEstimate = _Edge.MaterialValueChainNodeTo                                                                                                                                                                                            
{
  key MaterialValueChainNodeFrom,
  key MaterialValueChainNodeTo,

  key ProcessCategory,

      case when _MaterialHeader.ValuationArea is not initial then _MaterialHeader.ValuationArea
      else _Activity(P_DateFrom: :P_DateFrom, P_DateTo: :P_DateTo, P_CurrencyType: :P_CurrencyType, P_Ledger: :P_Ledger).ValuationArea end as ValuationArea,


      // Quantities

      @Semantics.quantity.unitOfMeasure: 'ValuationQuantityUnit'
      cast( ValuationQuantity as fml_dmvc_valuation_quantity preserving type )       as ValuationQuantity,

      @Semantics.unitOfMeasure:true
      cast( ValuationQuantityUnit as fml_dmvc_valn_quantity_unit preserving type )   as ValuationQuantityUnit,


      // Amounts

      @Semantics.amount.currencyCode: 'Currency'
      cast( InventoryAmtInCCCrcy as fml_dmvc_inventory_amt_cc_crcy preserving type ) as InventoryAmtInCCCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      PriceDifferenceAmtInCCCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      ExchRateDiffAmtInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      cast( InventoryAmtInCCCrcy + PriceDifferenceAmtInCCCrcy + ExchRateDiffAmtInCoCodeCrcy as kkb_ml_ges) as ActlInventoryAmtInCCCrcy,

      @Semantics.currencyCode:true
      Currency
}