P_CHANGEDOCUMENTITEM2

CDS View

P_CHANGEDOCUMENTITEM2 is a CDS View in S/4HANA. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
P_ChangeDocumentItem3 view from CONSUMPTION
P_InfoRecordPriceVariance view left_outer CONSUMPTION
P_PurContractPriceVariance1 view left_outer CONSUMPTION 
@AbapCatalog.sqlViewName: 'PMMPCHGEDOCITEM2'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType : #CONSUMPTION
@VDM.private: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

define view P_ChangeDocumentItem2
    with parameters 
      P_StartDate       : vdm_validitystart,
      P_EndDate         : vdm_validityend
    
 as select from P_ChangeDocumentItem 
 
{
  key ChangeDocObject,
  key DatabaseTable,
  key ChangeDocument,
  key cast('X' as abap.char( 1 )) as IsDocumentChanged,
  
  cast(substring(ChangeDocTableKey,14,18) as abap.numc( 5 )) as Item,
  cast(substring(ChangeDocTableKey,14,17) as abap.char( 4 )) as PurchasingOrganization,
  cast(substring(ChangeDocTableKey,18,18) as abap.char( 1 )) as PurchasingInfoRecordCategory,
  cast(substring(ChangeDocTableKey,19,22) as abap.char( 4 )) as Plant,
  
  ChangeDocNewCurrency as Currency,
  ChangeDocNewFieldValue as NetPriceAmount,
  CreationDate,
  NewFieldValAfterDecimal as ValueAfterDecimal,
  
  cast(1 as abap.int4) as NumberOfChanges,
  cast(1 as abap.int4) as NumberOfPriceChanges
  
} where CreationDate between $parameters.P_StartDate and $parameters.P_EndDate
 
 union all select from P_ChangeDocumentItem as Item1
  inner join P_ChangeDocumentItem1 (P_StartDate: $parameters.P_StartDate,
                                                         P_EndDate: $parameters.P_EndDate) as Item2
  on Item1.ChangeDocObject    = Item2.ChangeDocObject
  and Item1.CreationDateTime  = Item2.CreationDateTime
  
{
  key Item1.ChangeDocObject,
  key Item1.DatabaseTable,
  key cast('' as cdchangenr ) as  ChangeDocument,
  key cast('' as abap.char( 1 )) as IsDocumentChanged,
  
  cast(substring(ChangeDocTableKey,14,18) as abap.numc( 5 )) as Item,
  cast(substring(ChangeDocTableKey,14,17) as abap.char( 4 )) as PurchasingOrganization,
  cast(substring(ChangeDocTableKey,18,18) as abap.char( 1 )) as PurchasingInfoRecordCategory,
  cast(substring(ChangeDocTableKey,19,22) as abap.char( 4 )) as Plant,
    
  Item1.ChangeDocPreviousCurrency as Currency,
  Item1.ChangeDocPreviousFieldValue as NetPriceAmount,
  Item1.CreationDate,
  Item1.PreviousFieldValAfterDecimal as ValueAfterDecimal,
  cast(0 as abap.int4) as NumberOfChanges,
  cast(1 as abap.int4) as NumberOfPriceChanges
  
} where CreationDate between $parameters.P_StartDate and $parameters.P_EndDate

Learn More