I_SALESORDERSCHEDULELINE

CDS View

Sales Order Schedule Line

I_SALESORDERSCHEDULELINE is a CDS View in S/4HANA. Sales Order Schedule Line. It contains 22 fields. 8 CDS views read from this table.

Used by 8 CDS view(s) 22 fields

CDS Views using this table (8)

ViewTypeJoinVDMDescription
A_SalesOrderScheduleLine view from COMPOSITE Item Schedule Line
A_SalesOrderScheduleLineSimln view from COMPOSITE Sales Order Schedule Line Sim (API)
C_ESJISOScheduleLineDelivDate view from CONSUMPTION Requested Delivery Date from I_SalesOrderScheduleLine
C_SalesOrderScheduleLine view from CONSUMPTION
C_SlsOrdSchdLnWthCalInfoDEX view from CONSUMPTION Data Extraction for Sales Order Sched Line
I_MRPSalesOrder view from COMPOSITE MRP Sales Order
P_BusSolnOrdSlsOrdFlwLvl11 view inner CONSUMPTION Solution Order Sales Order Flow Level 11
R_SalesOrderScheduleLineTP view_entity from TRANSACTIONAL Schedule Line for Sales Order Item - TP

Fields (22)

KeyField CDS FieldsUsed in Views
KEY PurchaseRequisition SubsequentDocument 1
KEY PurchasingDocumentCategory SubsequentDocumentCategory 1
KEY SalesOrder SalesOrder 3
KEY SalesOrderItem SalesOrderItem 3
KEY ScheduleLine ScheduleLine,ScheduleLineForEdit 2
_DelivBlockReasonForSchedLine _DelivBlockReasonForSchedLine 1
_GoodsMovementType _GoodsMovementType 1
_OrderQuantityUnit _OrderQuantityUnit 1
_ScheduleLineCategory _ScheduleLineCategory 1
BaseUnit BaseUnit 1
ConfdOrderQtyByMatlAvailCheck ConfdOrderQtyByMatlAvailCheck 2
ConfirmedDeliveryDate ConfirmedDeliveryDate 2
DelivBlockReasonForSchedLine DelivBlockReasonForSchedLine 1
DeliveredQtyInOrderQtyUnit DeliveredQtyInOrderQtyUnit 1
GoodsMovementType GoodsMovementType 1
IsConfirmedDelivSchedLine IsConfirmedDelivSchedLine 1
IsRequestedDelivSchedLine IsRequestedDelivSchedLine 1
OpenConfdDelivQtyInOrdQtyUnit OpenConfdDelivQtyInOrdQtyUnit 1
OrderQuantityUnit OrderQuantityUnit 2
RequestedDeliveryDate RequestedDeliveryDate 1
ScheduleLineCategory ScheduleLineCategory 1
ScheduleLineOrderQuantity ScheduleLineOrderQuantity 2 
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel:{
    representativeKey: 'ScheduleLine',
    usageType:{
        dataClass: #TRANSACTIONAL,
        serviceQuality: #B,
        sizeCategory: #XL
        },
    supportedCapabilities: [ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
    modelingPattern: [ #ANALYTICAL_DIMENSION ]
}
@EndUserText.label: 'Sales Order Schedule Line'
@Analytics.dataCategory: #DIMENSION
@Metadata.allowExtensions: true
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:#CHECK
@AbapCatalog.sqlViewName: 'ISDSLSORDSCHEDLN'

define view I_SalesOrderScheduleLine
  as select from           I_SalesDocumentScheduleLine as SalesDocumentScheduleLine
    left outer to one join I_SalesDocumentBasic        as SalesDocumentBasic on SalesDocumentScheduleLine.SalesDocument = SalesDocumentBasic.SalesDocument
  association [1..1] to I_SalesOrder     as _SalesOrder     on  $projection.SalesOrder = _SalesOrder.SalesOrder
  association [1..1] to I_SalesOrderItem as _SalesOrderItem on  $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
                                                            and $projection.SalesOrder     = _SalesOrderItem.SalesOrder
{
      // Key

      @ObjectModel.foreignKey.association: '_SalesOrder'
  key SalesDocumentScheduleLine.SalesDocument                                   as SalesOrder,
      @ObjectModel.foreignKey.association: '_SalesOrderItem'
  key SalesDocumentItem                                                         as SalesOrderItem,
  key ScheduleLine,

      // Category

      @ObjectModel.foreignKey.association: '_ScheduleLineCategory'
      ScheduleLineCategory,

      // Sales

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
      OrderQuantityUnit,
      OrderToBaseQuantityDnmntr,
      OrderToBaseQuantityNmrtr,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_BaseUnit'
      BaseUnit,
      DeliveryDate,

      // Requested

      cast(IsRequestedDelivSchedLine as reqd_deliv)                             as IsRequestedDelivSchedLine,
      cast(SalesDocumentScheduleLine.RequestedDeliveryDate as reqd_deliv_date)  as RequestedDeliveryDate,
      RequestedDeliveryTime,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ScheduleLineOrderQuantity,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      CorrectedQtyInOrderQtyUnit,

      // Confirmed

      cast(IsConfirmedDelivSchedLine as confd_deliv)                            as IsConfirmedDelivSchedLine,
      cast(ConfirmedDeliveryDate as confd_deliv_date)                           as ConfirmedDeliveryDate,
      ConfirmedDeliveryTime,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ConfdOrderQtyByMatlAvailCheck,
      ConfdSchedLineReqdDelivDate,

      // Availability

      ProductAvailabilityDate,
      ProductAvailabilityTime,
      ProductAvailCheckRqmtDate,
      ProdAvailabilityCheckRqmtType,
      ProdAvailyCheckPlanningType,
      @ObjectModel.foreignKey.association: '_ScheduleLineConfStatus'
      ScheduleLineConfirmationStatus,
      OrderSchedulingGroup,

      //InternalProcurement

      PlannedOrder,
      @ObjectModel.foreignKey.association: '_OrderID'
      SalesDocumentScheduleLine.OrderID,

      //Purchasing

      PurchaseRequisition,
      PurchaseRequisitionItem,
      PurchasingOrderType,
      PurchasingDocumentCategory,


      // Shipping

      DeliveryCreationDate,
      TransportationPlanningDate,
      TransportationPlanningTime,
      GoodsIssueDate,
      LoadingDate,
      GoodsIssueTime,
      LoadingTime,
      ItemIsDeliveryRelevant,
      @ObjectModel.foreignKey.association: '_DelivBlockReasonForSchedLine'
      DelivBlockReasonForSchedLine,

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      OpenReqdDelivQtyInOrdQtyUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      OpenReqdDelivQtyInBaseUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      OpenConfdDelivQtyInOrdQtyUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      OpenConfdDelivQtyInBaseUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      DeliveredQtyInOrderQtyUnit,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      DeliveredQuantityInBaseUnit,
      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      GoodsMovementType,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      OpenDeliveryNetAmount,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      SalesDocumentScheduleLine.TransactionCurrency,
      @ObjectModel.foreignKey.association: '_TradeCmplncLegalCtrlChkSts'
      SalesDocumentScheduleLine.TradeCmplncLegalCtrlChkSts,

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _SalesOrder,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _SalesOrderItem,
      _ScheduleLineCategory,
      _ProdAvailabilityCheckRqmtType,
      _ScheduleLineConfStatus,
      SalesDocumentScheduleLine._TransactionCurrency,
      _OrderID,
      _OrderQuantityUnit,
      _BaseUnit,
      _DelivBlockReasonForSchedLine,
      _GoodsMovementType,
      SalesDocumentScheduleLine._TradeCmplncLegalCtrlChkSts
}
where
  SalesDocumentBasic.SDDocumentCategory = 'C';

Learn More