P_CUSTRETPROCFLOW0

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'PCUSTRETPROCF0'

define view P_CustRetProcFlow0
as select from I_SalesDocumentBasic as CustRet
       
{
    //Key

    key cast( ' ' as vbeln_von) as Level1Document,
    key cast( ' ' as posnr_von) as Level1DocumentItem,
   
    //Customer Return

    key CustRet.SalesDocument   as CustomerReturn,
   
    //Category

    CustRet.SalesDocumentType   as CustomerReturnType,
    CustRet.SDDocumentCategory,
       
    //Organization

    CustRet.SalesOrganization,
    CustRet.DistributionChannel,
    CustRet.OrganizationDivision,
    
    //ARM-based Process Identification Number

    CustRet.RetsMgmtProcess,
    
    //Relevance for planned subsequent process steps 

    case 
    when ( ( CustRet.OverallTotalDeliveryStatus = 'A' or
             CustRet.OverallTotalDeliveryStatus = 'B' )
     and CustRet.RetsMgmtProcess != '' )                          --- planned subsequent delivery for ARM-based Customer Returns only      
     then
       'X'
     else 
       ''
     end                         as DeliveryDocumentIsRequired,
    
    cast('' as boolean)          as PlndSubsqntCrdtMemoReqIsRqd,  --- planned subsequent credit memo request
    cast('' as boolean)          as PlndSubsqntRplcmtOrderIsRqd   --- planned subsequent replacement order
}
where CustRet.SDDocumentCategory = 'H'   --> Customer Return