P_CADOCUMENTSUMCLEAREDITEM

CDS View

Summarized Cleared Items

P_CADOCUMENTSUMCLEAREDITEM is a CDS View in S/4HANA. Summarized Cleared Items. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_CADocumentSumClearedItem view_entity from CONSUMPTION Summarized Cleared Items 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Summarized Cleared Items'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}


@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_CADocumentSumClearedItem
  as select from I_CADocumentBPItem
{
      @ObjectModel.foreignKey.association: '_ClearingDocHeader'
  key CAClearingDocumentNumber,
      @ObjectModel.foreignKey.association: '_CompCode'
  key CompanyCode,
      @ObjectModel.foreignKey.association: '_BusinessArea'
  key BusinessArea,
      @ObjectModel.foreignKey.association: '_Division'
  key Division,
  key BusinessPartner,
      @ObjectModel.foreignKey.association: '_CAPartner'
  key ContractAccount,
      @ObjectModel.foreignKey.association: '_Currency'
  key TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast(sum(CAAmountInTransactionCurrency) as betrw_kk) as CAAmountInTransactionCurrency,

      @EndUserText.label: 'Number'
      count(*)                                             as NumberOfCADocumentItems,
      
      cast(max(CADocumentNumber) as opbel_kk) as CADocumentNumber,
      cast(max(CABPItemNumber) as opupk_kk ) as CABPItemNumber,
      cast(max(CASubItemNumber) as opupz_kk ) as CASubItemNumber,
      cast(max(CARepetitionItemNumber) as opupw_kk ) as CARepetitionItemNumber,

      //Associations

      _ClearingDocHeader,
      _BusinessArea,
      _CompCode,
      _Division,
      _BusinessPartner,
      _CAPartner,
      _Currency


}
where
  CAClearingDocumentNumber <> ''
group by
  CAClearingDocumentNumber,
  CompanyCode,
  BusinessArea,
  Division,
  BusinessPartner,
  ContractAccount,
  TransactionCurrency

Learn More