I_REOBJECTASSGMT

@AbapCatalog.sqlViewName: 'IREOBJECTASS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Real Estate Object Assignments'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@VDM.viewType: #BASIC
//@Search.searchable: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true

@ObjectModel.representativeKey: ['REStatusObjectSource']
@ObjectModel.semanticKey: ['REStatusObjectSource', 'REObjectAssignmentType', 'REStatusObjectTarget', 'ValidityStartDate' ]


define view I_REObjectAssgmt
  as select from vibdobjass as REObjectAssgmt

  //real estate objects target

  association [0..1] to I_REContractSubject      as _REContractSubject      on $projection.REStatusObjectTarget = _REContractSubject.REStatusObject
  association [0..1] to I_REObjectGroup          as _REObjectGroup          on $projection.REStatusObjectTarget = _REObjectGroup.REStatusObject
  association [0..1] to I_REObjectTypeDetails    as _REObjectTypeDetails    on $projection.REStatusObjectTarget = _REObjectTypeDetails.REStatusObject

  //FI/CO objects

  association [0..1] to I_CostCenter             as _CostCenter             on $projection.REStatusObjectTarget = _CostCenter.ObjectInternalID
  association [0..1] to I_WBSElementBasicData    as _WBSElement             on $projection.REStatusObjectTarget = _WBSElement.WBSElementObject
  association [0..1] to I_InternalOrder          as _InternalOrder          on $projection.REStatusObjectTarget = _InternalOrder.ControllingObject
  association [0..1] to I_REFixedAssetRelation   as _FixedAsset             on $projection.REStatusObjectTarget = _FixedAsset.REStatusObjectAsset

  //technical objects

  association [0..*] to I_TechnicalObject        as _TechnicalObject        on $projection.REStatusObjectTarget = _TechnicalObject.MaintObjectInternalID

  association [1..1] to I_REObjectAssignmentType as _REObjectAssignmentType on $projection.REObjectAssignmentType = _REObjectAssignmentType.REObjectAssignmentType
  association [0..1] to I_REGenerationType       as _REGenerationType       on $projection.REGenerationType = _REGenerationType.REGenerationType
{
  key objnrsrc                                                                    as REStatusObjectSource,
      @ObjectModel.foreignKey.association: '_REObjectAssignmentType'
  key objasstype                                                                  as REObjectAssignmentType,
  key objnrtrg                                                                    as REStatusObjectTarget,
      @Semantics.businessDate.from: true
  key cast( coalesce(validfrom,'00000000')  as rebdvdmvalidfrom preserving type ) as ValidityStartDate,
      @Semantics.businessDate.to: true
      cast( coalesce(validto,'99991231')    as rebdvdmvalidto preserving type )   as ValidityEndDate,
      assignonlyinfo                                                              as REOnlyInfoAssgmt,
      objnrsrcarch                                                                as REStatusObjectSourceIsArchived,
      @ObjectModel.foreignKey.association: '_REGenerationType'
      flgentype                                                                   as REGenerationType,
      ismainasset                                                                 as REIsMainAsset,
      ismultiassgen                                                               as REAssignmentHasMultiple,
      possdatefrom                                                                as REObjectPossessionStartDate,
      possdateto                                                                  as REObjectPossessionEndDate,
      isleadingobject                                                             as REIsLeadingObject,

      //      @EndUserText.label: 'Accounting Object Type'

      //      _REContractSubject.REAccountingObjectType as REAccountingObjectType,


      //      _ContractSubjectSource,

      //      _REObjectGroupSource,

      //      _REContractSource,

      //      _REContractSubjectSource,

      //      _REBusinessEntitySource,

      //      _REBuildingSource,

      //      _REPropertySource,

      //      _RERentalObjectSource,

      //       _REObjectTypeDetailsSource,

      _REContractSubject,
      _REObjectGroup,
      //      _REContract,

      //      _REContractSubject,

      //      _REBusinessEntity,

      //      _REBuilding,

      //      _REProperty,

      //      _RERentalObject,

      _REObjectTypeDetails,

      _CostCenter,
      _WBSElement,
      _InternalOrder,
      _FixedAsset,
      _TechnicalObject,
      _REObjectAssignmentType,
      _REGenerationType

}