I_SALESORDERPARTNER

CDS View

Sales Order Partner

I_SALESORDERPARTNER is a CDS View in S/4HANA. Sales Order Partner. It contains 29 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 29 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_SalesOrderWrkflwInbox view left_outer CONSUMPTION Sales Order Workflow Inbox
I_CustProjSlsOrdPartner view from COMPOSITE Sales Order Partner for Customer Project
R_SalesOrderPartnerTP view_entity from TRANSACTIONAL Sales Order Partner - TP
R_SalesOrderShipToPartyTP view_entity from TRANSACTIONAL Sales Order Ship-to Party - TP

Fields (29)

KeyField CDS FieldsUsed in Views
KEY PartnerFunction PartnerFunction 1
_Address _Address 1
_BPRefAddressForDocSpcfcAddr _BPRefAddressForDocSpcfcAddr 2
_BusinessPartnerAddress _BusinessPartnerAddress 2
_DfltAddrRprstn _DfltAddrRprstn 2
_PartnerFunction _PartnerFunction 1
AddressID AddressID 3
AddressObjectType AddressObjectType 3
AddressPersonID AddressPersonID 3
BPAddrDeterminationTransaction BPAddrDeterminationTransaction 2
BPRefAddressIDForDocSpcfcAddr BPRefAddressIDForDocSpcfcAddr 2
ContactPerson ContactPerson 2
CorrespondenceLanguage CorrespondenceLanguage 2
Customer Customer,Partner,ShipToParty 3
EmailAddress EmailAddress 2
FormOfAddress FormOfAddress 2
FullName FullName 2
InternationalFaxNumber InternationalFaxNumber 2
InternationalMobilePhoneNumber InternationalMobilePhoneNumber 2
InternationalPhoneNumber InternationalPhoneNumber 2
Partner Partner 2
Personnel Personnel 1
ReferenceBusinessPartner ReferenceBusinessPartner 3
SalesOrder SalesOrder 1
SDDocPartnerAddressRefType SDDocPartnerAddressRefType 2
SDDocPartnerAddrIsDocSpecific SDDocPartnerAddrIsDocSpecific 2
Supplier Supplier 1
UnloadingPointName UnloadingPointName 2
VATRegistration VATRegistration 2 
@ClientHandling.algorithm: #SESSION_VARIABLE 
@EndUserText.label: 'Sales Order Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_Address', '_DfltAddrRprstn', '_PersonAddress', '_PersonName', '_OrganizationAddress', '_OrgNamePostalAddress' ]
}
@AbapCatalog: {
  sqlViewName: 'ISDSLSORDPT',
  compiler.compareFilter: true
}
@ObjectModel: {
   representativeKey: 'PartnerFunction',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
}
@Metadata.ignorePropagatedAnnotations: true

define view I_SalesOrderPartner   
 as select from I_SalesDocumentPartner as Partner
      
    association[1..1] to I_SalesOrder  as _SalesOrder on $projection.SalesOrder   = _SalesOrder.SalesOrder     
    
{
        @ObjectModel.foreignKey.association: '_SalesOrder'                                                                                                   
    key cast(Partner.SalesDocument as vdm_sales_order preserving type) as SalesOrder,             
        @ObjectModel.foreignKey.association: '_PartnerFunction'
    key Partner.PartnerFunction,  
         
        Partner.Customer,          
        Partner.Supplier,           
        Partner.Personnel,           
        Partner.ContactPerson,       
        
        @ObjectModel.text.element: ['FullName']
        Partner.Partner,
        
        @Semantics: {
          text: true,
          name.fullName: true
        }
        Partner.FullName,
       
        Partner.ReferenceBusinessPartner,  
            
        @ObjectModel.foreignKey.association: '_Address'
        Partner.AddressID,
        Partner.AddressPersonID,
        Partner.AddressObjectType,
        Partner.SDDocPartnerAddressRefType,
        Partner.BPAddrDeterminationTransaction,
        Partner.BPRefAddressIDForDocSpcfcAddr, 
        Partner.SDDocPartnerAddrIsDocSpecific,
           
        Partner.VATRegistration,  
        @Semantics.text: true
        Partner.UnloadingPointName,
        
        Partner.CorrespondenceLanguage,
        Partner.FormOfAddress,
        
        Partner.InternationalPhoneNumber,
        Partner.InternationalMobilePhoneNumber,
        Partner.InternationalFaxNumber,
        Partner.EmailAddress,
        
        //Association

        @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]    
        _SalesOrder,
        Partner._PartnerFunction,
        Partner._ContactPerson,
        Partner._Address,
        Partner._DfltAddrRprstn,
        Partner._BusinessPartnerAddress,
        Partner._BPRefAddressForDocSpcfcAddr,
        Partner._PersonAddress,
        Partner._PersonName,
        Partner._OrganizationAddress,
        Partner._OrgNamePostalAddress 

}
where Partner.SDDocumentCategory = 'C';

Learn More