I_SERVICEENTRYSHEETBASIC
Service Entry Sheet Basic
I_SERVICEENTRYSHEETBASIC is a CDS View in S/4HANA. Service Entry Sheet Basic. It contains 25 fields. 9 CDS views read from this table.
CDS Views using this table (9)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| A_ServiceEntrySheet | view | from | COMPOSITE | Service Entry Sheet |
| C_ServiceEntrySheetProcessFlow | view | inner | CONSUMPTION | Process Flow For Service Entry Sheet |
| C_ServiceEntrySheetProcessFlow | view | union_all | CONSUMPTION | Process Flow For Service Entry Sheet |
| C_SESWorkflowEmail | view | inner | CONSUMPTION | Email for SES Wfl Approval or Rejection |
| I_ServiceEntrySheet | view | from | COMPOSITE | Service Entry Sheet |
| I_ServiceEntrySheetAPI01 | view | from | BASIC | Service Entry Sheet |
| I_SESWorkflowStatus | view | from | COMPOSITE | Approval Status of Service Entry Sheet |
| I_SESWorkflowStatus | view | union_all | COMPOSITE | Approval Status of Service Entry Sheet |
| I_SrvcEntrShtCreationDate | view | from | COMPOSITE | Service Entry Sheet Creation Date |
Fields (25)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | ServiceEntrySheet | ServiceEntrySheet | 2 |
| _ApprovalStatusValueHelp | _ApprovalStatusValueHelp | 1 | |
| _ResponsiblePersonValueHelp | _ResponsiblePersonValueHelp | 1 | |
| _Supplier | _Supplier | 1 | |
| ApprovalDateTime | ApprovalDateTime | 1 | |
| ApprovalStatus | ApprovalStatus | 1 | |
| CreatedByUser | CreatedByUser | 1 | |
| Currency | Currency | 1 | |
| ExternalRevisionDateTime | ExternalRevisionDateTime | 1 | |
| IsDeleted | IsDeleted | 1 | |
| IsEndOfPurposeBlocked | IsEndOfPurposeBlocked | 2 | |
| LastChangeUser | LastChangeUser | 1 | |
| MaterialDocument | MaterialDocument | 1 | |
| MaterialDocumentYear | MaterialDocumentYear | 1 | |
| OriginObjectType | OriginObjectType | 1 | |
| PostingDate | PostingDate | 1 | |
| PricingDocument | PricingDocument | 1 | |
| PurchaseOrder | PurchaseOrder | 1 | |
| PurchasingGroup | PurchasingGroup | 2 | |
| PurchasingOrganization | PurchasingOrganization | 2 | |
| PurgDocExternalReference | PurgDocExternalReference | 1 | |
| PurgDocExternalSystem | PurgDocExternalSystem | 1 | |
| ResponsiblePerson | ResponsiblePerson | 1 | |
| ServiceEntrySheetName | ServiceEntrySheetName | 1 | |
| Supplier | Supplier | 1 |
@AbapCatalog.sqlViewName: 'ISRVCENTRSHTBSC'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_SESWorkflowStatus' ]
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Service Entry Sheet Basic'
@VDM.viewType : #BASIC
@ObjectModel: {
compositionRoot: true,
representativeKey: 'ServiceEntrySheet',
usageType.serviceQuality: #A,
usageType.sizeCategory: #L,
usageType.dataClass: #TRANSACTIONAL
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define view I_ServiceEntrySheetBasic
as select from mmpur_ses_header as Document
association [1..*] to I_ServiceEntrySheetItemBasic as _ServiceEntrySheetItem on $projection.ServiceEntrySheet = _ServiceEntrySheetItem.ServiceEntrySheet
association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [0..1] to I_SrvcEntrShtApprovalStatus as _ApprovalStatusValueHelp on $projection.ApprovalStatus = _ApprovalStatusValueHelp.ApprovalStatus
association [1..1] to I_SESWorkflowStatus as _SESWorkflowStatus on $projection.ServiceEntrySheet = _SESWorkflowStatus.ServiceEntrySheet
association [0..1] to I_SrvcEntrShtRespUsrValueHelp as _ResponsiblePersonValueHelp on $projection.ResponsiblePerson = _ResponsiblePersonValueHelp.EmploymentInternalID
association [0..1] to I_User as _CreatedByUser on $projection.CreatedByUser = _CreatedByUser.UserID
association [0..1] to I_User as _LastChangeUser on $projection.LastChangeUser = _LastChangeUser.UserID
{
key Document.serviceentrysheet as ServiceEntrySheet,
Document.serviceentrysheetuuid as ServiceEntrySheetUUID,
@Semantics.text: true
Document.name as ServiceEntrySheetName,
@ObjectModel.foreignKey.association: '_Supplier'
Document.supplier as Supplier,
Document.referencepurchaseorder as PurchaseOrder,
Document.deletioncode as IsDeleted,
@ObjectModel.foreignKey.association: '_ApprovalStatusValueHelp'
case when Document.deletioncode is not initial
then cast( '60' as mmpur_ses_approval_status )
when Document.deletioncode is initial
then cast( Document.approvalstatus as mmpur_ses_approval_status preserving type )
end as ApprovalStatus,
Document.approval_date_time as ApprovalDateTime,
@Consumption.valueHelp: '_ResponsiblePersonValueHelp'
Document.responsibleperson as ResponsiblePerson,
Document.originobjecttype as OriginObjectType,
@Semantics.currencyCode:true
Document.currency as Currency,
Document.mblnr as MaterialDocument,
Document.mjahr as MaterialDocumentYear,
Document.purchasingorganization as PurchasingOrganization,
Document.purchasinggroup as PurchasingGroup,
Document.crea_date_time as CreationDateTime,
@Semantics.user.createdBy: true
Document.crea_uname as CreatedByUser,
Document.lchg_date_time as LastChangeDateTime,
@Semantics.user.lastChangedBy: true
Document.lchg_uname as LastChangeUser,
// Data Privacy and Protection
@UI.hidden: true
@Consumption.hidden: true
@ObjectModel.readOnly: true
Document.iseopblocked as IsEndOfPurposeBlocked,
Document.externalsystem as PurgDocExternalSystem,
Document.externalreferenceid as PurgDocExternalReference,
Document.ext_rev_tmstmp as ExternalRevisionDateTime,
Document.postingdate as PostingDate,
Document.knumv as PricingDocument,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_ServiceEntrySheetItem,
_Supplier,
_ApprovalStatusValueHelp,
_ResponsiblePersonValueHelp,
_CreatedByUser,
_LastChangeUser,
_SESWorkflowStatus
}