I_UTILSINVCGDOCOUTSRTGDATA

CDS View

Outsorting Data for Invoicing Document

I_UTILSINVCGDOCOUTSRTGDATA is a CDS View in S/4HANA. Outsorting Data for Invoicing Document. It contains 7 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 7 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_UtilsInvcgDocOutsrtgData view from CONSUMPTION Outsorting Data for Invoicing Document
I_UtilsInvcgDocOutsrtgDataCntr view from COMPOSITE Number of Automatically Outsorted Invoicing Documents
I_UtilsInvcgDocOutsrtgDataRsn view from COMPOSITE First Record for Manually Outsorted Invoicing Document

Fields (7)

KeyField CDS FieldsUsed in Views
KEY UtilitiesInvoicingDocument UtilitiesInvoicingDocument 3
KEY UtilsInvcgDocSqncNmbrOutsrtg UtilsInvcgDocSqncNmbrOutsrtg 1
_UtilitiesInvoicingCheck _UtilitiesInvoicingCheck 1
_UtilitiesInvoicingDocument _UtilitiesInvoicingDocument 3
UtilitiesInvoicingCheck UtilitiesInvoicingCheck 1
UtilsInvcgDocIsReldBackground UtilsInvcgDocIsReldBackground 1
UtilsOutsrtdInvcgDocDvtgValue UtilsOutsrtdInvcgDocDvtgValue 1 
@EndUserText.label: 'Outsorting Data for Invoicing Document'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IEINVCGDOUTDATA'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L //or XL

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'UtilsInvcgDocSqncNmbrOutsrtg'
@Metadata.allowExtensions:true
@AbapCatalog.compiler.compareFilter:true
//@AbapCatalog.preserveKey:true

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE ]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

define view I_UtilsInvcgDocOutsrtgData
  as select from erdo
  association [1..1] to I_UtilitiesInvoicingDocument as _UtilitiesInvoicingDocument on $projection.UtilitiesInvoicingDocument = _UtilitiesInvoicingDocument.UtilitiesInvoicingDocument
  association [0..1] to I_UtilitiesInvoicingCheck    as _UtilitiesInvoicingCheck    on $projection.UtilitiesInvoicingCheck = _UtilitiesInvoicingCheck.UtilitiesInvoicingCheck
  association [0..1] to I_UtilsInvcgMnlOutsortingRsn as _UtilsInvcgMnlOutsortingRsn on $projection.UtilsInvcgOutsortingReason = _UtilsInvcgMnlOutsortingRsn.UtilsInvcgOutsortingReason
{
      @ObjectModel.foreignKey.association: '_UtilitiesInvoicingDocument'
  key erdo.opbel                                                       as UtilitiesInvoicingDocument,

  key erdo.outcnso                                                     as UtilsInvcgDocSqncNmbrOutsrtg,

      @ObjectModel.foreignKey.association: '_UtilitiesInvoicingCheck'
      cast(erdo.validat_in as e_invcgcheck_vdm preserving type)        as UtilitiesInvoicingCheck,

      @ObjectModel.foreignKey.association: '_UtilsInvcgMnlOutsortingRsn'
      cast(erdo.manouts_in as e_outsrtngreasinvcg_vdm preserving type) as UtilsInvcgOutsortingReason,

      @Semantics.businessDate.at: true
      erdo.frei_am                                                     as UtilsInvcgDocReleaseDate,

      //      @Semantics.user.responsible: true

      erdo.frei_von                                                    as UtilsInvcgDocReleasedByUser,

      erdo.deviation                                                   as UtilsOutsrtdInvcgDocDvtgValue,
      @Semantics.booleanIndicator:true
      erdo.bgrd_release                                                as UtilsInvcgDocIsReldBackground,


      /* Associations */
      _UtilitiesInvoicingDocument,
      _UtilitiesInvoicingCheck,
      _UtilsInvcgMnlOutsortingRsn
}

Learn More