I_QUEUINGOPERATIONS

CDS View

Queuing Operations

I_QUEUINGOPERATIONS is a CDS View in S/4HANA. Queuing Operations. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_WorkCenterPipeLineOperation view from COMPOSITE Queued Operations 
@AbapCatalog.sqlViewName: 'IQUEUINGOP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Queuing Operations'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}

define view I_QueuingOperations
  as select from I_MfgOrderWrkcntrOper
  association [0..1] to I_MfgOrderObjPgOpConfQty as _ConfirmedQty on  $projection.WorkCenterInternalID        = _ConfirmedQty.WorkCenterInternalID
                                                                  and $projection.ManufacturingOrder          = _ConfirmedQty.ProductionOrder
                                                                  and $projection.ManufacturingOrderOperation = _ConfirmedQty.Operation
                                                                  and $projection.ManufacturingOrderCategory  = _ConfirmedQty.OrderCategory
  association [0..1] to I_MfgOrderStatus         as _OrderStatus  on  $projection.ManufacturingOrder = _OrderStatus.ManufacturingOrder



{
  key    OrderInternalBillOfOperations,
  key    OrderIntBillOfOperationsItem,
         WorkCenterInternalID,
         ManufacturingOrder,
         ManufacturingOrderOperation,
         ManufacturingOrderCategory,
         MfgOrderOperationText,
         Material,
         cast(OperationIsReleased as boolean)                                                                                                                  as OperationIsReleased,
         OpErlstSchedldExecStrtDte,
         OpErlstSchedldExecStrtTme,
         OpErlstSchedldExecEndDte,
         OpErlstSchedldExecEndTme,
         OpPlannedTotalQuantity,
         OperationUnit,
         @DefaultAggregation: #SUM
         @Semantics.quantity.unitOfMeasure: 'ConfirmedQuantityUnit'
         _ConfirmedQty.ConfirmedQuantity,
         @DefaultAggregation: #SUM
         @VDM.lifecycle.status: #DEPRECATED
         @VDM.lifecycle.successor: 'ConfirmedQuantityUnit'
         cast ('  ' as meins) as ConfirmedQuantityInBaseUnit,     // deprecated - do not use!

          @Semantics.unitOfMeasure: true
         _ConfirmedQty.ConfirmedQuantityUnit,
         ErlstSchedldExecDurnInWorkdays,
         @Semantics.calendarItem.duration: true
         case
         when (OpActualExecutionDays          is null and ErlstSchedldExecDurnInWorkdays is null) then 0
         when (OpActualExecutionDays          is null and ErlstSchedldExecDurnInWorkdays is not null) then ErlstSchedldExecDurnInWorkdays
         when (OpActualExecutionDays          is not null and ErlstSchedldExecDurnInWorkdays is null) then 0
         else ErlstSchedldExecDurnInWorkdays - OpActualExecutionDays
         end                                                                                                                                                   as RemainingDuration,
         ManufacturingOrderSequence,
         cast(MfgOrderOperationIsPhase as boolean preserving type)                                                                                             as MfgOrderOperationIsPhase,

         _Material,
         _MfgOrderSequence,
         _MfgOrder
}
// Released but not yet started

where
      OperationIsReleased                   = 'X'
  and OpActualExecutionStartDate            = '00000000'
  and _OrderStatus.OrderIsClosed            = ''  
  and _OrderStatus.OrderIsMarkedForDeletion = '';

Learn More