I_QLTYTASKFLLWUPACTIONPARAM

@AbapCatalog.sqlViewName: 'IQLTYTSKFOAPRM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@VDM.viewType: #BASIC

@EndUserText.label: 'Quality Task Follow-Up Action Parameter'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    representativeKey: 'ItemCounter',
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M,
        serviceQuality: #A }
}
@Metadata.ignorePropagatedAnnotations: true
 
define view I_QltyTaskFllwUpActionParam
  as select from qmsm_foa_param
  //=== Assocation to QM specific views

  association [1..1] to I_QualityTask              as _QualityTask              on  $projection.QualityTaskInternalId = _QualityTask.QualityTaskInternalId

  //=== Assocation to other views

  association [0..1] to I_Material                 as _Material                 on  $projection.Material = _Material.Material
  association [0..1] to I_Plant                    as _Plant                    on  $projection.Plant = _Plant.Plant
  association [0..1] to I_StorageLocation          as _StorageLocation          on  $projection.Plant           = _StorageLocation.Plant
                                                                                and $projection.StorageLocation = _StorageLocation.StorageLocation

  association [0..1] to I_OrderInternalID          as _OrderInternalID          on  $projection.OrderInternalID =  _OrderInternalID.OrderInternalID
                                                                                and $projection.OrderInternalID <> '0000000000'
  association [0..1] to I_OrderOperationBasic      as _OrderOperationBasic      on  $projection.OrderInternalID          =  _OrderOperationBasic.OrderInternalID
                                                                                and $projection.OrderOperationInternalID =  _OrderOperationBasic.OrderOperationInternalID
                                                                                and $projection.OrderInternalID          <> '0000000000'

  association [0..1] to I_MfgActionReasonCodeGroup as _MfgActionReasonCodeGroup on  $projection.MfgNonConformanceRsnCodeCtlg = _MfgActionReasonCodeGroup.MfgActionReasonCodeGroupCtlg
                                                                                and $projection.MfgNonConformanceRsnCodeGrp  = _MfgActionReasonCodeGroup.MfgActionReasonCodeGroup
  association [0..1] to I_MfgActionReasonCode      as _MfgActionReasonCode      on  $projection.MfgNonConformanceRsnCodeCtlg = _MfgActionReasonCode.MfgActionReasonCodeGroupCtlg
                                                                                and $projection.MfgNonConformanceRsnCodeGrp  = _MfgActionReasonCode.MfgActionReasonCodeGroup
                                                                                and $projection.MfgNonConformanceReasonCode  = _MfgActionReasonCode.ManufacturingActionReasonCode
                                                                                and _MfgActionReasonCode.Version             = '0000'
  association [0..1] to I_ChangeRecordBsc          as _ChangeRecordBsc          on  $projection.ChangeRecord     = _ChangeRecordBsc.ChangeRecord
                                                                                and $projection.ChangeRecordType = _ChangeRecordBsc.ChangeRecordType
  association [0..1] to I_ProductionSupplyArea     as _ProductionSupplyArea     on  $projection.ProductionSupplyArea = _ProductionSupplyArea.ProductionSupplyArea 
                                                                                and $projection.Plant = _ProductionSupplyArea.Plant
  association [0..1] to I_EWM_WarehouseNumber     as _EWM_WarehouseNumber       on $projection.EWMWarehouse = _EWM_WarehouseNumber.Warehouse                                                                                                                                                        

  //=== Assocation to common views

  association [0..1] to I_UnitOfMeasure            as _UnitOfMeasure            on  $projection.DefectiveQuantityUnit = _UnitOfMeasure.UnitOfMeasure

  // Extension

  association [1..1] to E_QltyTskFllwUpActnParam   as _Extension                on  $projection.QualityTaskInternalId = _Extension.QualityNotification
                                                                                and _Extension.QualityNotificationTask = '0000'
                                                                                and $projection.ItemCounter = _Extension.ItemCounter
                                                                                
