I_SRVCDOCCHANGEDOCUMENT

CDS View

Change Documents For Service

I_SRVCDOCCHANGEDOCUMENT is a CDS View in S/4HANA. Change Documents For Service. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_SrvcDocChangeDocument view from CONSUMPTION Change Documents For Service 
@AbapCatalog.sqlViewName: 'ISRVCDOCCD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Change Documents For Service'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM: {
  viewType: #COMPOSITE
}
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_SrvcDocChangeDocument
  //Change log for status

  as select from I_SrvcDocStatusChangeDocument
  association [0..1] to I_SystemStatusText as _SystemStatusText on  $projection.SrvcMgmtObjectStatus = _SystemStatusText.SystemStatus
                                                                and _SystemStatusText.Language       = $session.system_language

{
  key ChangeDocument,
  key ChangeDocObject,
  key cast('CRM_JEST'   as tabname)                                                                   as DatabaseTable,
  key ChangeDocTableKey,
  key cast ( 'STAT' as fieldname )                                                                    as ChangeDocDatabaseTableField,
  key ChangeDocChangeType,
  key SrvcMgmtObjectStatus,
      cast( _SystemStatusText[1: Language = $session.system_language].SystemStatusName as cdfldvaln ) as ChangeDocNewFieldValue,
      cast( ' ' as cdfldvaln )                                                                        as ChangeDocPreviousFieldValue,
      ServiceDocChangedDateTime,
      CreatedByUser,
      cast('' as cdobjecttxt)                                                                         as ChangeDocObjectDescription,
      cast( 'CRM_ORDER'  as cdobjectcl)                                                               as ChangeDocObjectClass

}

//Entries from Change documents(without status)

union all select from I_SrvcDocChgDocWithoutStatus
{

  key ChangeDocument,
  key ChangeDocObject,
  key DatabaseTable,
  key ChangeDocTableKey,
  key ChangeDocDatabaseTableField,
  key ChangeDocChangeType,
  key SrvcMgmtObjectStatus,
      ChangeDocNewFieldValue,
      ChangeDocPreviousFieldValue,
      ServiceDocChangedDateTime,
      CreatedByUser,
      ChangeDocObjectDescription,
      ChangeDocObjectClass


}

Learn More