I_RECIPECLASSCHARCTP

CDS View

TP for Recipe Class Charcs

I_RECIPECLASSCHARCTP is a CDS View in S/4HANA. TP for Recipe Class Charcs. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_RecipeClassCharc view from CONSUMPTION Recipe Class and Characteristic Assignments 
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IRECCLSCHRTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'TP for Recipe Class Charcs'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
define view I_RecipeClassCharcTP 
  with parameters
    @Consumption.hidden: true
    @Semantics.businessDate.at: true
    P_KeyDate:sydate
  as select from I_ClfnObjectCharcForKeyDate( P_KeyDate: $parameters.P_KeyDate ) as Characteristics
    join I_ClfnClass as Class on
      Characteristics.ClassInternalID = Class.ClassInternalID and
      Characteristics.ClassType       = Class.ClassType
    join I_RecipeForKeyDateTP( P_KeyDate: $parameters.P_KeyDate ) as Recipe on
      Characteristics.ClfnObjectID = bintohex( Recipe.RecipeUUID )
  
    association [0..*] to I_RecipeCharcValueTP as _Valuation on
      $projection.RecipeUUID = _Valuation.RecipeUUID and
      $projection.CharcInternalID = _Valuation.CharcInternalID and
      $projection.ClassType = _Valuation.ClassType
    association [1..1] to I_RecipeClassTP as _RecipeClass on
      $projection.RecipeUUID = _RecipeClass.RecipeUUID and
      $projection.ClassInternalID = _RecipeClass.ClassInternalID 
    association [1..1] to I_RecipeForKeyDateTP as _Recipe on
      $projection.RecipeUUID = _Recipe.RecipeUUID 
  {
    key Recipe.RecipeUUID,
    key Characteristics.ClassInternalID,
    key Characteristics.CharcInternalID,
    
    $parameters.P_KeyDate as KeyDate,
    Characteristics.ClassType,
    Characteristics.ValidityStartDate,   
    Characteristics.ValidityEndDate,
    
    _Valuation,
    _RecipeClass,
    _Recipe,
    Characteristics._Characteristic
  }
    where
      Characteristics.ClfnObjectTable = '/PLMB/RCP_RECIPE' and
      Characteristics.ClfnObjectType = 'O'

Learn More