{
      @ObjectModel:{  foreignKey.association: '_QualityTask',
                      readOnly: true }
  key cast( qmsm_foa_param.qmnum as qtaskinternalid preserving type )    as QualityTaskInternalId,
      @ObjectModel.readOnly: true
  key qmsm_foa_param.counter                                             as ItemCounter,
  
      //=== Fields for usage as semantic key

      @ObjectModel.readOnly: true
      cast( substring(qmsm_foa_param.qmnum,2,11) as qtaskid preserving type ) as QualityTask,
      qmsm_foa_param.counter                                                  as QltyTaskFllwUpActionParam,
      
      @ObjectModel.readOnly: true
      qmsm_foa_param.paramtype                                           as QltyTskFllwUpActnParamType,

      @Semantics.quantity.unitOfMeasure: 'DefectiveQuantityUnit'
      qmsm_foa_param.menge                                               as DefectiveQuantity,

      @ObjectModel:{    foreignKey.association: '_UnitOfMeasure' }
      @Semantics.unitOfMeasure: true
      qmsm_foa_param.mgein                                               as DefectiveQuantityUnit,

      @ObjectModel:{    foreignKey.association: '_Material' }
      qmsm_foa_param.matnr                                               as Material,

      @ObjectModel:{    foreignKey.association: '_Plant' }
      qmsm_foa_param.werks                                               as Plant,

      @ObjectModel:{    foreignKey.association: '_StorageLocation' }
      qmsm_foa_param.lgort                                               as StorageLocation,
      qmsm_foa_param.affctd_obj_counter                                  as DefectAffectedObject, //only possible if item created from defect

      qmsm_foa_param.plnty                                               as BillOfOperationsType,

      qmsm_foa_param.plnnr                                               as BillOfOperationsGroup,

      qmsm_foa_param.plnal                                               as BillOfOperationsVariant,

      qmsm_foa_param.plnversn                                            as BillOfOperationsVersion,

      qmsm_foa_param.aufpl                                               as OrderInternalID,

      qmsm_foa_param.aplzl                                               as OrderOperationInternalID,

      qmsm_foa_param.mfgrewrkroutplnnr                                   as MfgReworkRoutingGroup,

      qmsm_foa_param.mfgrewrkroutplnal                                   as MfgReworkRoutingVariant,

      qmsm_foa_param.mpe_nc_rsn_code_ctlg                                as MfgNonConformanceRsnCodeCtlg,

      @ObjectModel:{   foreignKey.association: '_MfgActionReasonCodeGroup' }
      @Consumption.valueHelpDefinition: [
        { entity: { name: 'I_MfgActnRsnCodeGrpStdVH', element: 'MfgActionReasonCodeGroup' },
          additionalBinding: [{ localElement: 'MfgNonConformanceRsnCodeCtlg', element: 'MfgNonConformanceRsnCodeCtlg' }]
        }
      ]
      qmsm_foa_param.mpe_nc_rsn_code_grp                                 as MfgNonConformanceRsnCodeGrp,

      @ObjectModel:{    foreignKey.association: '_MfgActionReasonCode' }
      @Consumption.valueHelpDefinition: [
        { entity: { name: 'I_MfgActionReasonCode', element: 'ManufacturingActionReasonCode' },
          additionalBinding: [  { localElement: 'MfgNonConformanceRsnCodeCtlg', element: 'MfgActionReasonCodeGroupCtlg' },
                                { localElement: 'MfgNonConformanceRsnCodeGrp', element: 'MfgActionReasonCodeGroup' }]
        }
      ]
      qmsm_foa_param.mpe_nc_rsn_code                                     as MfgNonConformanceReasonCode,

      qmsm_foa_param.mpe_nc_note                                         as MfgNonConformanceNote,

      @ObjectModel:{    foreignKey.association: '_ChangeRecordBsc' }
      @Consumption.valueHelpDefinition: [
        // -- Basic View as Value Help

        { entity: { name: 'I_ChangeRecordBsc', element: 'ChangeRecord' },
          additionalBinding: [  { localElement: 'ChangeRecordType', element: 'ChangeRecordType' },
                                { localElement: 'ChgRecordDescriptionText', element: 'ChgRecordDescriptionText' }]
        },
        // -- Order Specific Value Help

        { entity: { name: 'C_OrdSpcfcChgRecdOpn', element: 'ChangeRecord' }, qualifier: 'vh_C_OrdSpcfcChgRecdOpn',
          additionalBinding: [  { localElement: 'ChangeRecordType', element: 'ChangeRecordType' },
                                { localElement: 'ChgRecordDescriptionText', element: 'ChgRecordDescriptionText' }]
        }
      ]
      qmsm_foa_param.chg_rec_id                                          as ChangeRecord,

      @Consumption.valueHelpDefinition: [
        // -- Basic View !! DOES NOT EXISTS !! If need create one and reference here.

        // -- Order Specific Value Help

        { entity: { name: 'C_OrdSpcfcChgRecdType', element: 'ChangeRecordType' }, label: 'Order Change' },
        
        { entity: { name: 'I_DfctChgRecdType', element: 'ChangeRecordType' }, qualifier: 'vh_I_DfctChgRecdType', label: 'Engineering Change' }     
        
      ]
      qmsm_foa_param.chg_rec_type                                        as ChangeRecordType,

      qmsm_foa_param.chg_rec_desc                                        as ChgRecordDescriptionText,
      
      @Consumption.valueHelpDefinition: [
        { entity: { name: 'I_ProductionSupplyAreaStdVH', element: 'ProductionSupplyArea' } }
      ]
      qmsm_foa_param.prvbe                                               as ProductionSupplyArea,
      
      @Consumption.valueHelpDefinition: [
        { entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' } }
      ]
      qmsm_foa_param.kostl                                               as CostCenter,
      qmsm_foa_param.vlpla                                               as SourceStorageBin,
      qmsm_foa_param.defectuuid                                          as DefectUUID,
      qmsm_foa_param.ewm_guid_stock                                      as StockItemUUID,
      qmsm_foa_param.ewm_guid_parent                                     as ParentHandlingUnitUUID,
      @Semantics.booleanIndicator 
      qmsm_foa_param.ewm_stock_sel_is_proc                               as QltyTaskStkSelInEWMIsProcd,
      @Semantics.booleanIndicator 
      qmsm_foa_param.def_aff_obj_is_add_param                            as DefectAffectedObjIsAddlParam,
      qmsm_foa_param.batch                                               as Batch,
      @ObjectModel.foreignKey.association: '_EWM_WarehouseNumber'
      qmsm_foa_param.lgnum                                               as EWMWarehouse,
      qmsm_foa_param.ewm_followup_action                                 as QltyTaskEWMFollowUpAction,
      qmsm_foa_param.warehouselogicalsystem                              as WarehouseLogicalSystem,

      /* Associations */
      _QualityTask,
      _Material,
      _Plant,
      _StorageLocation,
      _UnitOfMeasure,
      _MfgActionReasonCodeGroup,
      _MfgActionReasonCode,
      _ChangeRecordBsc,
      _ProductionSupplyArea,
      _OrderInternalID,
      _OrderOperationBasic,
      _EWM_WarehouseNumber
}
where
      qmsm_foa_param.qmnum like '$%'
  and qmsm_foa_param.manum =    '0000'