I_SERVICEDOCUMENTLONGTEXT
Service Transaction Long Texts
I_SERVICEDOCUMENTLONGTEXT is a CDS View in S/4HANA. Service Transaction Long Texts. It contains 25 fields. 24 CDS views read from this table.
CDS Views using this table (24)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| P_InhRepairItemNote | view_entity | union | TRANSACTIONAL | |
| P_InhRepairNote | view_entity | union | TRANSACTIONAL | |
| P_ServiceDocItemNote | view | union | COMPOSITE | Service Transaction Notes |
| P_ServiceDocNote | view | union | COMPOSITE | Service Transaction Notes |
| R_BusSolnOrdItemLongTextTP | view_entity | from | TRANSACTIONAL | Business Solution Order Item Long Text - TP |
| R_BusSolnOrdLongTextTP | view_entity | from | TRANSACTIONAL | Business Solution Order Long Text - TP |
| R_SrvcConfItemLongTextTP | view_entity | from | TRANSACTIONAL | Long Text for Service Conf Item |
| R_SrvcConfLongTextTP | view_entity | from | TRANSACTIONAL | Long Text for Service Confirmation |
| R_SrvcContrItemLongTextTP | view_entity | from | TRANSACTIONAL | Service Contract Item Long Text - TP |
| R_SrvcContrLongTextTP | view_entity | from | TRANSACTIONAL | Service Contract Long Text - TP |
| R_SrvcContrTmplItemLongTextTP | view_entity | from | TRANSACTIONAL | Service Contract Template Item Text - TP |
| R_SrvcContrTmplLongTextTP | view_entity | from | TRANSACTIONAL | Service Contract Template Text - TP |
| R_SrvcOrdItemLongTextTP | view_entity | from | TRANSACTIONAL | Notes Item view for Service Order |
| R_SrvcOrdLongTextTP | view_entity | from | TRANSACTIONAL | Long Text for Service Order |
| R_SrvcOrdTmplItemLongTextTP | view_entity | from | TRANSACTIONAL | Long text for Template Item - TP |
| R_SrvcOrdTmplLongTextTP | view_entity | from | TRANSACTIONAL | Service Order Template Long Text - TP |
| R_SrvcQtanItemLongTextTP | view_entity | from | TRANSACTIONAL | Long Text for Service Quotation Item |
| R_SrvcQtanLongTextTP | view_entity | from | TRANSACTIONAL | Long Text for Service Quotation |
| R_SrvcTransMstrAgrmtLongTextTP | view_entity | from | TRANSACTIONAL | Master Agreement Long Text |
| R_SubscrpnContrItemLongTextTP | view_entity | from | TRANSACTIONAL | Subscription Contr. Item Long Text - TP |
| R_SubscrpnContrLongTextTP | view_entity | from | TRANSACTIONAL | Subscription Contract Text - TP |
| R_SubscrpnOrdItemLongTextTP | view_entity | from | TRANSACTIONAL | Subscription Order Item Long Text |
| R_SubscrpnOrdLongTextTP | view_entity | from | TRANSACTIONAL | Subscription Order Long Text |
| R_SvTrMtAgrItmLongTextTP | view_entity | from | TRANSACTIONAL | Master Agreement Item Long Text |
Fields (25)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | Language | Language | 24 |
| KEY | ServiceDocument | BusinessSolutionOrder,InHouseRepair,ServiceConfirmation,ServiceContract,ServiceContractTemplate,ServiceOrder,ServiceOrderTemplate,ServiceQuotation,SrvcTransMstrAgrmtID,SubscriptionContract,SubscriptionOrder | 13 |
| KEY | ServiceDocumentItem | InHouseRepairItem,ServiceDocumentItem,SubscriptionContractItem | 4 |
| KEY | SrvcDocLogTextIdentifier | SrvcDocLogTextIdentifier | 20 |
| KEY | TextObjectType | TextObjectType | 24 |
| _Language | _Language | 8 | |
| _ReferenceTextObjectCategory | _ReferenceTextObjectCategory | 6 | |
| _ReferenceTextObjectType | _ReferenceTextObjectType | 6 | |
| _TextObjectCategory | _TextObjectCategory | 6 | |
| _TextObjectType | _TextObjectType | 6 | |
| ReferenceLongTextKey | ReferenceLongTextKey | 20 | |
| ReferenceServiceDocument | ReferenceServiceDocument | 15 | |
| ReferenceServiceDocumentItem | ReferenceServiceDocumentItem | 15 | |
| ReferenceServiceObjectType | ReferenceServiceObjectType | 13 | |
| ReferenceTextObjectCategory | ReferenceTextObjectCategory | 20 | |
| ReferenceTextObjectType | ReferenceTextObjectType | 20 | |
| ServiceDocumentLongText | BusinessSolutionOrderLongText,BusSolnOrdItmLongText,ServiceOrderItemLongText,ServiceOrderLongText,SrvcConfItemLongText,SrvcConfLongText,SrvcContrItemLongText,SrvcContrLongText,SrvcContrTmplItemLongText,SrvcContrTmplLongText,SrvcOrdTmplItemLongText,SrvcOrdTmplLongText,SrvcQtanItemLongText,SrvcQtanLongText,SrvcTransMstrAgrmtItmLongText,SrvcTransMstrAgrmtLongText,SubscriptionContractLongText,SubscrpnContrItemLongText,SubscrpnOrderLongText,SubscrpnOrdItemLongText | 20 | |
| ServiceDocumentLongTextUUID | ServiceDocumentLongTextUUID | 18 | |
| ServiceObjectType | ServiceObjectType | 10 | |
| SrvcDocLongTextChangedByUser | SrvcDocLongTextChangedByUser | 20 | |
| SrvcDocLongTextChangedDateTime | SrvcDocLongTextChangedDateTime | 20 | |
| SrvcDocLongTextCreatedByUser | SrvcDocLongTextCreatedByUser | 20 | |
| SrvcDocLongTextMimeType | SrvcDocLongTextMimeType | 20 | |
| SrvcDocLongTxtCreationDateTime | SrvcDocLongTxtCreationDateTime | 20 | |
| TextObjectCategory | TextObjectCategory | 24 |
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Service Transaction Long Texts'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #BASIC
define view entity I_ServiceDocumentLongText
// Texts which are reference texts to a One Order text
as select from crms4d_text as ServiceDocumentText
left outer to one join crms4d_text as ReferenceServiceDocumentText
on ReferenceServiceDocumentText.text_object = ServiceDocumentText.ref_text_object
and ReferenceServiceDocumentText.text_id = ServiceDocumentText.ref_text_id
and ReferenceServiceDocumentText.language = ServiceDocumentText.language
and ReferenceServiceDocumentText.objtype_h = ServiceDocumentText.ref_objtype_h
and ReferenceServiceDocumentText.object_id = ServiceDocumentText.ref_object_id
and ReferenceServiceDocumentText.number_int = ServiceDocumentText.ref_number_int
association [1..1] to I_TextObjectCategory as _TextObjectCategory on $projection.TextObjectCategory = _TextObjectCategory.TextObjectCategory
association [1..1] to I_TextObjectType as _TextObjectType on $projection.TextObjectCategory = _TextObjectType.TextObjectCategory
and $projection.TextObjectType = _TextObjectType.TextObjectType
association [1..1] to I_Language as _Language on $projection.Language = _Language.Language
association [1..1] to I_CustMgmtBusObjType as _ServiceObjType on $projection.ServiceObjectType = _ServiceObjType.BusinessObjectType
association [1..1] to I_TextObjectCategory as _ReferenceTextObjectCategory on $projection.ReferenceTextObjectCategory = _ReferenceTextObjectCategory.TextObjectCategory
association [1..1] to I_TextObjectType as _ReferenceTextObjectType on $projection.ReferenceTextObjectCategory = _ReferenceTextObjectType.TextObjectCategory
and $projection.ReferenceTextObjectType = _ReferenceTextObjectType.TextObjectType
{
key ServiceDocumentText.text_uuid as ServiceDocumentLongTextUUID,
@ObjectModel.foreignKey.association: '_TextObjectCategory'
ServiceDocumentText.text_object as TextObjectCategory,
@ObjectModel.foreignKey.association: '_TextObjectType'
ServiceDocumentText.text_id as TextObjectType,
@ObjectModel.foreignKey.association: '_Language'
@Semantics.language:true
ServiceDocumentText.language as Language,
@ObjectModel.foreignKey.association: '_ServiceObjType'
ServiceDocumentText.objtype_h as ServiceObjectType,
ServiceDocumentText.object_id as ServiceDocument,
ServiceDocumentText.number_int as ServiceDocumentItem,
ServiceDocumentText.mimetype as SrvcDocLongTextMimeType,
ReferenceServiceDocumentText.text_content as ServiceDocumentLongText,
@ObjectModel.foreignKey.association: '_ReferenceTextObjectCategory'
ServiceDocumentText.ref_text_object as ReferenceTextObjectCategory,
@ObjectModel.foreignKey.association: '_ReferenceTextObjectType'
ServiceDocumentText.ref_text_id as ReferenceTextObjectType,
ServiceDocumentText.ref_text_name as ReferenceLongTextKey,
ServiceDocumentText.ref_objtype_h as ReferenceServiceObjectType,
ServiceDocumentText.ref_object_id as ReferenceServiceDocument,
ServiceDocumentText.ref_number_int as ReferenceServiceDocumentItem,
ServiceDocumentText.log_timestamp as SrvcDocLogTextIdentifier,
ServiceDocumentText.created_at as SrvcDocLongTxtCreationDateTime,
ServiceDocumentText.created_by as SrvcDocLongTextCreatedByUser,
ServiceDocumentText.changed_at as SrvcDocLongTextChangedDateTime,
ServiceDocumentText.changed_by as SrvcDocLongTextChangedByUser,
_TextObjectCategory,
_TextObjectType,
_Language,
_ServiceObjType,
_ReferenceTextObjectCategory,
_ReferenceTextObjectType
}
where ServiceDocumentText.ref_text_object = 'CRM_ORDERH' or
ServiceDocumentText.ref_text_object = 'CRM_ORDERI'
// All other texts (texts which are not reference texts, or which have a reference to a foreign text object)
union all select from crms4d_text as ServiceDocumentText
association [1..1] to I_TextObjectCategory as _TextObjectCategory on $projection.TextObjectCategory = _TextObjectCategory.TextObjectCategory
association [1..1] to I_TextObjectType as _TextObjectType on $projection.TextObjectCategory = _TextObjectType.TextObjectCategory
and $projection.TextObjectType = _TextObjectType.TextObjectType
association [1..1] to I_Language as _Language on $projection.Language = _Language.Language
association [1..1] to I_CustMgmtBusObjType as _ServiceObjType on $projection.ServiceObjectType = _ServiceObjType.BusinessObjectType
association [1..1] to I_TextObjectCategory as _ReferenceTextObjectCategory on $projection.ReferenceTextObjectCategory = _ReferenceTextObjectCategory.TextObjectCategory
association [1..1] to I_TextObjectType as _ReferenceTextObjectType on $projection.ReferenceTextObjectCategory = _ReferenceTextObjectType.TextObjectCategory
and $projection.ReferenceTextObjectType = _ReferenceTextObjectType.TextObjectType
{
key ServiceDocumentText.text_uuid as ServiceDocumentLongTextUUID,
// @ObjectModel.foreignKey.association: '_TextObjectCategory'
ServiceDocumentText.text_object as TextObjectCategory,
// @ObjectModel.foreignKey.association: '_TextObjectType'
ServiceDocumentText.text_id as TextObjectType,
// @ObjectModel.foreignKey.association: '_Language'
ServiceDocumentText.language as Language,
// @ObjectModel.foreignKey.association: '_ServiceObjType'
ServiceDocumentText.objtype_h as ServiceObjectType,
ServiceDocumentText.object_id as ServiceDocument,
ServiceDocumentText.number_int as ServiceDocumentItem,
ServiceDocumentText.mimetype as SrvcDocLongTextMimeType,
ServiceDocumentText.text_content as ServiceDocumentLongText,
// @ObjectModel.foreignKey.association: '_ReferenceTextObjectCategory'
ServiceDocumentText.ref_text_object as ReferenceTextObjectCategory,
// @ObjectModel.foreignKey.association: '_ReferenceTextObjectType'
ServiceDocumentText.ref_text_id as ReferenceTextObjectType,
ServiceDocumentText.ref_text_name as ReferenceLongTextKey,
ServiceDocumentText.ref_objtype_h as ReferenceServiceObjectType,
ServiceDocumentText.ref_object_id as ReferenceServiceDocument,
ServiceDocumentText.ref_number_int as ReferenceServiceDocumentItem,
ServiceDocumentText.log_timestamp as SrvcDocLogTextIdentifier,
ServiceDocumentText.created_at as SrvcDocLongTxtCreationDateTime,
ServiceDocumentText.created_by as SrvcDocLongTextCreatedByUser,
ServiceDocumentText.changed_at as SrvcDocLongTextChangedDateTime,
ServiceDocumentText.changed_by as SrvcDocLongTextChangedByUser,
_TextObjectCategory,
_TextObjectType,
_Language,
_ServiceObjType,
_ReferenceTextObjectCategory,
_ReferenceTextObjectType
}
where ServiceDocumentText.ref_text_object <> 'CRM_ORDERH' and
ServiceDocumentText.ref_text_object <> 'CRM_ORDERI'